tjh.dev
1{ stdenv, fetchurl, python, buildPythonPackage, pycairo
2, which, cycler, dateutil, nose, numpy, pyparsing, sphinx, tornado
3, freetype, libpng, pkgconfig, mock, pytz, pygobject3, functools32, subprocess32
4, enableGhostscript ? false, ghostscript ? null, gtk3
5, enableGtk2 ? false, pygtk ? null, gobjectIntrospection
6, enableGtk3 ? false, cairo
7, enableTk ? false, tcl ? null, tk ? null, tkinter ? null, libX11 ? null
8, enableQt ? false, pyqt4
9, libcxx
10, Cocoa
11}:
12
13assert enableGhostscript -> ghostscript != null;
14assert enableGtk2 -> pygtk != null;
15assert enableTk -> (tcl != null)
16 && (tk != null)
17 && (tkinter != null)
18 && (libX11 != null)
19 ;
20assert enableQt -> pyqt4 != null;
21
22buildPythonPackage rec {
23 version = "2.0.2";
24 pname = "matplotlib";
25 name = "${pname}-${version}";
26
27 src = fetchurl {
28 url = "mirror://pypi/m/matplotlib/${name}.tar.gz";
29 sha256 = "0ffbc44faa34a8b1704bc108c451ecf87988f900ef7ce757b8e2e84383121ff1";
30 };
31
32 NIX_CFLAGS_COMPILE = stdenv.lib.optionalString stdenv.isDarwin "-I${libcxx}/include/c++/v1";
33
34 XDG_RUNTIME_DIR = "/tmp";
35
36 buildInputs = [ python which sphinx stdenv ]
37 ++ stdenv.lib.optional enableGhostscript ghostscript
38 ++ stdenv.lib.optional stdenv.isDarwin [ Cocoa ];
39
40 propagatedBuildInputs =
41 [ cycler dateutil nose numpy pyparsing tornado freetype
42 libpng pkgconfig mock pytz
43 ]
44 ++ stdenv.lib.optional enableGtk2 pygtk
45 ++ stdenv.lib.optionals enableGtk3 [ cairo pycairo gtk3 gobjectIntrospection pygobject3 ]
46 ++ stdenv.lib.optionals enableTk [ tcl tk tkinter libX11 ]
47 ++ stdenv.lib.optionals enableQt [ pyqt4 ]
48 ++ stdenv.lib.optionals (builtins.hasAttr "isPy2" python) [ functools32 subprocess32 ];
49
50 patches =
51 [ ./basedirlist.patch ] ++
52 stdenv.lib.optionals stdenv.isDarwin [ ./darwin-stdenv.patch ];
53
54 # Matplotlib tries to find Tcl/Tk by opening a Tk window and asking the
55 # corresponding interpreter object for its library paths. This fails if
56 # `$DISPLAY` is not set. The fallback option assumes that Tcl/Tk are both
57 # installed under the same path which is not true in Nix.
58 # With the following patch we just hard-code these paths into the install
59 # script.
60 postPatch =
61 let
62 inherit (stdenv.lib.strings) substring;
63 tcl_tk_cache = ''"${tk}/lib", "${tcl}/lib", "${substring 0 3 tk.version}"'';
64 in
65 stdenv.lib.optionalString enableTk
66 "sed -i '/self.tcl_tk_cache = None/s|None|${tcl_tk_cache}|' setupext.py";
67
68 checkPhase = ''
69 ${python.interpreter} tests.py
70 '';
71
72 # Test data is not included in the distribution (the `tests` folder
73 # is missing)
74 doCheck = false;
75
76 prePatch = ''
77 # Failing test: ERROR: matplotlib.tests.test_style.test_use_url
78 sed -i 's/test_use_url/fails/' lib/matplotlib/tests/test_style.py
79 # Failing test: ERROR: test suite for <class 'matplotlib.sphinxext.tests.test_tinypages.TestTinyPages'>
80 sed -i 's/TestTinyPages/fails/' lib/matplotlib/sphinxext/tests/test_tinypages.py
81 # Transient errors
82 sed -i 's/test_invisible_Line_rendering/noop/' lib/matplotlib/tests/test_lines.py
83 '';
84
85 meta = with stdenv.lib; {
86 description = "Python plotting library, making publication quality plots";
87 homepage = "http://matplotlib.sourceforge.net/";
88 maintainers = with maintainers; [ lovek323 ];
89 platforms = platforms.unix;
90 };
91
92}