tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ stdenv, lib, fetchurl, pkgconfig, audiofile
2, openglSupport ? false, mesa_noglu
3, alsaSupport ? true, alsaLib
4, x11Support ? true, libICE, libXi, libXScrnSaver, libXcursor, libXinerama, libXext, libXxf86vm, libXrandr
5, dbusSupport ? false, dbus
6, udevSupport ? false, udev
7, ibusSupport ? false, ibus
8, pulseaudioSupport ? true, libpulseaudio
9, AudioUnit, Cocoa, CoreAudio, CoreServices, ForceFeedback, OpenGL
10}:
11
12# OSS is no longer supported, for it's much crappier than ALSA and
13# PulseAudio.
14assert !stdenv.isDarwin -> alsaSupport || pulseaudioSupport;
15
16assert openglSupport -> (stdenv.isDarwin || mesa_noglu != null && x11Support);
17
18let
19 configureFlagsFun = attrs: [
20 "--disable-oss" "--disable-x11-shared"
21 "--disable-pulseaudio-shared" "--disable-alsa-shared"
22 ] ++ lib.optional alsaSupport "--with-alsa-prefix=${attrs.alsaLib.out}/lib"
23 ++ lib.optional (!x11Support) "--without-x";
24in
25stdenv.mkDerivation rec {
26 name = "SDL2-${version}";
27 version = "2.0.5";
28
29 src = fetchurl {
30 url = "http://www.libsdl.org/release/${name}.tar.gz";
31 sha256 = "11c75qj1qxmx67iwkvf9z4x69phk301pdn86zzr6jncnap7kh824";
32 };
33
34 outputs = [ "out" "dev" ];
35
36 patches = [ ./find-headers.patch ];
37
38 nativeBuildInputs = [ pkgconfig ];
39
40 # Since `libpulse*.la' contain `-lgdbm', PulseAudio must be propagated.
41 propagatedBuildInputs = lib.optionals x11Support [ libICE libXi libXScrnSaver libXcursor libXinerama libXext libXrandr libXxf86vm ] ++
42 lib.optional pulseaudioSupport libpulseaudio;
43
44 buildInputs = [ audiofile ] ++
45 lib.optional openglSupport mesa_noglu ++
46 lib.optional alsaSupport alsaLib ++
47 lib.optional dbusSupport dbus ++
48 lib.optional udevSupport udev ++
49 lib.optional ibusSupport ibus ++
50 lib.optionals stdenv.isDarwin [ AudioUnit Cocoa CoreAudio CoreServices ForceFeedback OpenGL ];
51
52 # https://bugzilla.libsdl.org/show_bug.cgi?id=1431
53 dontDisableStatic = true;
54
55 enableParallelBuilding = true;
56
57 # XXX: By default, SDL wants to dlopen() PulseAudio, in which case
58 # we must arrange to add it to its RPATH; however, `patchelf' seems
59 # to fail at doing this, hence `--disable-pulseaudio-shared'.
60 configureFlags = configureFlagsFun { inherit alsaLib; };
61
62 crossAttrs = {
63 configureFlags = configureFlagsFun { alsaLib = alsaLib.crossDrv; };
64 };
65
66 postInstall = ''
67 moveToOutput lib/libSDL2main.a "$dev"
68 rm $out/lib/*.a
69 moveToOutput bin/sdl2-config "$dev"
70 '';
71
72 setupHook = ./setup-hook.sh;
73
74 passthru = { inherit openglSupport; };
75
76 meta = with stdenv.lib; {
77 description = "A cross-platform multimedia library";
78 homepage = http://www.libsdl.org/;
79 license = licenses.zlib;
80 platforms = platforms.all;
81 maintainers = with maintainers; [ cpages ];
82 };
83}