Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#ifndef LOAD_OFFSET
54#define LOAD_OFFSET 0
55#endif
56
57/*
58 * Only some architectures want to have the .notes segment visible in
59 * a separate PT_NOTE ELF Program Header. When this happens, it needs
60 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
61 * Program Headers. In this case, though, the PT_LOAD needs to be made
62 * the default again so that all the following sections don't also end
63 * up in the PT_NOTE Program Header.
64 */
65#ifdef EMITS_PT_NOTE
66#define NOTES_HEADERS :text :note
67#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
68#else
69#define NOTES_HEADERS
70#define NOTES_HEADERS_RESTORE
71#endif
72
73/*
74 * Some architectures have non-executable read-only exception tables.
75 * They can be added to the RO_DATA segment by specifying their desired
76 * alignment.
77 */
78#ifdef RO_EXCEPTION_TABLE_ALIGN
79#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
80#else
81#define RO_EXCEPTION_TABLE
82#endif
83
84/* Align . to a 8 byte boundary equals to maximum function alignment. */
85#define ALIGN_FUNCTION() . = ALIGN(8)
86
87/*
88 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
89 * generates .data.identifier sections, which need to be pulled in with
90 * .data. We don't want to pull in .data..other sections, which Linux
91 * has defined. Same for text and bss.
92 *
93 * With LTO_CLANG, the linker also splits sections by default, so we need
94 * these macros to combine the sections during the final link.
95 *
96 * RODATA_MAIN is not used because existing code already defines .rodata.x
97 * sections to be brought in with rodata.
98 */
99#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
100#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
101#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
102#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
103#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
104#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..compoundliteral*
105#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
106#else
107#define TEXT_MAIN .text
108#define DATA_MAIN .data
109#define SDATA_MAIN .sdata
110#define RODATA_MAIN .rodata
111#define BSS_MAIN .bss
112#define SBSS_MAIN .sbss
113#endif
114
115/*
116 * GCC 4.5 and later have a 32 bytes section alignment for structures.
117 * Except GCC 4.9, that feels the need to align on 64 bytes.
118 */
119#define STRUCT_ALIGNMENT 32
120#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
121
122/*
123 * The order of the sched class addresses are important, as they are
124 * used to determine the order of the priority of each sched class in
125 * relation to each other.
126 */
127#define SCHED_DATA \
128 STRUCT_ALIGN(); \
129 __sched_class_highest = .; \
130 *(__stop_sched_class) \
131 *(__dl_sched_class) \
132 *(__rt_sched_class) \
133 *(__fair_sched_class) \
134 *(__idle_sched_class) \
135 __sched_class_lowest = .;
136
137/* The actual configuration determine if the init/exit sections
138 * are handled as text/data or they can be discarded (which
139 * often happens at runtime)
140 */
141#ifdef CONFIG_HOTPLUG_CPU
142#define CPU_KEEP(sec) *(.cpu##sec)
143#define CPU_DISCARD(sec)
144#else
145#define CPU_KEEP(sec)
146#define CPU_DISCARD(sec) *(.cpu##sec)
147#endif
148
149#if defined(CONFIG_MEMORY_HOTPLUG)
150#define MEM_KEEP(sec) *(.mem##sec)
151#define MEM_DISCARD(sec)
152#else
153#define MEM_KEEP(sec)
154#define MEM_DISCARD(sec) *(.mem##sec)
155#endif
156
157#ifdef CONFIG_FTRACE_MCOUNT_RECORD
158/*
159 * The ftrace call sites are logged to a section whose name depends on the
160 * compiler option used. A given kernel image will only use one, AKA
161 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
162 * dependencies for FTRACE_CALLSITE_SECTION's definition.
163 *
164 * Need to also make ftrace_stub_graph point to ftrace_stub
165 * so that the same stub location may have different protocols
166 * and not mess up with C verifiers.
167 *
168 * ftrace_ops_list_func will be defined as arch_ftrace_ops_list_func
169 * as some archs will have a different prototype for that function
170 * but ftrace_ops_list_func() will have a single prototype.
171 */
172#define MCOUNT_REC() . = ALIGN(8); \
173 __start_mcount_loc = .; \
174 KEEP(*(__mcount_loc)) \
175 KEEP(*(__patchable_function_entries)) \
176 __stop_mcount_loc = .; \
177 ftrace_stub_graph = ftrace_stub; \
178 ftrace_ops_list_func = arch_ftrace_ops_list_func;
179#else
180# ifdef CONFIG_FUNCTION_TRACER
181# define MCOUNT_REC() ftrace_stub_graph = ftrace_stub; \
182 ftrace_ops_list_func = arch_ftrace_ops_list_func;
183# else
184# define MCOUNT_REC()
185# endif
186#endif
187
188#ifdef CONFIG_TRACE_BRANCH_PROFILING
189#define LIKELY_PROFILE() __start_annotated_branch_profile = .; \
190 KEEP(*(_ftrace_annotated_branch)) \
191 __stop_annotated_branch_profile = .;
192#else
193#define LIKELY_PROFILE()
194#endif
195
196#ifdef CONFIG_PROFILE_ALL_BRANCHES
197#define BRANCH_PROFILE() __start_branch_profile = .; \
198 KEEP(*(_ftrace_branch)) \
199 __stop_branch_profile = .;
200#else
201#define BRANCH_PROFILE()
202#endif
203
204#ifdef CONFIG_KPROBES
205#define KPROBE_BLACKLIST() . = ALIGN(8); \
206 __start_kprobe_blacklist = .; \
207 KEEP(*(_kprobe_blacklist)) \
208 __stop_kprobe_blacklist = .;
209#else
210#define KPROBE_BLACKLIST()
211#endif
212
213#ifdef CONFIG_FUNCTION_ERROR_INJECTION
214#define ERROR_INJECT_WHITELIST() STRUCT_ALIGN(); \
215 __start_error_injection_whitelist = .; \
216 KEEP(*(_error_injection_whitelist)) \
217 __stop_error_injection_whitelist = .;
218#else
219#define ERROR_INJECT_WHITELIST()
220#endif
221
222#ifdef CONFIG_EVENT_TRACING
223#define FTRACE_EVENTS() . = ALIGN(8); \
224 __start_ftrace_events = .; \
225 KEEP(*(_ftrace_events)) \
226 __stop_ftrace_events = .; \
227 __start_ftrace_eval_maps = .; \
228 KEEP(*(_ftrace_eval_map)) \
229 __stop_ftrace_eval_maps = .;
230#else
231#define FTRACE_EVENTS()
232#endif
233
234#ifdef CONFIG_TRACING
235#define TRACE_PRINTKS() __start___trace_bprintk_fmt = .; \
236 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
237 __stop___trace_bprintk_fmt = .;
238#define TRACEPOINT_STR() __start___tracepoint_str = .; \
239 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
240 __stop___tracepoint_str = .;
241#else
242#define TRACE_PRINTKS()
243#define TRACEPOINT_STR()
244#endif
245
246#ifdef CONFIG_FTRACE_SYSCALLS
247#define TRACE_SYSCALLS() . = ALIGN(8); \
248 __start_syscalls_metadata = .; \
249 KEEP(*(__syscalls_metadata)) \
250 __stop_syscalls_metadata = .;
251#else
252#define TRACE_SYSCALLS()
253#endif
254
255#ifdef CONFIG_BPF_EVENTS
256#define BPF_RAW_TP() STRUCT_ALIGN(); \
257 __start__bpf_raw_tp = .; \
258 KEEP(*(__bpf_raw_tp_map)) \
259 __stop__bpf_raw_tp = .;
260#else
261#define BPF_RAW_TP()
262#endif
263
264#ifdef CONFIG_SERIAL_EARLYCON
265#define EARLYCON_TABLE() . = ALIGN(8); \
266 __earlycon_table = .; \
267 KEEP(*(__earlycon_table)) \
268 __earlycon_table_end = .;
269#else
270#define EARLYCON_TABLE()
271#endif
272
273#ifdef CONFIG_SECURITY
274#define LSM_TABLE() . = ALIGN(8); \
275 __start_lsm_info = .; \
276 KEEP(*(.lsm_info.init)) \
277 __end_lsm_info = .;
278#define EARLY_LSM_TABLE() . = ALIGN(8); \
279 __start_early_lsm_info = .; \
280 KEEP(*(.early_lsm_info.init)) \
281 __end_early_lsm_info = .;
282#else
283#define LSM_TABLE()
284#define EARLY_LSM_TABLE()
285#endif
286
287#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
288#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
289#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
290#define _OF_TABLE_0(name)
291#define _OF_TABLE_1(name) \
292 . = ALIGN(8); \
293 __##name##_of_table = .; \
294 KEEP(*(__##name##_of_table)) \
295 KEEP(*(__##name##_of_table_end))
296
297#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
298#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
299#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
300#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
301#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
302#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
303
304#ifdef CONFIG_ACPI
305#define ACPI_PROBE_TABLE(name) \
306 . = ALIGN(8); \
307 __##name##_acpi_probe_table = .; \
308 KEEP(*(__##name##_acpi_probe_table)) \
309 __##name##_acpi_probe_table_end = .;
310#else
311#define ACPI_PROBE_TABLE(name)
312#endif
313
314#ifdef CONFIG_THERMAL
315#define THERMAL_TABLE(name) \
316 . = ALIGN(8); \
317 __##name##_thermal_table = .; \
318 KEEP(*(__##name##_thermal_table)) \
319 __##name##_thermal_table_end = .;
320#else
321#define THERMAL_TABLE(name)
322#endif
323
324#define KERNEL_DTB() \
325 STRUCT_ALIGN(); \
326 __dtb_start = .; \
327 KEEP(*(.dtb.init.rodata)) \
328 __dtb_end = .;
329
330/*
331 * .data section
332 */
333#define DATA_DATA \
334 *(.xiptext) \
335 *(DATA_MAIN) \
336 *(.ref.data) \
337 *(.data..shared_aligned) /* percpu related */ \
338 MEM_KEEP(init.data*) \
339 MEM_KEEP(exit.data*) \
340 *(.data.unlikely) \
341 __start_once = .; \
342 *(.data.once) \
343 __end_once = .; \
344 STRUCT_ALIGN(); \
345 *(__tracepoints) \
346 /* implement dynamic printk debug */ \
347 . = ALIGN(8); \
348 __start___dyndbg = .; \
349 KEEP(*(__dyndbg)) \
350 __stop___dyndbg = .; \
351 LIKELY_PROFILE() \
352 BRANCH_PROFILE() \
353 TRACE_PRINTKS() \
354 BPF_RAW_TP() \
355 TRACEPOINT_STR()
356
357/*
358 * Data section helpers
359 */
360#define NOSAVE_DATA \
361 . = ALIGN(PAGE_SIZE); \
362 __nosave_begin = .; \
363 *(.data..nosave) \
364 . = ALIGN(PAGE_SIZE); \
365 __nosave_end = .;
366
367#define PAGE_ALIGNED_DATA(page_align) \
368 . = ALIGN(page_align); \
369 *(.data..page_aligned) \
370 . = ALIGN(page_align);
371
372#define READ_MOSTLY_DATA(align) \
373 . = ALIGN(align); \
374 *(.data..read_mostly) \
375 . = ALIGN(align);
376
377#define CACHELINE_ALIGNED_DATA(align) \
378 . = ALIGN(align); \
379 *(.data..cacheline_aligned)
380
381#define INIT_TASK_DATA(align) \
382 . = ALIGN(align); \
383 __start_init_task = .; \
384 init_thread_union = .; \
385 init_stack = .; \
386 KEEP(*(.data..init_task)) \
387 KEEP(*(.data..init_thread_info)) \
388 . = __start_init_task + THREAD_SIZE; \
389 __end_init_task = .;
390
391#define JUMP_TABLE_DATA \
392 . = ALIGN(8); \
393 __start___jump_table = .; \
394 KEEP(*(__jump_table)) \
395 __stop___jump_table = .;
396
397#ifdef CONFIG_HAVE_STATIC_CALL_INLINE
398#define STATIC_CALL_DATA \
399 . = ALIGN(8); \
400 __start_static_call_sites = .; \
401 KEEP(*(.static_call_sites)) \
402 __stop_static_call_sites = .; \
403 __start_static_call_tramp_key = .; \
404 KEEP(*(.static_call_tramp_key)) \
405 __stop_static_call_tramp_key = .;
406#else
407#define STATIC_CALL_DATA
408#endif
409
410/*
411 * Allow architectures to handle ro_after_init data on their
412 * own by defining an empty RO_AFTER_INIT_DATA.
413 */
414#ifndef RO_AFTER_INIT_DATA
415#define RO_AFTER_INIT_DATA \
416 . = ALIGN(8); \
417 __start_ro_after_init = .; \
418 *(.data..ro_after_init) \
419 JUMP_TABLE_DATA \
420 STATIC_CALL_DATA \
421 __end_ro_after_init = .;
422#endif
423
424/*
425 * Read only Data
426 */
427#define RO_DATA(align) \
428 . = ALIGN((align)); \
429 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
430 __start_rodata = .; \
431 *(.rodata) *(.rodata.*) \
432 SCHED_DATA \
433 RO_AFTER_INIT_DATA /* Read only after init */ \
434 . = ALIGN(8); \
435 __start___tracepoints_ptrs = .; \
436 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
437 __stop___tracepoints_ptrs = .; \
438 *(__tracepoints_strings)/* Tracepoints: strings */ \
439 } \
440 \
441 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
442 *(.rodata1) \
443 } \
444 \
445 /* PCI quirks */ \
446 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
447 __start_pci_fixups_early = .; \
448 KEEP(*(.pci_fixup_early)) \
449 __end_pci_fixups_early = .; \
450 __start_pci_fixups_header = .; \
451 KEEP(*(.pci_fixup_header)) \
452 __end_pci_fixups_header = .; \
453 __start_pci_fixups_final = .; \
454 KEEP(*(.pci_fixup_final)) \
455 __end_pci_fixups_final = .; \
456 __start_pci_fixups_enable = .; \
457 KEEP(*(.pci_fixup_enable)) \
458 __end_pci_fixups_enable = .; \
459 __start_pci_fixups_resume = .; \
460 KEEP(*(.pci_fixup_resume)) \
461 __end_pci_fixups_resume = .; \
462 __start_pci_fixups_resume_early = .; \
463 KEEP(*(.pci_fixup_resume_early)) \
464 __end_pci_fixups_resume_early = .; \
465 __start_pci_fixups_suspend = .; \
466 KEEP(*(.pci_fixup_suspend)) \
467 __end_pci_fixups_suspend = .; \
468 __start_pci_fixups_suspend_late = .; \
469 KEEP(*(.pci_fixup_suspend_late)) \
470 __end_pci_fixups_suspend_late = .; \
471 } \
472 \
473 FW_LOADER_BUILT_IN_DATA \
474 TRACEDATA \
475 \
476 PRINTK_INDEX \
477 \
478 /* Kernel symbol table: Normal symbols */ \
479 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
480 __start___ksymtab = .; \
481 KEEP(*(SORT(___ksymtab+*))) \
482 __stop___ksymtab = .; \
483 } \
484 \
485 /* Kernel symbol table: GPL-only symbols */ \
486 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
487 __start___ksymtab_gpl = .; \
488 KEEP(*(SORT(___ksymtab_gpl+*))) \
489 __stop___ksymtab_gpl = .; \
490 } \
491 \
492 /* Kernel symbol table: Normal symbols */ \
493 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
494 __start___kcrctab = .; \
495 KEEP(*(SORT(___kcrctab+*))) \
496 __stop___kcrctab = .; \
497 } \
498 \
499 /* Kernel symbol table: GPL-only symbols */ \
500 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
501 __start___kcrctab_gpl = .; \
502 KEEP(*(SORT(___kcrctab_gpl+*))) \
503 __stop___kcrctab_gpl = .; \
504 } \
505 \
506 /* Kernel symbol table: strings */ \
507 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
508 *(__ksymtab_strings) \
509 } \
510 \
511 /* __*init sections */ \
512 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
513 *(.ref.rodata) \
514 MEM_KEEP(init.rodata) \
515 MEM_KEEP(exit.rodata) \
516 } \
517 \
518 /* Built-in module parameters. */ \
519 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
520 __start___param = .; \
521 KEEP(*(__param)) \
522 __stop___param = .; \
523 } \
524 \
525 /* Built-in module versions. */ \
526 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
527 __start___modver = .; \
528 KEEP(*(__modver)) \
529 __stop___modver = .; \
530 } \
531 \
532 RO_EXCEPTION_TABLE \
533 NOTES \
534 BTF \
535 \
536 . = ALIGN((align)); \
537 __end_rodata = .;
538
539
540/*
541 * .text..L.cfi.jumptable.* contain Control-Flow Integrity (CFI)
542 * jump table entries.
543 */
544#ifdef CONFIG_CFI_CLANG
545#define TEXT_CFI_JT \
546 ALIGN_FUNCTION(); \
547 __cfi_jt_start = .; \
548 *(.text..L.cfi.jumptable .text..L.cfi.jumptable.*) \
549 __cfi_jt_end = .;
550#else
551#define TEXT_CFI_JT
552#endif
553
554/*
555 * Non-instrumentable text section
556 */
557#define NOINSTR_TEXT \
558 ALIGN_FUNCTION(); \
559 __noinstr_text_start = .; \
560 *(.noinstr.text) \
561 __noinstr_text_end = .;
562
563/*
564 * .text section. Map to function alignment to avoid address changes
565 * during second ld run in second ld pass when generating System.map
566 *
567 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
568 * code elimination is enabled, so these sections should be converted
569 * to use ".." first.
570 */
571#define TEXT_TEXT \
572 ALIGN_FUNCTION(); \
573 *(.text.hot .text.hot.*) \
574 *(TEXT_MAIN .text.fixup) \
575 *(.text.unlikely .text.unlikely.*) \
576 *(.text.unknown .text.unknown.*) \
577 NOINSTR_TEXT \
578 *(.text..refcount) \
579 *(.ref.text) \
580 *(.text.asan.* .text.tsan.*) \
581 TEXT_CFI_JT \
582 MEM_KEEP(init.text*) \
583 MEM_KEEP(exit.text*) \
584
585
586/* sched.text is aling to function alignment to secure we have same
587 * address even at second ld pass when generating System.map */
588#define SCHED_TEXT \
589 ALIGN_FUNCTION(); \
590 __sched_text_start = .; \
591 *(.sched.text) \
592 __sched_text_end = .;
593
594/* spinlock.text is aling to function alignment to secure we have same
595 * address even at second ld pass when generating System.map */
596#define LOCK_TEXT \
597 ALIGN_FUNCTION(); \
598 __lock_text_start = .; \
599 *(.spinlock.text) \
600 __lock_text_end = .;
601
602#define CPUIDLE_TEXT \
603 ALIGN_FUNCTION(); \
604 __cpuidle_text_start = .; \
605 *(.cpuidle.text) \
606 __cpuidle_text_end = .;
607
608#define KPROBES_TEXT \
609 ALIGN_FUNCTION(); \
610 __kprobes_text_start = .; \
611 *(.kprobes.text) \
612 __kprobes_text_end = .;
613
614#define ENTRY_TEXT \
615 ALIGN_FUNCTION(); \
616 __entry_text_start = .; \
617 *(.entry.text) \
618 __entry_text_end = .;
619
620#define IRQENTRY_TEXT \
621 ALIGN_FUNCTION(); \
622 __irqentry_text_start = .; \
623 *(.irqentry.text) \
624 __irqentry_text_end = .;
625
626#define SOFTIRQENTRY_TEXT \
627 ALIGN_FUNCTION(); \
628 __softirqentry_text_start = .; \
629 *(.softirqentry.text) \
630 __softirqentry_text_end = .;
631
632#define STATIC_CALL_TEXT \
633 ALIGN_FUNCTION(); \
634 __static_call_text_start = .; \
635 *(.static_call.text) \
636 __static_call_text_end = .;
637
638/* Section used for early init (in .S files) */
639#define HEAD_TEXT KEEP(*(.head.text))
640
641#define HEAD_TEXT_SECTION \
642 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
643 HEAD_TEXT \
644 }
645
646/*
647 * Exception table
648 */
649#define EXCEPTION_TABLE(align) \
650 . = ALIGN(align); \
651 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
652 __start___ex_table = .; \
653 KEEP(*(__ex_table)) \
654 __stop___ex_table = .; \
655 }
656
657/*
658 * .BTF
659 */
660#ifdef CONFIG_DEBUG_INFO_BTF
661#define BTF \
662 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
663 __start_BTF = .; \
664 KEEP(*(.BTF)) \
665 __stop_BTF = .; \
666 } \
667 . = ALIGN(4); \
668 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
669 *(.BTF_ids) \
670 }
671#else
672#define BTF
673#endif
674
675/*
676 * Init task
677 */
678#define INIT_TASK_DATA_SECTION(align) \
679 . = ALIGN(align); \
680 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
681 INIT_TASK_DATA(align) \
682 }
683
684#ifdef CONFIG_CONSTRUCTORS
685#define KERNEL_CTORS() . = ALIGN(8); \
686 __ctors_start = .; \
687 KEEP(*(SORT(.ctors.*))) \
688 KEEP(*(.ctors)) \
689 KEEP(*(SORT(.init_array.*))) \
690 KEEP(*(.init_array)) \
691 __ctors_end = .;
692#else
693#define KERNEL_CTORS()
694#endif
695
696/* init and exit section handling */
697#define INIT_DATA \
698 KEEP(*(SORT(___kentry+*))) \
699 *(.init.data init.data.*) \
700 MEM_DISCARD(init.data*) \
701 KERNEL_CTORS() \
702 MCOUNT_REC() \
703 *(.init.rodata .init.rodata.*) \
704 FTRACE_EVENTS() \
705 TRACE_SYSCALLS() \
706 KPROBE_BLACKLIST() \
707 ERROR_INJECT_WHITELIST() \
708 MEM_DISCARD(init.rodata) \
709 CLK_OF_TABLES() \
710 RESERVEDMEM_OF_TABLES() \
711 TIMER_OF_TABLES() \
712 CPU_METHOD_OF_TABLES() \
713 CPUIDLE_METHOD_OF_TABLES() \
714 KERNEL_DTB() \
715 IRQCHIP_OF_MATCH_TABLE() \
716 ACPI_PROBE_TABLE(irqchip) \
717 ACPI_PROBE_TABLE(timer) \
718 THERMAL_TABLE(governor) \
719 EARLYCON_TABLE() \
720 LSM_TABLE() \
721 EARLY_LSM_TABLE() \
722 KUNIT_TABLE()
723
724#define INIT_TEXT \
725 *(.init.text .init.text.*) \
726 *(.text.startup) \
727 MEM_DISCARD(init.text*)
728
729#define EXIT_DATA \
730 *(.exit.data .exit.data.*) \
731 *(.fini_array .fini_array.*) \
732 *(.dtors .dtors.*) \
733 MEM_DISCARD(exit.data*) \
734 MEM_DISCARD(exit.rodata*)
735
736#define EXIT_TEXT \
737 *(.exit.text) \
738 *(.text.exit) \
739 MEM_DISCARD(exit.text)
740
741#define EXIT_CALL \
742 *(.exitcall.exit)
743
744/*
745 * bss (Block Started by Symbol) - uninitialized data
746 * zeroed during startup
747 */
748#define SBSS(sbss_align) \
749 . = ALIGN(sbss_align); \
750 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
751 *(.dynsbss) \
752 *(SBSS_MAIN) \
753 *(.scommon) \
754 }
755
756/*
757 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
758 * sections to the front of bss.
759 */
760#ifndef BSS_FIRST_SECTIONS
761#define BSS_FIRST_SECTIONS
762#endif
763
764#define BSS(bss_align) \
765 . = ALIGN(bss_align); \
766 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
767 BSS_FIRST_SECTIONS \
768 . = ALIGN(PAGE_SIZE); \
769 *(.bss..page_aligned) \
770 . = ALIGN(PAGE_SIZE); \
771 *(.dynbss) \
772 *(BSS_MAIN) \
773 *(COMMON) \
774 }
775
776/*
777 * DWARF debug sections.
778 * Symbols in the DWARF debugging sections are relative to
779 * the beginning of the section so we begin them at 0.
780 */
781#define DWARF_DEBUG \
782 /* DWARF 1 */ \
783 .debug 0 : { *(.debug) } \
784 .line 0 : { *(.line) } \
785 /* GNU DWARF 1 extensions */ \
786 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
787 .debug_sfnames 0 : { *(.debug_sfnames) } \
788 /* DWARF 1.1 and DWARF 2 */ \
789 .debug_aranges 0 : { *(.debug_aranges) } \
790 .debug_pubnames 0 : { *(.debug_pubnames) } \
791 /* DWARF 2 */ \
792 .debug_info 0 : { *(.debug_info \
793 .gnu.linkonce.wi.*) } \
794 .debug_abbrev 0 : { *(.debug_abbrev) } \
795 .debug_line 0 : { *(.debug_line) } \
796 .debug_frame 0 : { *(.debug_frame) } \
797 .debug_str 0 : { *(.debug_str) } \
798 .debug_loc 0 : { *(.debug_loc) } \
799 .debug_macinfo 0 : { *(.debug_macinfo) } \
800 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
801 /* DWARF 3 */ \
802 .debug_ranges 0 : { *(.debug_ranges) } \
803 /* SGI/MIPS DWARF 2 extensions */ \
804 .debug_weaknames 0 : { *(.debug_weaknames) } \
805 .debug_funcnames 0 : { *(.debug_funcnames) } \
806 .debug_typenames 0 : { *(.debug_typenames) } \
807 .debug_varnames 0 : { *(.debug_varnames) } \
808 /* GNU DWARF 2 extensions */ \
809 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
810 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
811 /* DWARF 4 */ \
812 .debug_types 0 : { *(.debug_types) } \
813 /* DWARF 5 */ \
814 .debug_addr 0 : { *(.debug_addr) } \
815 .debug_line_str 0 : { *(.debug_line_str) } \
816 .debug_loclists 0 : { *(.debug_loclists) } \
817 .debug_macro 0 : { *(.debug_macro) } \
818 .debug_names 0 : { *(.debug_names) } \
819 .debug_rnglists 0 : { *(.debug_rnglists) } \
820 .debug_str_offsets 0 : { *(.debug_str_offsets) }
821
822/* Stabs debugging sections. */
823#define STABS_DEBUG \
824 .stab 0 : { *(.stab) } \
825 .stabstr 0 : { *(.stabstr) } \
826 .stab.excl 0 : { *(.stab.excl) } \
827 .stab.exclstr 0 : { *(.stab.exclstr) } \
828 .stab.index 0 : { *(.stab.index) } \
829 .stab.indexstr 0 : { *(.stab.indexstr) }
830
831/* Required sections not related to debugging. */
832#define ELF_DETAILS \
833 .comment 0 : { *(.comment) } \
834 .symtab 0 : { *(.symtab) } \
835 .strtab 0 : { *(.strtab) } \
836 .shstrtab 0 : { *(.shstrtab) }
837
838#ifdef CONFIG_GENERIC_BUG
839#define BUG_TABLE \
840 . = ALIGN(8); \
841 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
842 __start___bug_table = .; \
843 KEEP(*(__bug_table)) \
844 __stop___bug_table = .; \
845 }
846#else
847#define BUG_TABLE
848#endif
849
850#ifdef CONFIG_UNWINDER_ORC
851#define ORC_UNWIND_TABLE \
852 . = ALIGN(4); \
853 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
854 __start_orc_unwind_ip = .; \
855 KEEP(*(.orc_unwind_ip)) \
856 __stop_orc_unwind_ip = .; \
857 } \
858 . = ALIGN(2); \
859 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
860 __start_orc_unwind = .; \
861 KEEP(*(.orc_unwind)) \
862 __stop_orc_unwind = .; \
863 } \
864 text_size = _etext - _stext; \
865 . = ALIGN(4); \
866 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
867 orc_lookup = .; \
868 . += (((text_size + LOOKUP_BLOCK_SIZE - 1) / \
869 LOOKUP_BLOCK_SIZE) + 1) * 4; \
870 orc_lookup_end = .; \
871 }
872#else
873#define ORC_UNWIND_TABLE
874#endif
875
876/* Built-in firmware blobs */
877#ifdef CONFIG_FW_LOADER
878#define FW_LOADER_BUILT_IN_DATA \
879 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
880 __start_builtin_fw = .; \
881 KEEP(*(.builtin_fw)) \
882 __end_builtin_fw = .; \
883 }
884#else
885#define FW_LOADER_BUILT_IN_DATA
886#endif
887
888#ifdef CONFIG_PM_TRACE
889#define TRACEDATA \
890 . = ALIGN(4); \
891 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
892 __tracedata_start = .; \
893 KEEP(*(.tracedata)) \
894 __tracedata_end = .; \
895 }
896#else
897#define TRACEDATA
898#endif
899
900#ifdef CONFIG_PRINTK_INDEX
901#define PRINTK_INDEX \
902 .printk_index : AT(ADDR(.printk_index) - LOAD_OFFSET) { \
903 __start_printk_index = .; \
904 *(.printk_index) \
905 __stop_printk_index = .; \
906 }
907#else
908#define PRINTK_INDEX
909#endif
910
911#define NOTES \
912 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
913 __start_notes = .; \
914 KEEP(*(.note.*)) \
915 __stop_notes = .; \
916 } NOTES_HEADERS \
917 NOTES_HEADERS_RESTORE
918
919#define INIT_SETUP(initsetup_align) \
920 . = ALIGN(initsetup_align); \
921 __setup_start = .; \
922 KEEP(*(.init.setup)) \
923 __setup_end = .;
924
925#define INIT_CALLS_LEVEL(level) \
926 __initcall##level##_start = .; \
927 KEEP(*(.initcall##level##.init)) \
928 KEEP(*(.initcall##level##s.init)) \
929
930#define INIT_CALLS \
931 __initcall_start = .; \
932 KEEP(*(.initcallearly.init)) \
933 INIT_CALLS_LEVEL(0) \
934 INIT_CALLS_LEVEL(1) \
935 INIT_CALLS_LEVEL(2) \
936 INIT_CALLS_LEVEL(3) \
937 INIT_CALLS_LEVEL(4) \
938 INIT_CALLS_LEVEL(5) \
939 INIT_CALLS_LEVEL(rootfs) \
940 INIT_CALLS_LEVEL(6) \
941 INIT_CALLS_LEVEL(7) \
942 __initcall_end = .;
943
944#define CON_INITCALL \
945 __con_initcall_start = .; \
946 KEEP(*(.con_initcall.init)) \
947 __con_initcall_end = .;
948
949/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
950#define KUNIT_TABLE() \
951 . = ALIGN(8); \
952 __kunit_suites_start = .; \
953 KEEP(*(.kunit_test_suites)) \
954 __kunit_suites_end = .;
955
956#ifdef CONFIG_BLK_DEV_INITRD
957#define INIT_RAM_FS \
958 . = ALIGN(4); \
959 __initramfs_start = .; \
960 KEEP(*(.init.ramfs)) \
961 . = ALIGN(8); \
962 KEEP(*(.init.ramfs.info))
963#else
964#define INIT_RAM_FS
965#endif
966
967/*
968 * Memory encryption operates on a page basis. Since we need to clear
969 * the memory encryption mask for this section, it needs to be aligned
970 * on a page boundary and be a page-size multiple in length.
971 *
972 * Note: We use a separate section so that only this section gets
973 * decrypted to avoid exposing more than we wish.
974 */
975#ifdef CONFIG_AMD_MEM_ENCRYPT
976#define PERCPU_DECRYPTED_SECTION \
977 . = ALIGN(PAGE_SIZE); \
978 *(.data..decrypted) \
979 *(.data..percpu..decrypted) \
980 . = ALIGN(PAGE_SIZE);
981#else
982#define PERCPU_DECRYPTED_SECTION
983#endif
984
985
986/*
987 * Default discarded sections.
988 *
989 * Some archs want to discard exit text/data at runtime rather than
990 * link time due to cross-section references such as alt instructions,
991 * bug table, eh_frame, etc. DISCARDS must be the last of output
992 * section definitions so that such archs put those in earlier section
993 * definitions.
994 */
995#ifdef RUNTIME_DISCARD_EXIT
996#define EXIT_DISCARDS
997#else
998#define EXIT_DISCARDS \
999 EXIT_TEXT \
1000 EXIT_DATA
1001#endif
1002
1003/*
1004 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
1005 * -fsanitize=thread produce unwanted sections (.eh_frame
1006 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
1007 * keep any .init_array.* sections.
1008 * https://bugs.llvm.org/show_bug.cgi?id=46478
1009 */
1010#if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN) || \
1011 defined(CONFIG_CFI_CLANG)
1012# ifdef CONFIG_CONSTRUCTORS
1013# define SANITIZER_DISCARDS \
1014 *(.eh_frame)
1015# else
1016# define SANITIZER_DISCARDS \
1017 *(.init_array) *(.init_array.*) \
1018 *(.eh_frame)
1019# endif
1020#else
1021# define SANITIZER_DISCARDS
1022#endif
1023
1024#define COMMON_DISCARDS \
1025 SANITIZER_DISCARDS \
1026 *(.discard) \
1027 *(.discard.*) \
1028 *(.modinfo) \
1029 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1030 *(.gnu.version*) \
1031
1032#define DISCARDS \
1033 /DISCARD/ : { \
1034 EXIT_DISCARDS \
1035 EXIT_CALL \
1036 COMMON_DISCARDS \
1037 }
1038
1039/**
1040 * PERCPU_INPUT - the percpu input sections
1041 * @cacheline: cacheline size
1042 *
1043 * The core percpu section names and core symbols which do not rely
1044 * directly upon load addresses.
1045 *
1046 * @cacheline is used to align subsections to avoid false cacheline
1047 * sharing between subsections for different purposes.
1048 */
1049#define PERCPU_INPUT(cacheline) \
1050 __per_cpu_start = .; \
1051 *(.data..percpu..first) \
1052 . = ALIGN(PAGE_SIZE); \
1053 *(.data..percpu..page_aligned) \
1054 . = ALIGN(cacheline); \
1055 *(.data..percpu..read_mostly) \
1056 . = ALIGN(cacheline); \
1057 *(.data..percpu) \
1058 *(.data..percpu..shared_aligned) \
1059 PERCPU_DECRYPTED_SECTION \
1060 __per_cpu_end = .;
1061
1062/**
1063 * PERCPU_VADDR - define output section for percpu area
1064 * @cacheline: cacheline size
1065 * @vaddr: explicit base address (optional)
1066 * @phdr: destination PHDR (optional)
1067 *
1068 * Macro which expands to output section for percpu area.
1069 *
1070 * @cacheline is used to align subsections to avoid false cacheline
1071 * sharing between subsections for different purposes.
1072 *
1073 * If @vaddr is not blank, it specifies explicit base address and all
1074 * percpu symbols will be offset from the given address. If blank,
1075 * @vaddr always equals @laddr + LOAD_OFFSET.
1076 *
1077 * @phdr defines the output PHDR to use if not blank. Be warned that
1078 * output PHDR is sticky. If @phdr is specified, the next output
1079 * section in the linker script will go there too. @phdr should have
1080 * a leading colon.
1081 *
1082 * Note that this macros defines __per_cpu_load as an absolute symbol.
1083 * If there is no need to put the percpu section at a predetermined
1084 * address, use PERCPU_SECTION.
1085 */
1086#define PERCPU_VADDR(cacheline, vaddr, phdr) \
1087 __per_cpu_load = .; \
1088 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1089 PERCPU_INPUT(cacheline) \
1090 } phdr \
1091 . = __per_cpu_load + SIZEOF(.data..percpu);
1092
1093/**
1094 * PERCPU_SECTION - define output section for percpu area, simple version
1095 * @cacheline: cacheline size
1096 *
1097 * Align to PAGE_SIZE and outputs output section for percpu area. This
1098 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1099 * __per_cpu_start will be identical.
1100 *
1101 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1102 * except that __per_cpu_load is defined as a relative symbol against
1103 * .data..percpu which is required for relocatable x86_32 configuration.
1104 */
1105#define PERCPU_SECTION(cacheline) \
1106 . = ALIGN(PAGE_SIZE); \
1107 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1108 __per_cpu_load = .; \
1109 PERCPU_INPUT(cacheline) \
1110 }
1111
1112
1113/*
1114 * Definition of the high level *_SECTION macros
1115 * They will fit only a subset of the architectures
1116 */
1117
1118
1119/*
1120 * Writeable data.
1121 * All sections are combined in a single .data section.
1122 * The sections following CONSTRUCTORS are arranged so their
1123 * typical alignment matches.
1124 * A cacheline is typical/always less than a PAGE_SIZE so
1125 * the sections that has this restriction (or similar)
1126 * is located before the ones requiring PAGE_SIZE alignment.
1127 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1128 * matches the requirement of PAGE_ALIGNED_DATA.
1129 *
1130 * use 0 as page_align if page_aligned data is not used */
1131#define RW_DATA(cacheline, pagealigned, inittask) \
1132 . = ALIGN(PAGE_SIZE); \
1133 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1134 INIT_TASK_DATA(inittask) \
1135 NOSAVE_DATA \
1136 PAGE_ALIGNED_DATA(pagealigned) \
1137 CACHELINE_ALIGNED_DATA(cacheline) \
1138 READ_MOSTLY_DATA(cacheline) \
1139 DATA_DATA \
1140 CONSTRUCTORS \
1141 } \
1142 BUG_TABLE \
1143
1144#define INIT_TEXT_SECTION(inittext_align) \
1145 . = ALIGN(inittext_align); \
1146 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1147 _sinittext = .; \
1148 INIT_TEXT \
1149 _einittext = .; \
1150 }
1151
1152#define INIT_DATA_SECTION(initsetup_align) \
1153 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1154 INIT_DATA \
1155 INIT_SETUP(initsetup_align) \
1156 INIT_CALLS \
1157 CON_INITCALL \
1158 INIT_RAM_FS \
1159 }
1160
1161#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1162 . = ALIGN(sbss_align); \
1163 __bss_start = .; \
1164 SBSS(sbss_align) \
1165 BSS(bss_align) \
1166 . = ALIGN(stop_align); \
1167 __bss_stop = .;