Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#ifndef LOAD_OFFSET
54#define LOAD_OFFSET 0
55#endif
56
57/*
58 * Only some architectures want to have the .notes segment visible in
59 * a separate PT_NOTE ELF Program Header. When this happens, it needs
60 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
61 * Program Headers. In this case, though, the PT_LOAD needs to be made
62 * the default again so that all the following sections don't also end
63 * up in the PT_NOTE Program Header.
64 */
65#ifdef EMITS_PT_NOTE
66#define NOTES_HEADERS :text :note
67#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
68#else
69#define NOTES_HEADERS
70#define NOTES_HEADERS_RESTORE
71#endif
72
73/*
74 * Some architectures have non-executable read-only exception tables.
75 * They can be added to the RO_DATA segment by specifying their desired
76 * alignment.
77 */
78#ifdef RO_EXCEPTION_TABLE_ALIGN
79#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
80#else
81#define RO_EXCEPTION_TABLE
82#endif
83
84/* Align . function alignment. */
85#define ALIGN_FUNCTION() . = ALIGN(CONFIG_FUNCTION_ALIGNMENT)
86
87/*
88 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
89 * generates .data.identifier sections, which need to be pulled in with
90 * .data. We don't want to pull in .data..other sections, which Linux
91 * has defined. Same for text and bss.
92 *
93 * With LTO_CLANG, the linker also splits sections by default, so we need
94 * these macros to combine the sections during the final link.
95 *
96 * RODATA_MAIN is not used because existing code already defines .rodata.x
97 * sections to be brought in with rodata.
98 */
99#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
100#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
101#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
102#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
103#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
104#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..compoundliteral*
105#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
106#else
107#define TEXT_MAIN .text
108#define DATA_MAIN .data
109#define SDATA_MAIN .sdata
110#define RODATA_MAIN .rodata
111#define BSS_MAIN .bss
112#define SBSS_MAIN .sbss
113#endif
114
115/*
116 * GCC 4.5 and later have a 32 bytes section alignment for structures.
117 * Except GCC 4.9, that feels the need to align on 64 bytes.
118 */
119#define STRUCT_ALIGNMENT 32
120#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
121
122/*
123 * The order of the sched class addresses are important, as they are
124 * used to determine the order of the priority of each sched class in
125 * relation to each other.
126 */
127#define SCHED_DATA \
128 STRUCT_ALIGN(); \
129 __sched_class_highest = .; \
130 *(__stop_sched_class) \
131 *(__dl_sched_class) \
132 *(__rt_sched_class) \
133 *(__fair_sched_class) \
134 *(__idle_sched_class) \
135 __sched_class_lowest = .;
136
137/* The actual configuration determine if the init/exit sections
138 * are handled as text/data or they can be discarded (which
139 * often happens at runtime)
140 */
141#ifdef CONFIG_HOTPLUG_CPU
142#define CPU_KEEP(sec) *(.cpu##sec)
143#define CPU_DISCARD(sec)
144#else
145#define CPU_KEEP(sec)
146#define CPU_DISCARD(sec) *(.cpu##sec)
147#endif
148
149#if defined(CONFIG_MEMORY_HOTPLUG)
150#define MEM_KEEP(sec) *(.mem##sec)
151#define MEM_DISCARD(sec)
152#else
153#define MEM_KEEP(sec)
154#define MEM_DISCARD(sec) *(.mem##sec)
155#endif
156
157#ifndef CONFIG_HAVE_DYNAMIC_FTRACE_NO_PATCHABLE
158#define KEEP_PATCHABLE KEEP(*(__patchable_function_entries))
159#define PATCHABLE_DISCARDS
160#else
161#define KEEP_PATCHABLE
162#define PATCHABLE_DISCARDS *(__patchable_function_entries)
163#endif
164
165#ifndef CONFIG_ARCH_SUPPORTS_CFI_CLANG
166/*
167 * Simply points to ftrace_stub, but with the proper protocol.
168 * Defined by the linker script in linux/vmlinux.lds.h
169 */
170#define FTRACE_STUB_HACK ftrace_stub_graph = ftrace_stub;
171#else
172#define FTRACE_STUB_HACK
173#endif
174
175#ifdef CONFIG_FTRACE_MCOUNT_RECORD
176/*
177 * The ftrace call sites are logged to a section whose name depends on the
178 * compiler option used. A given kernel image will only use one, AKA
179 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
180 * dependencies for FTRACE_CALLSITE_SECTION's definition.
181 *
182 * ftrace_ops_list_func will be defined as arch_ftrace_ops_list_func
183 * as some archs will have a different prototype for that function
184 * but ftrace_ops_list_func() will have a single prototype.
185 */
186#define MCOUNT_REC() . = ALIGN(8); \
187 __start_mcount_loc = .; \
188 KEEP(*(__mcount_loc)) \
189 KEEP_PATCHABLE \
190 __stop_mcount_loc = .; \
191 FTRACE_STUB_HACK \
192 ftrace_ops_list_func = arch_ftrace_ops_list_func;
193#else
194# ifdef CONFIG_FUNCTION_TRACER
195# define MCOUNT_REC() FTRACE_STUB_HACK \
196 ftrace_ops_list_func = arch_ftrace_ops_list_func;
197# else
198# define MCOUNT_REC()
199# endif
200#endif
201
202#define BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_) \
203 _BEGIN_##_label_ = .; \
204 KEEP(*(_sec_)) \
205 _END_##_label_ = .;
206
207#define BOUNDED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_) \
208 _label_##_BEGIN_ = .; \
209 KEEP(*(_sec_)) \
210 _label_##_END_ = .;
211
212#define BOUNDED_SECTION_BY(_sec_, _label_) \
213 BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, __start, __stop)
214
215#define BOUNDED_SECTION(_sec) BOUNDED_SECTION_BY(_sec, _sec)
216
217#define HEADERED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_, _HDR_) \
218 _HDR_##_label_ = .; \
219 KEEP(*(.gnu.linkonce.##_sec_)) \
220 BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_)
221
222#define HEADERED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_, _HDR_) \
223 _label_##_HDR_ = .; \
224 KEEP(*(.gnu.linkonce.##_sec_)) \
225 BOUNDED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_)
226
227#define HEADERED_SECTION_BY(_sec_, _label_) \
228 HEADERED_SECTION_PRE_LABEL(_sec_, _label_, __start, __stop)
229
230#define HEADERED_SECTION(_sec) HEADERED_SECTION_BY(_sec, _sec)
231
232#ifdef CONFIG_TRACE_BRANCH_PROFILING
233#define LIKELY_PROFILE() \
234 BOUNDED_SECTION_BY(_ftrace_annotated_branch, _annotated_branch_profile)
235#else
236#define LIKELY_PROFILE()
237#endif
238
239#ifdef CONFIG_PROFILE_ALL_BRANCHES
240#define BRANCH_PROFILE() \
241 BOUNDED_SECTION_BY(_ftrace_branch, _branch_profile)
242#else
243#define BRANCH_PROFILE()
244#endif
245
246#ifdef CONFIG_KPROBES
247#define KPROBE_BLACKLIST() \
248 . = ALIGN(8); \
249 BOUNDED_SECTION(_kprobe_blacklist)
250#else
251#define KPROBE_BLACKLIST()
252#endif
253
254#ifdef CONFIG_FUNCTION_ERROR_INJECTION
255#define ERROR_INJECT_WHITELIST() \
256 STRUCT_ALIGN(); \
257 BOUNDED_SECTION(_error_injection_whitelist)
258#else
259#define ERROR_INJECT_WHITELIST()
260#endif
261
262#ifdef CONFIG_EVENT_TRACING
263#define FTRACE_EVENTS() \
264 . = ALIGN(8); \
265 BOUNDED_SECTION(_ftrace_events) \
266 BOUNDED_SECTION_BY(_ftrace_eval_map, _ftrace_eval_maps)
267#else
268#define FTRACE_EVENTS()
269#endif
270
271#ifdef CONFIG_TRACING
272#define TRACE_PRINTKS() BOUNDED_SECTION_BY(__trace_printk_fmt, ___trace_bprintk_fmt)
273#define TRACEPOINT_STR() BOUNDED_SECTION_BY(__tracepoint_str, ___tracepoint_str)
274#else
275#define TRACE_PRINTKS()
276#define TRACEPOINT_STR()
277#endif
278
279#ifdef CONFIG_FTRACE_SYSCALLS
280#define TRACE_SYSCALLS() \
281 . = ALIGN(8); \
282 BOUNDED_SECTION_BY(__syscalls_metadata, _syscalls_metadata)
283#else
284#define TRACE_SYSCALLS()
285#endif
286
287#ifdef CONFIG_BPF_EVENTS
288#define BPF_RAW_TP() STRUCT_ALIGN(); \
289 BOUNDED_SECTION_BY(__bpf_raw_tp_map, __bpf_raw_tp)
290#else
291#define BPF_RAW_TP()
292#endif
293
294#ifdef CONFIG_SERIAL_EARLYCON
295#define EARLYCON_TABLE() \
296 . = ALIGN(8); \
297 BOUNDED_SECTION_POST_LABEL(__earlycon_table, __earlycon_table, , _end)
298#else
299#define EARLYCON_TABLE()
300#endif
301
302#ifdef CONFIG_SECURITY
303#define LSM_TABLE() \
304 . = ALIGN(8); \
305 BOUNDED_SECTION_PRE_LABEL(.lsm_info.init, _lsm_info, __start, __end)
306
307#define EARLY_LSM_TABLE() \
308 . = ALIGN(8); \
309 BOUNDED_SECTION_PRE_LABEL(.early_lsm_info.init, _early_lsm_info, __start, __end)
310#else
311#define LSM_TABLE()
312#define EARLY_LSM_TABLE()
313#endif
314
315#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
316#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
317#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
318#define _OF_TABLE_0(name)
319#define _OF_TABLE_1(name) \
320 . = ALIGN(8); \
321 __##name##_of_table = .; \
322 KEEP(*(__##name##_of_table)) \
323 KEEP(*(__##name##_of_table_end))
324
325#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
326#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
327#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
328#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
329#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
330#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
331
332#ifdef CONFIG_ACPI
333#define ACPI_PROBE_TABLE(name) \
334 . = ALIGN(8); \
335 BOUNDED_SECTION_POST_LABEL(__##name##_acpi_probe_table, \
336 __##name##_acpi_probe_table,, _end)
337#else
338#define ACPI_PROBE_TABLE(name)
339#endif
340
341#ifdef CONFIG_THERMAL
342#define THERMAL_TABLE(name) \
343 . = ALIGN(8); \
344 BOUNDED_SECTION_POST_LABEL(__##name##_thermal_table, \
345 __##name##_thermal_table,, _end)
346#else
347#define THERMAL_TABLE(name)
348#endif
349
350#define KERNEL_DTB() \
351 STRUCT_ALIGN(); \
352 __dtb_start = .; \
353 KEEP(*(.dtb.init.rodata)) \
354 __dtb_end = .;
355
356/*
357 * .data section
358 */
359#define DATA_DATA \
360 *(.xiptext) \
361 *(DATA_MAIN) \
362 *(.data..decrypted) \
363 *(.ref.data) \
364 *(.data..shared_aligned) /* percpu related */ \
365 MEM_KEEP(init.data*) \
366 MEM_KEEP(exit.data*) \
367 *(.data.unlikely) \
368 __start_once = .; \
369 *(.data.once) \
370 __end_once = .; \
371 STRUCT_ALIGN(); \
372 *(__tracepoints) \
373 /* implement dynamic printk debug */ \
374 . = ALIGN(8); \
375 BOUNDED_SECTION_BY(__dyndbg_classes, ___dyndbg_classes) \
376 BOUNDED_SECTION_BY(__dyndbg, ___dyndbg) \
377 LIKELY_PROFILE() \
378 BRANCH_PROFILE() \
379 TRACE_PRINTKS() \
380 BPF_RAW_TP() \
381 TRACEPOINT_STR()
382
383/*
384 * Data section helpers
385 */
386#define NOSAVE_DATA \
387 . = ALIGN(PAGE_SIZE); \
388 __nosave_begin = .; \
389 *(.data..nosave) \
390 . = ALIGN(PAGE_SIZE); \
391 __nosave_end = .;
392
393#define PAGE_ALIGNED_DATA(page_align) \
394 . = ALIGN(page_align); \
395 *(.data..page_aligned) \
396 . = ALIGN(page_align);
397
398#define READ_MOSTLY_DATA(align) \
399 . = ALIGN(align); \
400 *(.data..read_mostly) \
401 . = ALIGN(align);
402
403#define CACHELINE_ALIGNED_DATA(align) \
404 . = ALIGN(align); \
405 *(.data..cacheline_aligned)
406
407#define INIT_TASK_DATA(align) \
408 . = ALIGN(align); \
409 __start_init_task = .; \
410 init_thread_union = .; \
411 init_stack = .; \
412 KEEP(*(.data..init_task)) \
413 KEEP(*(.data..init_thread_info)) \
414 . = __start_init_task + THREAD_SIZE; \
415 __end_init_task = .;
416
417#define JUMP_TABLE_DATA \
418 . = ALIGN(8); \
419 BOUNDED_SECTION_BY(__jump_table, ___jump_table)
420
421#ifdef CONFIG_HAVE_STATIC_CALL_INLINE
422#define STATIC_CALL_DATA \
423 . = ALIGN(8); \
424 BOUNDED_SECTION_BY(.static_call_sites, _static_call_sites) \
425 BOUNDED_SECTION_BY(.static_call_tramp_key, _static_call_tramp_key)
426#else
427#define STATIC_CALL_DATA
428#endif
429
430/*
431 * Allow architectures to handle ro_after_init data on their
432 * own by defining an empty RO_AFTER_INIT_DATA.
433 */
434#ifndef RO_AFTER_INIT_DATA
435#define RO_AFTER_INIT_DATA \
436 . = ALIGN(8); \
437 __start_ro_after_init = .; \
438 *(.data..ro_after_init) \
439 JUMP_TABLE_DATA \
440 STATIC_CALL_DATA \
441 __end_ro_after_init = .;
442#endif
443
444/*
445 * .kcfi_traps contains a list KCFI trap locations.
446 */
447#ifndef KCFI_TRAPS
448#ifdef CONFIG_ARCH_USES_CFI_TRAPS
449#define KCFI_TRAPS \
450 __kcfi_traps : AT(ADDR(__kcfi_traps) - LOAD_OFFSET) { \
451 BOUNDED_SECTION_BY(.kcfi_traps, ___kcfi_traps) \
452 }
453#else
454#define KCFI_TRAPS
455#endif
456#endif
457
458/*
459 * Read only Data
460 */
461#define RO_DATA(align) \
462 . = ALIGN((align)); \
463 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
464 __start_rodata = .; \
465 *(.rodata) *(.rodata.*) \
466 SCHED_DATA \
467 RO_AFTER_INIT_DATA /* Read only after init */ \
468 . = ALIGN(8); \
469 BOUNDED_SECTION_BY(__tracepoints_ptrs, ___tracepoints_ptrs) \
470 *(__tracepoints_strings)/* Tracepoints: strings */ \
471 } \
472 \
473 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
474 *(.rodata1) \
475 } \
476 \
477 /* PCI quirks */ \
478 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
479 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_early, _pci_fixups_early, __start, __end) \
480 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_header, _pci_fixups_header, __start, __end) \
481 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_final, _pci_fixups_final, __start, __end) \
482 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_enable, _pci_fixups_enable, __start, __end) \
483 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_resume, _pci_fixups_resume, __start, __end) \
484 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_suspend, _pci_fixups_suspend, __start, __end) \
485 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_resume_early, _pci_fixups_resume_early, __start, __end) \
486 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_suspend_late, _pci_fixups_suspend_late, __start, __end) \
487 } \
488 \
489 FW_LOADER_BUILT_IN_DATA \
490 TRACEDATA \
491 \
492 PRINTK_INDEX \
493 \
494 /* Kernel symbol table: Normal symbols */ \
495 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
496 __start___ksymtab = .; \
497 KEEP(*(SORT(___ksymtab+*))) \
498 __stop___ksymtab = .; \
499 } \
500 \
501 /* Kernel symbol table: GPL-only symbols */ \
502 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
503 __start___ksymtab_gpl = .; \
504 KEEP(*(SORT(___ksymtab_gpl+*))) \
505 __stop___ksymtab_gpl = .; \
506 } \
507 \
508 /* Kernel symbol table: Normal symbols */ \
509 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
510 __start___kcrctab = .; \
511 KEEP(*(SORT(___kcrctab+*))) \
512 __stop___kcrctab = .; \
513 } \
514 \
515 /* Kernel symbol table: GPL-only symbols */ \
516 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
517 __start___kcrctab_gpl = .; \
518 KEEP(*(SORT(___kcrctab_gpl+*))) \
519 __stop___kcrctab_gpl = .; \
520 } \
521 \
522 /* Kernel symbol table: strings */ \
523 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
524 *(__ksymtab_strings) \
525 } \
526 \
527 /* __*init sections */ \
528 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
529 *(.ref.rodata) \
530 MEM_KEEP(init.rodata) \
531 MEM_KEEP(exit.rodata) \
532 } \
533 \
534 /* Built-in module parameters. */ \
535 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
536 BOUNDED_SECTION_BY(__param, ___param) \
537 } \
538 \
539 /* Built-in module versions. */ \
540 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
541 BOUNDED_SECTION_BY(__modver, ___modver) \
542 } \
543 \
544 KCFI_TRAPS \
545 \
546 RO_EXCEPTION_TABLE \
547 NOTES \
548 BTF \
549 \
550 . = ALIGN((align)); \
551 __end_rodata = .;
552
553
554/*
555 * Non-instrumentable text section
556 */
557#define NOINSTR_TEXT \
558 ALIGN_FUNCTION(); \
559 __noinstr_text_start = .; \
560 *(.noinstr.text) \
561 __cpuidle_text_start = .; \
562 *(.cpuidle.text) \
563 __cpuidle_text_end = .; \
564 __noinstr_text_end = .;
565
566/*
567 * .text section. Map to function alignment to avoid address changes
568 * during second ld run in second ld pass when generating System.map
569 *
570 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
571 * code elimination is enabled, so these sections should be converted
572 * to use ".." first.
573 */
574#define TEXT_TEXT \
575 ALIGN_FUNCTION(); \
576 *(.text.hot .text.hot.*) \
577 *(TEXT_MAIN .text.fixup) \
578 *(.text.unlikely .text.unlikely.*) \
579 *(.text.unknown .text.unknown.*) \
580 NOINSTR_TEXT \
581 *(.ref.text) \
582 *(.text.asan.* .text.tsan.*) \
583 MEM_KEEP(init.text*) \
584 MEM_KEEP(exit.text*) \
585
586
587/* sched.text is aling to function alignment to secure we have same
588 * address even at second ld pass when generating System.map */
589#define SCHED_TEXT \
590 ALIGN_FUNCTION(); \
591 __sched_text_start = .; \
592 *(.sched.text) \
593 __sched_text_end = .;
594
595/* spinlock.text is aling to function alignment to secure we have same
596 * address even at second ld pass when generating System.map */
597#define LOCK_TEXT \
598 ALIGN_FUNCTION(); \
599 __lock_text_start = .; \
600 *(.spinlock.text) \
601 __lock_text_end = .;
602
603#define KPROBES_TEXT \
604 ALIGN_FUNCTION(); \
605 __kprobes_text_start = .; \
606 *(.kprobes.text) \
607 __kprobes_text_end = .;
608
609#define ENTRY_TEXT \
610 ALIGN_FUNCTION(); \
611 __entry_text_start = .; \
612 *(.entry.text) \
613 __entry_text_end = .;
614
615#define IRQENTRY_TEXT \
616 ALIGN_FUNCTION(); \
617 __irqentry_text_start = .; \
618 *(.irqentry.text) \
619 __irqentry_text_end = .;
620
621#define SOFTIRQENTRY_TEXT \
622 ALIGN_FUNCTION(); \
623 __softirqentry_text_start = .; \
624 *(.softirqentry.text) \
625 __softirqentry_text_end = .;
626
627#define STATIC_CALL_TEXT \
628 ALIGN_FUNCTION(); \
629 __static_call_text_start = .; \
630 *(.static_call.text) \
631 __static_call_text_end = .;
632
633/* Section used for early init (in .S files) */
634#define HEAD_TEXT KEEP(*(.head.text))
635
636#define HEAD_TEXT_SECTION \
637 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
638 HEAD_TEXT \
639 }
640
641/*
642 * Exception table
643 */
644#define EXCEPTION_TABLE(align) \
645 . = ALIGN(align); \
646 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
647 BOUNDED_SECTION_BY(__ex_table, ___ex_table) \
648 }
649
650/*
651 * .BTF
652 */
653#ifdef CONFIG_DEBUG_INFO_BTF
654#define BTF \
655 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
656 BOUNDED_SECTION_BY(.BTF, _BTF) \
657 } \
658 . = ALIGN(4); \
659 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
660 *(.BTF_ids) \
661 }
662#else
663#define BTF
664#endif
665
666/*
667 * Init task
668 */
669#define INIT_TASK_DATA_SECTION(align) \
670 . = ALIGN(align); \
671 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
672 INIT_TASK_DATA(align) \
673 }
674
675#ifdef CONFIG_CONSTRUCTORS
676#define KERNEL_CTORS() . = ALIGN(8); \
677 __ctors_start = .; \
678 KEEP(*(SORT(.ctors.*))) \
679 KEEP(*(.ctors)) \
680 KEEP(*(SORT(.init_array.*))) \
681 KEEP(*(.init_array)) \
682 __ctors_end = .;
683#else
684#define KERNEL_CTORS()
685#endif
686
687/* init and exit section handling */
688#define INIT_DATA \
689 KEEP(*(SORT(___kentry+*))) \
690 *(.init.data .init.data.*) \
691 MEM_DISCARD(init.data*) \
692 KERNEL_CTORS() \
693 MCOUNT_REC() \
694 *(.init.rodata .init.rodata.*) \
695 FTRACE_EVENTS() \
696 TRACE_SYSCALLS() \
697 KPROBE_BLACKLIST() \
698 ERROR_INJECT_WHITELIST() \
699 MEM_DISCARD(init.rodata) \
700 CLK_OF_TABLES() \
701 RESERVEDMEM_OF_TABLES() \
702 TIMER_OF_TABLES() \
703 CPU_METHOD_OF_TABLES() \
704 CPUIDLE_METHOD_OF_TABLES() \
705 KERNEL_DTB() \
706 IRQCHIP_OF_MATCH_TABLE() \
707 ACPI_PROBE_TABLE(irqchip) \
708 ACPI_PROBE_TABLE(timer) \
709 THERMAL_TABLE(governor) \
710 EARLYCON_TABLE() \
711 LSM_TABLE() \
712 EARLY_LSM_TABLE() \
713 KUNIT_TABLE()
714
715#define INIT_TEXT \
716 *(.init.text .init.text.*) \
717 *(.text.startup) \
718 MEM_DISCARD(init.text*)
719
720#define EXIT_DATA \
721 *(.exit.data .exit.data.*) \
722 *(.fini_array .fini_array.*) \
723 *(.dtors .dtors.*) \
724 MEM_DISCARD(exit.data*) \
725 MEM_DISCARD(exit.rodata*)
726
727#define EXIT_TEXT \
728 *(.exit.text) \
729 *(.text.exit) \
730 MEM_DISCARD(exit.text)
731
732#define EXIT_CALL \
733 *(.exitcall.exit)
734
735/*
736 * bss (Block Started by Symbol) - uninitialized data
737 * zeroed during startup
738 */
739#define SBSS(sbss_align) \
740 . = ALIGN(sbss_align); \
741 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
742 *(.dynsbss) \
743 *(SBSS_MAIN) \
744 *(.scommon) \
745 }
746
747/*
748 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
749 * sections to the front of bss.
750 */
751#ifndef BSS_FIRST_SECTIONS
752#define BSS_FIRST_SECTIONS
753#endif
754
755#define BSS(bss_align) \
756 . = ALIGN(bss_align); \
757 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
758 BSS_FIRST_SECTIONS \
759 . = ALIGN(PAGE_SIZE); \
760 *(.bss..page_aligned) \
761 . = ALIGN(PAGE_SIZE); \
762 *(.dynbss) \
763 *(BSS_MAIN) \
764 *(COMMON) \
765 }
766
767/*
768 * DWARF debug sections.
769 * Symbols in the DWARF debugging sections are relative to
770 * the beginning of the section so we begin them at 0.
771 */
772#define DWARF_DEBUG \
773 /* DWARF 1 */ \
774 .debug 0 : { *(.debug) } \
775 .line 0 : { *(.line) } \
776 /* GNU DWARF 1 extensions */ \
777 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
778 .debug_sfnames 0 : { *(.debug_sfnames) } \
779 /* DWARF 1.1 and DWARF 2 */ \
780 .debug_aranges 0 : { *(.debug_aranges) } \
781 .debug_pubnames 0 : { *(.debug_pubnames) } \
782 /* DWARF 2 */ \
783 .debug_info 0 : { *(.debug_info \
784 .gnu.linkonce.wi.*) } \
785 .debug_abbrev 0 : { *(.debug_abbrev) } \
786 .debug_line 0 : { *(.debug_line) } \
787 .debug_frame 0 : { *(.debug_frame) } \
788 .debug_str 0 : { *(.debug_str) } \
789 .debug_loc 0 : { *(.debug_loc) } \
790 .debug_macinfo 0 : { *(.debug_macinfo) } \
791 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
792 /* DWARF 3 */ \
793 .debug_ranges 0 : { *(.debug_ranges) } \
794 /* SGI/MIPS DWARF 2 extensions */ \
795 .debug_weaknames 0 : { *(.debug_weaknames) } \
796 .debug_funcnames 0 : { *(.debug_funcnames) } \
797 .debug_typenames 0 : { *(.debug_typenames) } \
798 .debug_varnames 0 : { *(.debug_varnames) } \
799 /* GNU DWARF 2 extensions */ \
800 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
801 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
802 /* DWARF 4 */ \
803 .debug_types 0 : { *(.debug_types) } \
804 /* DWARF 5 */ \
805 .debug_addr 0 : { *(.debug_addr) } \
806 .debug_line_str 0 : { *(.debug_line_str) } \
807 .debug_loclists 0 : { *(.debug_loclists) } \
808 .debug_macro 0 : { *(.debug_macro) } \
809 .debug_names 0 : { *(.debug_names) } \
810 .debug_rnglists 0 : { *(.debug_rnglists) } \
811 .debug_str_offsets 0 : { *(.debug_str_offsets) }
812
813/* Stabs debugging sections. */
814#define STABS_DEBUG \
815 .stab 0 : { *(.stab) } \
816 .stabstr 0 : { *(.stabstr) } \
817 .stab.excl 0 : { *(.stab.excl) } \
818 .stab.exclstr 0 : { *(.stab.exclstr) } \
819 .stab.index 0 : { *(.stab.index) } \
820 .stab.indexstr 0 : { *(.stab.indexstr) }
821
822/* Required sections not related to debugging. */
823#define ELF_DETAILS \
824 .comment 0 : { *(.comment) } \
825 .symtab 0 : { *(.symtab) } \
826 .strtab 0 : { *(.strtab) } \
827 .shstrtab 0 : { *(.shstrtab) }
828
829#ifdef CONFIG_GENERIC_BUG
830#define BUG_TABLE \
831 . = ALIGN(8); \
832 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
833 BOUNDED_SECTION_BY(__bug_table, ___bug_table) \
834 }
835#else
836#define BUG_TABLE
837#endif
838
839#ifdef CONFIG_UNWINDER_ORC
840#define ORC_UNWIND_TABLE \
841 .orc_header : AT(ADDR(.orc_header) - LOAD_OFFSET) { \
842 BOUNDED_SECTION_BY(.orc_header, _orc_header) \
843 } \
844 . = ALIGN(4); \
845 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
846 BOUNDED_SECTION_BY(.orc_unwind_ip, _orc_unwind_ip) \
847 } \
848 . = ALIGN(2); \
849 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
850 BOUNDED_SECTION_BY(.orc_unwind, _orc_unwind) \
851 } \
852 text_size = _etext - _stext; \
853 . = ALIGN(4); \
854 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
855 orc_lookup = .; \
856 . += (((text_size + LOOKUP_BLOCK_SIZE - 1) / \
857 LOOKUP_BLOCK_SIZE) + 1) * 4; \
858 orc_lookup_end = .; \
859 }
860#else
861#define ORC_UNWIND_TABLE
862#endif
863
864/* Built-in firmware blobs */
865#ifdef CONFIG_FW_LOADER
866#define FW_LOADER_BUILT_IN_DATA \
867 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
868 BOUNDED_SECTION_PRE_LABEL(.builtin_fw, _builtin_fw, __start, __end) \
869 }
870#else
871#define FW_LOADER_BUILT_IN_DATA
872#endif
873
874#ifdef CONFIG_PM_TRACE
875#define TRACEDATA \
876 . = ALIGN(4); \
877 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
878 BOUNDED_SECTION_POST_LABEL(.tracedata, __tracedata, _start, _end) \
879 }
880#else
881#define TRACEDATA
882#endif
883
884#ifdef CONFIG_PRINTK_INDEX
885#define PRINTK_INDEX \
886 .printk_index : AT(ADDR(.printk_index) - LOAD_OFFSET) { \
887 BOUNDED_SECTION_BY(.printk_index, _printk_index) \
888 }
889#else
890#define PRINTK_INDEX
891#endif
892
893/*
894 * Discard .note.GNU-stack, which is emitted as PROGBITS by the compiler.
895 * Otherwise, the type of .notes section would become PROGBITS instead of NOTES.
896 *
897 * Also, discard .note.gnu.property, otherwise it forces the notes section to
898 * be 8-byte aligned which causes alignment mismatches with the kernel's custom
899 * 4-byte aligned notes.
900 */
901#define NOTES \
902 /DISCARD/ : { \
903 *(.note.GNU-stack) \
904 *(.note.gnu.property) \
905 } \
906 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
907 BOUNDED_SECTION_BY(.note.*, _notes) \
908 } NOTES_HEADERS \
909 NOTES_HEADERS_RESTORE
910
911#define INIT_SETUP(initsetup_align) \
912 . = ALIGN(initsetup_align); \
913 BOUNDED_SECTION_POST_LABEL(.init.setup, __setup, _start, _end)
914
915#define INIT_CALLS_LEVEL(level) \
916 __initcall##level##_start = .; \
917 KEEP(*(.initcall##level##.init)) \
918 KEEP(*(.initcall##level##s.init)) \
919
920#define INIT_CALLS \
921 __initcall_start = .; \
922 KEEP(*(.initcallearly.init)) \
923 INIT_CALLS_LEVEL(0) \
924 INIT_CALLS_LEVEL(1) \
925 INIT_CALLS_LEVEL(2) \
926 INIT_CALLS_LEVEL(3) \
927 INIT_CALLS_LEVEL(4) \
928 INIT_CALLS_LEVEL(5) \
929 INIT_CALLS_LEVEL(rootfs) \
930 INIT_CALLS_LEVEL(6) \
931 INIT_CALLS_LEVEL(7) \
932 __initcall_end = .;
933
934#define CON_INITCALL \
935 BOUNDED_SECTION_POST_LABEL(.con_initcall.init, __con_initcall, _start, _end)
936
937/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
938#define KUNIT_TABLE() \
939 . = ALIGN(8); \
940 BOUNDED_SECTION_POST_LABEL(.kunit_test_suites, __kunit_suites, _start, _end)
941
942#ifdef CONFIG_BLK_DEV_INITRD
943#define INIT_RAM_FS \
944 . = ALIGN(4); \
945 __initramfs_start = .; \
946 KEEP(*(.init.ramfs)) \
947 . = ALIGN(8); \
948 KEEP(*(.init.ramfs.info))
949#else
950#define INIT_RAM_FS
951#endif
952
953/*
954 * Memory encryption operates on a page basis. Since we need to clear
955 * the memory encryption mask for this section, it needs to be aligned
956 * on a page boundary and be a page-size multiple in length.
957 *
958 * Note: We use a separate section so that only this section gets
959 * decrypted to avoid exposing more than we wish.
960 */
961#ifdef CONFIG_AMD_MEM_ENCRYPT
962#define PERCPU_DECRYPTED_SECTION \
963 . = ALIGN(PAGE_SIZE); \
964 *(.data..percpu..decrypted) \
965 . = ALIGN(PAGE_SIZE);
966#else
967#define PERCPU_DECRYPTED_SECTION
968#endif
969
970
971/*
972 * Default discarded sections.
973 *
974 * Some archs want to discard exit text/data at runtime rather than
975 * link time due to cross-section references such as alt instructions,
976 * bug table, eh_frame, etc. DISCARDS must be the last of output
977 * section definitions so that such archs put those in earlier section
978 * definitions.
979 */
980#ifdef RUNTIME_DISCARD_EXIT
981#define EXIT_DISCARDS
982#else
983#define EXIT_DISCARDS \
984 EXIT_TEXT \
985 EXIT_DATA
986#endif
987
988/*
989 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
990 * -fsanitize=thread produce unwanted sections (.eh_frame
991 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
992 * keep any .init_array.* sections.
993 * https://bugs.llvm.org/show_bug.cgi?id=46478
994 */
995#ifdef CONFIG_UNWIND_TABLES
996#define DISCARD_EH_FRAME
997#else
998#define DISCARD_EH_FRAME *(.eh_frame)
999#endif
1000#if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN)
1001# ifdef CONFIG_CONSTRUCTORS
1002# define SANITIZER_DISCARDS \
1003 DISCARD_EH_FRAME
1004# else
1005# define SANITIZER_DISCARDS \
1006 *(.init_array) *(.init_array.*) \
1007 DISCARD_EH_FRAME
1008# endif
1009#else
1010# define SANITIZER_DISCARDS
1011#endif
1012
1013#define COMMON_DISCARDS \
1014 SANITIZER_DISCARDS \
1015 PATCHABLE_DISCARDS \
1016 *(.discard) \
1017 *(.discard.*) \
1018 *(.export_symbol) \
1019 *(.modinfo) \
1020 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1021 *(.gnu.version*) \
1022
1023#define DISCARDS \
1024 /DISCARD/ : { \
1025 EXIT_DISCARDS \
1026 EXIT_CALL \
1027 COMMON_DISCARDS \
1028 }
1029
1030/**
1031 * PERCPU_INPUT - the percpu input sections
1032 * @cacheline: cacheline size
1033 *
1034 * The core percpu section names and core symbols which do not rely
1035 * directly upon load addresses.
1036 *
1037 * @cacheline is used to align subsections to avoid false cacheline
1038 * sharing between subsections for different purposes.
1039 */
1040#define PERCPU_INPUT(cacheline) \
1041 __per_cpu_start = .; \
1042 *(.data..percpu..first) \
1043 . = ALIGN(PAGE_SIZE); \
1044 *(.data..percpu..page_aligned) \
1045 . = ALIGN(cacheline); \
1046 *(.data..percpu..read_mostly) \
1047 . = ALIGN(cacheline); \
1048 *(.data..percpu) \
1049 *(.data..percpu..shared_aligned) \
1050 PERCPU_DECRYPTED_SECTION \
1051 __per_cpu_end = .;
1052
1053/**
1054 * PERCPU_VADDR - define output section for percpu area
1055 * @cacheline: cacheline size
1056 * @vaddr: explicit base address (optional)
1057 * @phdr: destination PHDR (optional)
1058 *
1059 * Macro which expands to output section for percpu area.
1060 *
1061 * @cacheline is used to align subsections to avoid false cacheline
1062 * sharing between subsections for different purposes.
1063 *
1064 * If @vaddr is not blank, it specifies explicit base address and all
1065 * percpu symbols will be offset from the given address. If blank,
1066 * @vaddr always equals @laddr + LOAD_OFFSET.
1067 *
1068 * @phdr defines the output PHDR to use if not blank. Be warned that
1069 * output PHDR is sticky. If @phdr is specified, the next output
1070 * section in the linker script will go there too. @phdr should have
1071 * a leading colon.
1072 *
1073 * Note that this macros defines __per_cpu_load as an absolute symbol.
1074 * If there is no need to put the percpu section at a predetermined
1075 * address, use PERCPU_SECTION.
1076 */
1077#define PERCPU_VADDR(cacheline, vaddr, phdr) \
1078 __per_cpu_load = .; \
1079 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1080 PERCPU_INPUT(cacheline) \
1081 } phdr \
1082 . = __per_cpu_load + SIZEOF(.data..percpu);
1083
1084/**
1085 * PERCPU_SECTION - define output section for percpu area, simple version
1086 * @cacheline: cacheline size
1087 *
1088 * Align to PAGE_SIZE and outputs output section for percpu area. This
1089 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1090 * __per_cpu_start will be identical.
1091 *
1092 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1093 * except that __per_cpu_load is defined as a relative symbol against
1094 * .data..percpu which is required for relocatable x86_32 configuration.
1095 */
1096#define PERCPU_SECTION(cacheline) \
1097 . = ALIGN(PAGE_SIZE); \
1098 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1099 __per_cpu_load = .; \
1100 PERCPU_INPUT(cacheline) \
1101 }
1102
1103
1104/*
1105 * Definition of the high level *_SECTION macros
1106 * They will fit only a subset of the architectures
1107 */
1108
1109
1110/*
1111 * Writeable data.
1112 * All sections are combined in a single .data section.
1113 * The sections following CONSTRUCTORS are arranged so their
1114 * typical alignment matches.
1115 * A cacheline is typical/always less than a PAGE_SIZE so
1116 * the sections that has this restriction (or similar)
1117 * is located before the ones requiring PAGE_SIZE alignment.
1118 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1119 * matches the requirement of PAGE_ALIGNED_DATA.
1120 *
1121 * use 0 as page_align if page_aligned data is not used */
1122#define RW_DATA(cacheline, pagealigned, inittask) \
1123 . = ALIGN(PAGE_SIZE); \
1124 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1125 INIT_TASK_DATA(inittask) \
1126 NOSAVE_DATA \
1127 PAGE_ALIGNED_DATA(pagealigned) \
1128 CACHELINE_ALIGNED_DATA(cacheline) \
1129 READ_MOSTLY_DATA(cacheline) \
1130 DATA_DATA \
1131 CONSTRUCTORS \
1132 } \
1133 BUG_TABLE \
1134
1135#define INIT_TEXT_SECTION(inittext_align) \
1136 . = ALIGN(inittext_align); \
1137 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1138 _sinittext = .; \
1139 INIT_TEXT \
1140 _einittext = .; \
1141 }
1142
1143#define INIT_DATA_SECTION(initsetup_align) \
1144 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1145 INIT_DATA \
1146 INIT_SETUP(initsetup_align) \
1147 INIT_CALLS \
1148 CON_INITCALL \
1149 INIT_RAM_FS \
1150 }
1151
1152#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1153 . = ALIGN(sbss_align); \
1154 __bss_start = .; \
1155 SBSS(sbss_align) \
1156 BSS(bss_align) \
1157 . = ALIGN(stop_align); \
1158 __bss_stop = .;