tjh.dev
Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
kernel
os
linux
fork
Configure Feed
Select the types of activity you want to include in your feed.
1
2%option reentrant
3%option bison-bridge
4%option prefix="parse_events_"
5%option stack
6%option bison-locations
7%option yylineno
8%option reject
9
10%{
11#include <errno.h>
12#include <sys/types.h>
13#include <sys/stat.h>
14#include <unistd.h>
15#include "parse-events.h"
16#include "parse-events-bison.h"
17#include "evsel.h"
18
19char *parse_events_get_text(yyscan_t yyscanner);
20YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
21int parse_events_get_column(yyscan_t yyscanner);
22int parse_events_get_leng(yyscan_t yyscanner);
23
24static int get_column(yyscan_t scanner)
25{
26 return parse_events_get_column(scanner) - parse_events_get_leng(scanner);
27}
28
29static int value(struct parse_events_state *parse_state, yyscan_t scanner, int base)
30{
31 YYSTYPE *yylval = parse_events_get_lval(scanner);
32 char *text = parse_events_get_text(scanner);
33 u64 num;
34
35 errno = 0;
36 num = strtoull(text, NULL, base);
37 if (errno) {
38 struct parse_events_error *error = parse_state->error;
39 char *help = NULL;
40
41 if (asprintf(&help, "Bad base %d number \"%s\"", base, text) > 0)
42 parse_events_error__handle(error, get_column(scanner), help , NULL);
43
44 return PE_ERROR;
45 }
46
47 yylval->num = num;
48 return PE_VALUE;
49}
50
51static int str(yyscan_t scanner, int token)
52{
53 YYSTYPE *yylval = parse_events_get_lval(scanner);
54 char *text = parse_events_get_text(scanner);
55
56 if (text[0] != '\'') {
57 yylval->str = strdup(text);
58 } else {
59 /*
60 * If a text tag specified on the command line
61 * contains opening single quite ' then it is
62 * expected that the tag ends with single quote
63 * as well, like this:
64 * name=\'CPU_CLK_UNHALTED.THREAD:cmask=1\'
65 * quotes need to be escaped to bypass shell
66 * processing.
67 */
68 yylval->str = strndup(&text[1], strlen(text) - 2);
69 }
70
71 return token;
72}
73
74static int lc_str(yyscan_t scanner, const struct parse_events_state *state)
75{
76 return str(scanner, state->match_legacy_cache_terms ? PE_LEGACY_CACHE : PE_NAME);
77}
78
79/*
80 * This function is called when the parser gets two kind of input:
81 *
82 * @cfg1 or @cfg2=config
83 *
84 * The leading '@' is stripped off before 'cfg1' and 'cfg2=config' are given to
85 * bison. In the latter case it is necessary to keep the string intact so that
86 * the PMU kernel driver can determine what configurable is associated to
87 * 'config'.
88 */
89static int drv_str(yyscan_t scanner, int token)
90{
91 YYSTYPE *yylval = parse_events_get_lval(scanner);
92 char *text = parse_events_get_text(scanner);
93
94 /* Strip off the '@' */
95 yylval->str = strdup(text + 1);
96 return token;
97}
98
99/*
100 * Use yyless to return all the characaters to the input. Update the column for
101 * location debugging. If __alloc is non-zero set yylval to the text for the
102 * returned token's value.
103 */
104#define REWIND(__alloc) \
105do { \
106 YYSTYPE *__yylval = parse_events_get_lval(yyscanner); \
107 char *text = parse_events_get_text(yyscanner); \
108 \
109 if (__alloc) \
110 __yylval->str = strdup(text); \
111 \
112 yycolumn -= strlen(text); \
113 yyless(0); \
114} while (0)
115
116static int sym(yyscan_t scanner, int type, int config)
117{
118 YYSTYPE *yylval = parse_events_get_lval(scanner);
119
120 yylval->num = (type << 16) + config;
121 return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
122}
123
124static int tool(yyscan_t scanner, enum perf_tool_event event)
125{
126 YYSTYPE *yylval = parse_events_get_lval(scanner);
127
128 yylval->num = event;
129 return PE_VALUE_SYM_TOOL;
130}
131
132static int term(yyscan_t scanner, enum parse_events__term_type type)
133{
134 YYSTYPE *yylval = parse_events_get_lval(scanner);
135
136 yylval->term_type = type;
137 return PE_TERM;
138}
139
140static int hw_term(yyscan_t scanner, int config)
141{
142 YYSTYPE *yylval = parse_events_get_lval(scanner);
143 char *text = parse_events_get_text(scanner);
144
145 yylval->hardware_term.str = strdup(text);
146 yylval->hardware_term.num = PERF_TYPE_HARDWARE + config;
147 return PE_TERM_HW;
148}
149
150static void modifiers_error(struct parse_events_state *parse_state, yyscan_t scanner,
151 int pos, char mod_char, const char *mod_name)
152{
153 struct parse_events_error *error = parse_state->error;
154 char *help = NULL;
155
156 if (asprintf(&help, "Duplicate modifier '%c' (%s)", mod_char, mod_name) > 0)
157 parse_events_error__handle(error, get_column(scanner) + pos, help , NULL);
158}
159
160static int modifiers(struct parse_events_state *parse_state, yyscan_t scanner)
161{
162 YYSTYPE *yylval = parse_events_get_lval(scanner);
163 char *text = parse_events_get_text(scanner);
164 struct parse_events_modifier mod = { .precise = 0, };
165
166 for (size_t i = 0, n = strlen(text); i < n; i++) {
167#define CASE(c, field) \
168 case c: \
169 if (mod.field) { \
170 modifiers_error(parse_state, scanner, i, c, #field); \
171 return PE_ERROR; \
172 } \
173 mod.field = true; \
174 break
175
176 switch (text[i]) {
177 CASE('u', user);
178 CASE('k', kernel);
179 CASE('h', hypervisor);
180 CASE('I', non_idle);
181 CASE('G', guest);
182 CASE('H', host);
183 case 'p':
184 mod.precise++;
185 /*
186 * precise ip:
187 *
188 * 0 - SAMPLE_IP can have arbitrary skid
189 * 1 - SAMPLE_IP must have constant skid
190 * 2 - SAMPLE_IP requested to have 0 skid
191 * 3 - SAMPLE_IP must have 0 skid
192 *
193 * See also PERF_RECORD_MISC_EXACT_IP
194 */
195 if (mod.precise > 3) {
196 struct parse_events_error *error = parse_state->error;
197 char *help = strdup("Maximum precise value is 3");
198
199 if (help) {
200 parse_events_error__handle(error, get_column(scanner) + i,
201 help , NULL);
202 }
203 return PE_ERROR;
204 }
205 break;
206 CASE('P', precise_max);
207 CASE('S', sample_read);
208 CASE('D', pinned);
209 CASE('W', weak);
210 CASE('e', exclusive);
211 CASE('b', bpf);
212 CASE('R', retire_lat);
213 default:
214 return PE_ERROR;
215 }
216#undef CASE
217 }
218 yylval->mod = mod;
219 return PE_MODIFIER_EVENT;
220}
221
222#define YY_USER_ACTION \
223do { \
224 yylloc->last_column = yylloc->first_column; \
225 yylloc->first_column = yycolumn; \
226 yycolumn += yyleng; \
227} while (0);
228
229#define USER_REJECT \
230 yycolumn -= yyleng; \
231 REJECT
232
233%}
234
235%x mem
236%s config
237%x event
238
239group [^,{}/]*[{][^}]*[}][^,{}/]*
240event_pmu [^,{}/]+[/][^/]*[/][^,{}/]*
241event [^,{}/]+
242
243num_dec [0-9]+
244num_hex 0x[a-fA-F0-9]{1,16}
245num_raw_hex [a-fA-F0-9]{1,16}
246name [a-zA-Z0-9_*?\[\]][a-zA-Z0-9_*?.\[\]!\-]*
247name_tag [\'][a-zA-Z0-9_*?\[\]][a-zA-Z0-9_*?\-,\.\[\]:=]*[\']
248name_minus [a-zA-Z_*?][a-zA-Z0-9\-_*?.:]*
249drv_cfg_term [a-zA-Z0-9_\.]+(=[a-zA-Z0-9_*?\.:]+)?
250/*
251 * If you add a modifier you need to update check_modifier().
252 * Also, the letters in modifier_event must not be in modifier_bp.
253 */
254modifier_event [ukhpPGHSDIWebR]{1,16}
255modifier_bp [rwx]{1,3}
256lc_type (L1-dcache|l1-d|l1d|L1-data|L1-icache|l1-i|l1i|L1-instruction|LLC|L2|dTLB|d-tlb|Data-TLB|iTLB|i-tlb|Instruction-TLB|branch|branches|bpu|btb|bpc|node)
257lc_op_result (load|loads|read|store|stores|write|prefetch|prefetches|speculative-read|speculative-load|refs|Reference|ops|access|misses|miss)
258digit [0-9]
259non_digit [^0-9]
260
261%%
262
263%{
264 struct parse_events_state *_parse_state = parse_events_get_extra(yyscanner);
265 {
266 int start_token = _parse_state->stoken;
267
268 if (start_token == PE_START_TERMS)
269 BEGIN(config);
270 else if (start_token == PE_START_EVENTS)
271 BEGIN(event);
272
273 if (start_token) {
274 _parse_state->stoken = 0;
275 /*
276 * The flex parser does not init locations variable
277 * via the scan_string interface, so we need do the
278 * init in here.
279 */
280 yycolumn = 0;
281 return start_token;
282 }
283 }
284%}
285
286<event>{
287
288{group} {
289 BEGIN(INITIAL);
290 REWIND(0);
291 }
292
293{event_pmu} |
294{event} {
295 BEGIN(INITIAL);
296 REWIND(1);
297 return PE_EVENT_NAME;
298 }
299
300<<EOF>> {
301 BEGIN(INITIAL);
302 REWIND(0);
303 }
304, {
305 return ',';
306 }
307}
308
309<config>{
310 /*
311 * Please update config_term_names when new static term is added.
312 */
313config { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
314config1 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
315config2 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
316config3 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG3); }
317name { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
318period { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
319freq { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
320branch_type { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
321time { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
322call-graph { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
323stack-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
324max-stack { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_STACK); }
325nr { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_MAX_EVENTS); }
326inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_INHERIT); }
327no-inherit { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOINHERIT); }
328overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_OVERWRITE); }
329no-overwrite { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOOVERWRITE); }
330percore { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_PERCORE); }
331aux-output { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_AUX_OUTPUT); }
332aux-sample-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_AUX_SAMPLE_SIZE); }
333metric-id { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_METRIC_ID); }
334cpu-cycles|cycles { return hw_term(yyscanner, PERF_COUNT_HW_CPU_CYCLES); }
335stalled-cycles-frontend|idle-cycles-frontend { return hw_term(yyscanner, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
336stalled-cycles-backend|idle-cycles-backend { return hw_term(yyscanner, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
337instructions { return hw_term(yyscanner, PERF_COUNT_HW_INSTRUCTIONS); }
338cache-references { return hw_term(yyscanner, PERF_COUNT_HW_CACHE_REFERENCES); }
339cache-misses { return hw_term(yyscanner, PERF_COUNT_HW_CACHE_MISSES); }
340branch-instructions|branches { return hw_term(yyscanner, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
341branch-misses { return hw_term(yyscanner, PERF_COUNT_HW_BRANCH_MISSES); }
342bus-cycles { return hw_term(yyscanner, PERF_COUNT_HW_BUS_CYCLES); }
343ref-cycles { return hw_term(yyscanner, PERF_COUNT_HW_REF_CPU_CYCLES); }
344r{num_raw_hex} { return str(yyscanner, PE_RAW); }
345r0x{num_raw_hex} { return str(yyscanner, PE_RAW); }
346, { return ','; }
347"/" { BEGIN(INITIAL); return '/'; }
348{lc_type} { return lc_str(yyscanner, _parse_state); }
349{lc_type}-{lc_op_result} { return lc_str(yyscanner, _parse_state); }
350{lc_type}-{lc_op_result}-{lc_op_result} { return lc_str(yyscanner, _parse_state); }
351{name_minus} { return str(yyscanner, PE_NAME); }
352@{drv_cfg_term} { return drv_str(yyscanner, PE_DRV_CFG_TERM); }
353}
354
355<mem>{
356{modifier_bp} { return str(yyscanner, PE_MODIFIER_BP); }
357 /*
358 * The colon before memory access modifiers can get mixed up with the
359 * colon before event modifiers. Fortunately none of the option letters
360 * are the same, so trailing context can be used disambiguate the two
361 * cases.
362 */
363":"/{modifier_bp} { return PE_BP_COLON; }
364 /*
365 * The slash before memory length can get mixed up with the slash before
366 * config terms. Fortunately config terms do not start with a numeric
367 * digit, so trailing context can be used disambiguate the two cases.
368 */
369"/"/{digit} { return PE_BP_SLASH; }
370"/"/{non_digit} { BEGIN(config); return '/'; }
371{num_dec} { return value(_parse_state, yyscanner, 10); }
372{num_hex} { return value(_parse_state, yyscanner, 16); }
373 /*
374 * We need to separate 'mem:' scanner part, in order to get specific
375 * modifier bits parsed out. Otherwise we would need to handle PE_NAME
376 * and we'd need to parse it manually. During the escape from <mem>
377 * state we need to put the escaping char back, so we dont miss it.
378 */
379. { unput(*yytext); BEGIN(INITIAL); }
380 /*
381 * We destroy the scanner after reaching EOF,
382 * but anyway just to be sure get back to INIT state.
383 */
384<<EOF>> { BEGIN(INITIAL); }
385}
386
387cpu-cycles|cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
388stalled-cycles-frontend|idle-cycles-frontend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
389stalled-cycles-backend|idle-cycles-backend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
390instructions { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
391cache-references { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
392cache-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
393branch-instructions|branches { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
394branch-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
395bus-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
396ref-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
397cpu-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
398task-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
399page-faults|faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
400minor-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
401major-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
402context-switches|cs { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
403cpu-migrations|migrations { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
404alignment-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
405emulation-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
406dummy { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
407duration_time { return tool(yyscanner, PERF_TOOL_DURATION_TIME); }
408user_time { return tool(yyscanner, PERF_TOOL_USER_TIME); }
409system_time { return tool(yyscanner, PERF_TOOL_SYSTEM_TIME); }
410bpf-output { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_BPF_OUTPUT); }
411cgroup-switches { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CGROUP_SWITCHES); }
412
413{lc_type} { return str(yyscanner, PE_LEGACY_CACHE); }
414{lc_type}-{lc_op_result} { return str(yyscanner, PE_LEGACY_CACHE); }
415{lc_type}-{lc_op_result}-{lc_op_result} { return str(yyscanner, PE_LEGACY_CACHE); }
416mem: { BEGIN(mem); return PE_PREFIX_MEM; }
417r{num_raw_hex} { return str(yyscanner, PE_RAW); }
418{num_dec} { return value(_parse_state, yyscanner, 10); }
419{num_hex} { return value(_parse_state, yyscanner, 16); }
420
421{modifier_event} { return modifiers(_parse_state, yyscanner); }
422{name} { return str(yyscanner, PE_NAME); }
423{name_tag} { return str(yyscanner, PE_NAME); }
424"/" { BEGIN(config); return '/'; }
425, { BEGIN(event); return ','; }
426: { return ':'; }
427"{" { BEGIN(event); return '{'; }
428"}" { return '}'; }
429= { return '='; }
430\n { }
431. { }
432
433%%
434
435int parse_events_wrap(void *scanner __maybe_unused)
436{
437 return 1;
438}