tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ stdenv, fetchurl, fetchpatch, flex, bison }:
2
3stdenv.mkDerivation rec {
4 name = "libpcap-1.8.1";
5
6 src = fetchurl {
7 url = "http://www.tcpdump.org/release/${name}.tar.gz";
8 sha256 = "07jlhc66z76dipj4j5v3dig8x6h3k6cb36kmnmpsixf3zmlvqgb7";
9 };
10
11 nativeBuildInputs = [ flex bison ];
12
13 # We need to force the autodetection because detection doesn't
14 # work in pure build enviroments.
15 configureFlags =
16 if stdenv.isLinux then [ "--with-pcap=linux" ]
17 else if stdenv.isDarwin then [ "--with-pcap=bpf" ]
18 else [];
19
20 prePatch = stdenv.lib.optionalString stdenv.isDarwin ''
21 substituteInPlace configure --replace " -arch i386" ""
22 '';
23
24 patches = [
25 (fetchpatch {
26 url = "https://sources.debian.net/data/main/libp/libpcap/1.8.1-3/debian/patches/disable-remote.diff";
27 sha256 = "0dvjax9c0spvq8cdjnkbnm65wlzaml259yragf95kzg611vszfmj";
28 })
29 ];
30
31 preInstall = ''mkdir -p $out/bin'';
32
33 crossAttrs = {
34 # Stripping hurts in static libraries
35 dontStrip = true;
36 configureFlags = configureFlags ++ [ "ac_cv_linux_vers=2" ];
37 };
38
39 meta = with stdenv.lib; {
40 homepage = http://www.tcpdump.org;
41 description = "Packet Capture Library";
42 platforms = platforms.unix;
43 maintainers = with maintainers; [ fpletz ];
44 };
45}