Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#ifndef LOAD_OFFSET
54#define LOAD_OFFSET 0
55#endif
56
57/*
58 * Only some architectures want to have the .notes segment visible in
59 * a separate PT_NOTE ELF Program Header. When this happens, it needs
60 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
61 * Program Headers. In this case, though, the PT_LOAD needs to be made
62 * the default again so that all the following sections don't also end
63 * up in the PT_NOTE Program Header.
64 */
65#ifdef EMITS_PT_NOTE
66#define NOTES_HEADERS :text :note
67#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
68#else
69#define NOTES_HEADERS
70#define NOTES_HEADERS_RESTORE
71#endif
72
73/*
74 * Some architectures have non-executable read-only exception tables.
75 * They can be added to the RO_DATA segment by specifying their desired
76 * alignment.
77 */
78#ifdef RO_EXCEPTION_TABLE_ALIGN
79#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
80#else
81#define RO_EXCEPTION_TABLE
82#endif
83
84/* Align . to a 8 byte boundary equals to maximum function alignment. */
85#define ALIGN_FUNCTION() . = ALIGN(8)
86
87/*
88 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
89 * generates .data.identifier sections, which need to be pulled in with
90 * .data. We don't want to pull in .data..other sections, which Linux
91 * has defined. Same for text and bss.
92 *
93 * With LTO_CLANG, the linker also splits sections by default, so we need
94 * these macros to combine the sections during the final link.
95 *
96 * RODATA_MAIN is not used because existing code already defines .rodata.x
97 * sections to be brought in with rodata.
98 */
99#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
100#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
101#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
102#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
103#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
104#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..compoundliteral*
105#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
106#else
107#define TEXT_MAIN .text
108#define DATA_MAIN .data
109#define SDATA_MAIN .sdata
110#define RODATA_MAIN .rodata
111#define BSS_MAIN .bss
112#define SBSS_MAIN .sbss
113#endif
114
115/*
116 * GCC 4.5 and later have a 32 bytes section alignment for structures.
117 * Except GCC 4.9, that feels the need to align on 64 bytes.
118 */
119#if __GNUC__ == 4 && __GNUC_MINOR__ == 9
120#define STRUCT_ALIGNMENT 64
121#else
122#define STRUCT_ALIGNMENT 32
123#endif
124#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
125
126/*
127 * The order of the sched class addresses are important, as they are
128 * used to determine the order of the priority of each sched class in
129 * relation to each other.
130 */
131#define SCHED_DATA \
132 STRUCT_ALIGN(); \
133 __begin_sched_classes = .; \
134 *(__idle_sched_class) \
135 *(__fair_sched_class) \
136 *(__rt_sched_class) \
137 *(__dl_sched_class) \
138 *(__stop_sched_class) \
139 __end_sched_classes = .;
140
141/* The actual configuration determine if the init/exit sections
142 * are handled as text/data or they can be discarded (which
143 * often happens at runtime)
144 */
145#ifdef CONFIG_HOTPLUG_CPU
146#define CPU_KEEP(sec) *(.cpu##sec)
147#define CPU_DISCARD(sec)
148#else
149#define CPU_KEEP(sec)
150#define CPU_DISCARD(sec) *(.cpu##sec)
151#endif
152
153#if defined(CONFIG_MEMORY_HOTPLUG)
154#define MEM_KEEP(sec) *(.mem##sec)
155#define MEM_DISCARD(sec)
156#else
157#define MEM_KEEP(sec)
158#define MEM_DISCARD(sec) *(.mem##sec)
159#endif
160
161#ifdef CONFIG_FTRACE_MCOUNT_RECORD
162/*
163 * The ftrace call sites are logged to a section whose name depends on the
164 * compiler option used. A given kernel image will only use one, AKA
165 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
166 * dependencies for FTRACE_CALLSITE_SECTION's definition.
167 *
168 * Need to also make ftrace_stub_graph point to ftrace_stub
169 * so that the same stub location may have different protocols
170 * and not mess up with C verifiers.
171 */
172#define MCOUNT_REC() . = ALIGN(8); \
173 __start_mcount_loc = .; \
174 KEEP(*(__mcount_loc)) \
175 KEEP(*(__patchable_function_entries)) \
176 __stop_mcount_loc = .; \
177 ftrace_stub_graph = ftrace_stub;
178#else
179# ifdef CONFIG_FUNCTION_TRACER
180# define MCOUNT_REC() ftrace_stub_graph = ftrace_stub;
181# else
182# define MCOUNT_REC()
183# endif
184#endif
185
186#ifdef CONFIG_TRACE_BRANCH_PROFILING
187#define LIKELY_PROFILE() __start_annotated_branch_profile = .; \
188 KEEP(*(_ftrace_annotated_branch)) \
189 __stop_annotated_branch_profile = .;
190#else
191#define LIKELY_PROFILE()
192#endif
193
194#ifdef CONFIG_PROFILE_ALL_BRANCHES
195#define BRANCH_PROFILE() __start_branch_profile = .; \
196 KEEP(*(_ftrace_branch)) \
197 __stop_branch_profile = .;
198#else
199#define BRANCH_PROFILE()
200#endif
201
202#ifdef CONFIG_KPROBES
203#define KPROBE_BLACKLIST() . = ALIGN(8); \
204 __start_kprobe_blacklist = .; \
205 KEEP(*(_kprobe_blacklist)) \
206 __stop_kprobe_blacklist = .;
207#else
208#define KPROBE_BLACKLIST()
209#endif
210
211#ifdef CONFIG_FUNCTION_ERROR_INJECTION
212#define ERROR_INJECT_WHITELIST() STRUCT_ALIGN(); \
213 __start_error_injection_whitelist = .; \
214 KEEP(*(_error_injection_whitelist)) \
215 __stop_error_injection_whitelist = .;
216#else
217#define ERROR_INJECT_WHITELIST()
218#endif
219
220#ifdef CONFIG_EVENT_TRACING
221#define FTRACE_EVENTS() . = ALIGN(8); \
222 __start_ftrace_events = .; \
223 KEEP(*(_ftrace_events)) \
224 __stop_ftrace_events = .; \
225 __start_ftrace_eval_maps = .; \
226 KEEP(*(_ftrace_eval_map)) \
227 __stop_ftrace_eval_maps = .;
228#else
229#define FTRACE_EVENTS()
230#endif
231
232#ifdef CONFIG_TRACING
233#define TRACE_PRINTKS() __start___trace_bprintk_fmt = .; \
234 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
235 __stop___trace_bprintk_fmt = .;
236#define TRACEPOINT_STR() __start___tracepoint_str = .; \
237 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
238 __stop___tracepoint_str = .;
239#else
240#define TRACE_PRINTKS()
241#define TRACEPOINT_STR()
242#endif
243
244#ifdef CONFIG_FTRACE_SYSCALLS
245#define TRACE_SYSCALLS() . = ALIGN(8); \
246 __start_syscalls_metadata = .; \
247 KEEP(*(__syscalls_metadata)) \
248 __stop_syscalls_metadata = .;
249#else
250#define TRACE_SYSCALLS()
251#endif
252
253#ifdef CONFIG_BPF_EVENTS
254#define BPF_RAW_TP() STRUCT_ALIGN(); \
255 __start__bpf_raw_tp = .; \
256 KEEP(*(__bpf_raw_tp_map)) \
257 __stop__bpf_raw_tp = .;
258#else
259#define BPF_RAW_TP()
260#endif
261
262#ifdef CONFIG_SERIAL_EARLYCON
263#define EARLYCON_TABLE() . = ALIGN(8); \
264 __earlycon_table = .; \
265 KEEP(*(__earlycon_table)) \
266 __earlycon_table_end = .;
267#else
268#define EARLYCON_TABLE()
269#endif
270
271#ifdef CONFIG_SECURITY
272#define LSM_TABLE() . = ALIGN(8); \
273 __start_lsm_info = .; \
274 KEEP(*(.lsm_info.init)) \
275 __end_lsm_info = .;
276#define EARLY_LSM_TABLE() . = ALIGN(8); \
277 __start_early_lsm_info = .; \
278 KEEP(*(.early_lsm_info.init)) \
279 __end_early_lsm_info = .;
280#else
281#define LSM_TABLE()
282#define EARLY_LSM_TABLE()
283#endif
284
285#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
286#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
287#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
288#define _OF_TABLE_0(name)
289#define _OF_TABLE_1(name) \
290 . = ALIGN(8); \
291 __##name##_of_table = .; \
292 KEEP(*(__##name##_of_table)) \
293 KEEP(*(__##name##_of_table_end))
294
295#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
296#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
297#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
298#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
299#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
300#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
301
302#ifdef CONFIG_ACPI
303#define ACPI_PROBE_TABLE(name) \
304 . = ALIGN(8); \
305 __##name##_acpi_probe_table = .; \
306 KEEP(*(__##name##_acpi_probe_table)) \
307 __##name##_acpi_probe_table_end = .;
308#else
309#define ACPI_PROBE_TABLE(name)
310#endif
311
312#ifdef CONFIG_THERMAL
313#define THERMAL_TABLE(name) \
314 . = ALIGN(8); \
315 __##name##_thermal_table = .; \
316 KEEP(*(__##name##_thermal_table)) \
317 __##name##_thermal_table_end = .;
318#else
319#define THERMAL_TABLE(name)
320#endif
321
322#ifdef CONFIG_DTPM
323#define DTPM_TABLE() \
324 . = ALIGN(8); \
325 __dtpm_table = .; \
326 KEEP(*(__dtpm_table)) \
327 __dtpm_table_end = .;
328#else
329#define DTPM_TABLE()
330#endif
331
332#define KERNEL_DTB() \
333 STRUCT_ALIGN(); \
334 __dtb_start = .; \
335 KEEP(*(.dtb.init.rodata)) \
336 __dtb_end = .;
337
338/*
339 * .data section
340 */
341#define DATA_DATA \
342 *(.xiptext) \
343 *(DATA_MAIN) \
344 *(.ref.data) \
345 *(.data..shared_aligned) /* percpu related */ \
346 MEM_KEEP(init.data*) \
347 MEM_KEEP(exit.data*) \
348 *(.data.unlikely) \
349 __start_once = .; \
350 *(.data.once) \
351 __end_once = .; \
352 STRUCT_ALIGN(); \
353 *(__tracepoints) \
354 /* implement dynamic printk debug */ \
355 . = ALIGN(8); \
356 __start___dyndbg = .; \
357 KEEP(*(__dyndbg)) \
358 __stop___dyndbg = .; \
359 LIKELY_PROFILE() \
360 BRANCH_PROFILE() \
361 TRACE_PRINTKS() \
362 BPF_RAW_TP() \
363 TRACEPOINT_STR()
364
365/*
366 * Data section helpers
367 */
368#define NOSAVE_DATA \
369 . = ALIGN(PAGE_SIZE); \
370 __nosave_begin = .; \
371 *(.data..nosave) \
372 . = ALIGN(PAGE_SIZE); \
373 __nosave_end = .;
374
375#define PAGE_ALIGNED_DATA(page_align) \
376 . = ALIGN(page_align); \
377 *(.data..page_aligned) \
378 . = ALIGN(page_align);
379
380#define READ_MOSTLY_DATA(align) \
381 . = ALIGN(align); \
382 *(.data..read_mostly) \
383 . = ALIGN(align);
384
385#define CACHELINE_ALIGNED_DATA(align) \
386 . = ALIGN(align); \
387 *(.data..cacheline_aligned)
388
389#define INIT_TASK_DATA(align) \
390 . = ALIGN(align); \
391 __start_init_task = .; \
392 init_thread_union = .; \
393 init_stack = .; \
394 KEEP(*(.data..init_task)) \
395 KEEP(*(.data..init_thread_info)) \
396 . = __start_init_task + THREAD_SIZE; \
397 __end_init_task = .;
398
399#define JUMP_TABLE_DATA \
400 . = ALIGN(8); \
401 __start___jump_table = .; \
402 KEEP(*(__jump_table)) \
403 __stop___jump_table = .;
404
405#define STATIC_CALL_DATA \
406 . = ALIGN(8); \
407 __start_static_call_sites = .; \
408 KEEP(*(.static_call_sites)) \
409 __stop_static_call_sites = .; \
410 __start_static_call_tramp_key = .; \
411 KEEP(*(.static_call_tramp_key)) \
412 __stop_static_call_tramp_key = .;
413
414/*
415 * Allow architectures to handle ro_after_init data on their
416 * own by defining an empty RO_AFTER_INIT_DATA.
417 */
418#ifndef RO_AFTER_INIT_DATA
419#define RO_AFTER_INIT_DATA \
420 . = ALIGN(8); \
421 __start_ro_after_init = .; \
422 *(.data..ro_after_init) \
423 JUMP_TABLE_DATA \
424 STATIC_CALL_DATA \
425 __end_ro_after_init = .;
426#endif
427
428/*
429 * Read only Data
430 */
431#define RO_DATA(align) \
432 . = ALIGN((align)); \
433 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
434 __start_rodata = .; \
435 *(.rodata) *(.rodata.*) \
436 SCHED_DATA \
437 RO_AFTER_INIT_DATA /* Read only after init */ \
438 . = ALIGN(8); \
439 __start___tracepoints_ptrs = .; \
440 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
441 __stop___tracepoints_ptrs = .; \
442 *(__tracepoints_strings)/* Tracepoints: strings */ \
443 } \
444 \
445 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
446 *(.rodata1) \
447 } \
448 \
449 /* PCI quirks */ \
450 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
451 __start_pci_fixups_early = .; \
452 KEEP(*(.pci_fixup_early)) \
453 __end_pci_fixups_early = .; \
454 __start_pci_fixups_header = .; \
455 KEEP(*(.pci_fixup_header)) \
456 __end_pci_fixups_header = .; \
457 __start_pci_fixups_final = .; \
458 KEEP(*(.pci_fixup_final)) \
459 __end_pci_fixups_final = .; \
460 __start_pci_fixups_enable = .; \
461 KEEP(*(.pci_fixup_enable)) \
462 __end_pci_fixups_enable = .; \
463 __start_pci_fixups_resume = .; \
464 KEEP(*(.pci_fixup_resume)) \
465 __end_pci_fixups_resume = .; \
466 __start_pci_fixups_resume_early = .; \
467 KEEP(*(.pci_fixup_resume_early)) \
468 __end_pci_fixups_resume_early = .; \
469 __start_pci_fixups_suspend = .; \
470 KEEP(*(.pci_fixup_suspend)) \
471 __end_pci_fixups_suspend = .; \
472 __start_pci_fixups_suspend_late = .; \
473 KEEP(*(.pci_fixup_suspend_late)) \
474 __end_pci_fixups_suspend_late = .; \
475 } \
476 \
477 /* Built-in firmware blobs */ \
478 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
479 __start_builtin_fw = .; \
480 KEEP(*(.builtin_fw)) \
481 __end_builtin_fw = .; \
482 } \
483 \
484 TRACEDATA \
485 \
486 PRINTK_INDEX \
487 \
488 /* Kernel symbol table: Normal symbols */ \
489 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
490 __start___ksymtab = .; \
491 KEEP(*(SORT(___ksymtab+*))) \
492 __stop___ksymtab = .; \
493 } \
494 \
495 /* Kernel symbol table: GPL-only symbols */ \
496 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
497 __start___ksymtab_gpl = .; \
498 KEEP(*(SORT(___ksymtab_gpl+*))) \
499 __stop___ksymtab_gpl = .; \
500 } \
501 \
502 /* Kernel symbol table: Normal symbols */ \
503 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
504 __start___kcrctab = .; \
505 KEEP(*(SORT(___kcrctab+*))) \
506 __stop___kcrctab = .; \
507 } \
508 \
509 /* Kernel symbol table: GPL-only symbols */ \
510 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
511 __start___kcrctab_gpl = .; \
512 KEEP(*(SORT(___kcrctab_gpl+*))) \
513 __stop___kcrctab_gpl = .; \
514 } \
515 \
516 /* Kernel symbol table: strings */ \
517 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
518 *(__ksymtab_strings) \
519 } \
520 \
521 /* __*init sections */ \
522 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
523 *(.ref.rodata) \
524 MEM_KEEP(init.rodata) \
525 MEM_KEEP(exit.rodata) \
526 } \
527 \
528 /* Built-in module parameters. */ \
529 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
530 __start___param = .; \
531 KEEP(*(__param)) \
532 __stop___param = .; \
533 } \
534 \
535 /* Built-in module versions. */ \
536 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
537 __start___modver = .; \
538 KEEP(*(__modver)) \
539 __stop___modver = .; \
540 } \
541 \
542 RO_EXCEPTION_TABLE \
543 NOTES \
544 BTF \
545 \
546 . = ALIGN((align)); \
547 __end_rodata = .;
548
549
550/*
551 * .text..L.cfi.jumptable.* contain Control-Flow Integrity (CFI)
552 * jump table entries.
553 */
554#ifdef CONFIG_CFI_CLANG
555#define TEXT_CFI_JT \
556 . = ALIGN(PMD_SIZE); \
557 __cfi_jt_start = .; \
558 *(.text..L.cfi.jumptable .text..L.cfi.jumptable.*) \
559 . = ALIGN(PMD_SIZE); \
560 __cfi_jt_end = .;
561#else
562#define TEXT_CFI_JT
563#endif
564
565/*
566 * Non-instrumentable text section
567 */
568#define NOINSTR_TEXT \
569 ALIGN_FUNCTION(); \
570 __noinstr_text_start = .; \
571 *(.noinstr.text) \
572 __noinstr_text_end = .;
573
574/*
575 * .text section. Map to function alignment to avoid address changes
576 * during second ld run in second ld pass when generating System.map
577 *
578 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
579 * code elimination is enabled, so these sections should be converted
580 * to use ".." first.
581 */
582#define TEXT_TEXT \
583 ALIGN_FUNCTION(); \
584 *(.text.hot .text.hot.*) \
585 *(TEXT_MAIN .text.fixup) \
586 *(.text.unlikely .text.unlikely.*) \
587 *(.text.unknown .text.unknown.*) \
588 NOINSTR_TEXT \
589 *(.text..refcount) \
590 *(.ref.text) \
591 *(.text.asan.* .text.tsan.*) \
592 TEXT_CFI_JT \
593 MEM_KEEP(init.text*) \
594 MEM_KEEP(exit.text*) \
595
596
597/* sched.text is aling to function alignment to secure we have same
598 * address even at second ld pass when generating System.map */
599#define SCHED_TEXT \
600 ALIGN_FUNCTION(); \
601 __sched_text_start = .; \
602 *(.sched.text) \
603 __sched_text_end = .;
604
605/* spinlock.text is aling to function alignment to secure we have same
606 * address even at second ld pass when generating System.map */
607#define LOCK_TEXT \
608 ALIGN_FUNCTION(); \
609 __lock_text_start = .; \
610 *(.spinlock.text) \
611 __lock_text_end = .;
612
613#define CPUIDLE_TEXT \
614 ALIGN_FUNCTION(); \
615 __cpuidle_text_start = .; \
616 *(.cpuidle.text) \
617 __cpuidle_text_end = .;
618
619#define KPROBES_TEXT \
620 ALIGN_FUNCTION(); \
621 __kprobes_text_start = .; \
622 *(.kprobes.text) \
623 __kprobes_text_end = .;
624
625#define ENTRY_TEXT \
626 ALIGN_FUNCTION(); \
627 __entry_text_start = .; \
628 *(.entry.text) \
629 __entry_text_end = .;
630
631#define IRQENTRY_TEXT \
632 ALIGN_FUNCTION(); \
633 __irqentry_text_start = .; \
634 *(.irqentry.text) \
635 __irqentry_text_end = .;
636
637#define SOFTIRQENTRY_TEXT \
638 ALIGN_FUNCTION(); \
639 __softirqentry_text_start = .; \
640 *(.softirqentry.text) \
641 __softirqentry_text_end = .;
642
643#define STATIC_CALL_TEXT \
644 ALIGN_FUNCTION(); \
645 __static_call_text_start = .; \
646 *(.static_call.text) \
647 __static_call_text_end = .;
648
649/* Section used for early init (in .S files) */
650#define HEAD_TEXT KEEP(*(.head.text))
651
652#define HEAD_TEXT_SECTION \
653 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
654 HEAD_TEXT \
655 }
656
657/*
658 * Exception table
659 */
660#define EXCEPTION_TABLE(align) \
661 . = ALIGN(align); \
662 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
663 __start___ex_table = .; \
664 KEEP(*(__ex_table)) \
665 __stop___ex_table = .; \
666 }
667
668/*
669 * .BTF
670 */
671#ifdef CONFIG_DEBUG_INFO_BTF
672#define BTF \
673 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
674 __start_BTF = .; \
675 KEEP(*(.BTF)) \
676 __stop_BTF = .; \
677 } \
678 . = ALIGN(4); \
679 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
680 *(.BTF_ids) \
681 }
682#else
683#define BTF
684#endif
685
686/*
687 * Init task
688 */
689#define INIT_TASK_DATA_SECTION(align) \
690 . = ALIGN(align); \
691 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
692 INIT_TASK_DATA(align) \
693 }
694
695#ifdef CONFIG_CONSTRUCTORS
696#define KERNEL_CTORS() . = ALIGN(8); \
697 __ctors_start = .; \
698 KEEP(*(SORT(.ctors.*))) \
699 KEEP(*(.ctors)) \
700 KEEP(*(SORT(.init_array.*))) \
701 KEEP(*(.init_array)) \
702 __ctors_end = .;
703#else
704#define KERNEL_CTORS()
705#endif
706
707/* init and exit section handling */
708#define INIT_DATA \
709 KEEP(*(SORT(___kentry+*))) \
710 *(.init.data init.data.*) \
711 MEM_DISCARD(init.data*) \
712 KERNEL_CTORS() \
713 MCOUNT_REC() \
714 *(.init.rodata .init.rodata.*) \
715 FTRACE_EVENTS() \
716 TRACE_SYSCALLS() \
717 KPROBE_BLACKLIST() \
718 ERROR_INJECT_WHITELIST() \
719 MEM_DISCARD(init.rodata) \
720 CLK_OF_TABLES() \
721 RESERVEDMEM_OF_TABLES() \
722 TIMER_OF_TABLES() \
723 CPU_METHOD_OF_TABLES() \
724 CPUIDLE_METHOD_OF_TABLES() \
725 KERNEL_DTB() \
726 IRQCHIP_OF_MATCH_TABLE() \
727 ACPI_PROBE_TABLE(irqchip) \
728 ACPI_PROBE_TABLE(timer) \
729 THERMAL_TABLE(governor) \
730 DTPM_TABLE() \
731 EARLYCON_TABLE() \
732 LSM_TABLE() \
733 EARLY_LSM_TABLE() \
734 KUNIT_TABLE()
735
736#define INIT_TEXT \
737 *(.init.text .init.text.*) \
738 *(.text.startup) \
739 MEM_DISCARD(init.text*)
740
741#define EXIT_DATA \
742 *(.exit.data .exit.data.*) \
743 *(.fini_array .fini_array.*) \
744 *(.dtors .dtors.*) \
745 MEM_DISCARD(exit.data*) \
746 MEM_DISCARD(exit.rodata*)
747
748#define EXIT_TEXT \
749 *(.exit.text) \
750 *(.text.exit) \
751 MEM_DISCARD(exit.text)
752
753#define EXIT_CALL \
754 *(.exitcall.exit)
755
756/*
757 * bss (Block Started by Symbol) - uninitialized data
758 * zeroed during startup
759 */
760#define SBSS(sbss_align) \
761 . = ALIGN(sbss_align); \
762 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
763 *(.dynsbss) \
764 *(SBSS_MAIN) \
765 *(.scommon) \
766 }
767
768/*
769 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
770 * sections to the front of bss.
771 */
772#ifndef BSS_FIRST_SECTIONS
773#define BSS_FIRST_SECTIONS
774#endif
775
776#define BSS(bss_align) \
777 . = ALIGN(bss_align); \
778 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
779 BSS_FIRST_SECTIONS \
780 . = ALIGN(PAGE_SIZE); \
781 *(.bss..page_aligned) \
782 . = ALIGN(PAGE_SIZE); \
783 *(.dynbss) \
784 *(BSS_MAIN) \
785 *(COMMON) \
786 }
787
788/*
789 * DWARF debug sections.
790 * Symbols in the DWARF debugging sections are relative to
791 * the beginning of the section so we begin them at 0.
792 */
793#define DWARF_DEBUG \
794 /* DWARF 1 */ \
795 .debug 0 : { *(.debug) } \
796 .line 0 : { *(.line) } \
797 /* GNU DWARF 1 extensions */ \
798 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
799 .debug_sfnames 0 : { *(.debug_sfnames) } \
800 /* DWARF 1.1 and DWARF 2 */ \
801 .debug_aranges 0 : { *(.debug_aranges) } \
802 .debug_pubnames 0 : { *(.debug_pubnames) } \
803 /* DWARF 2 */ \
804 .debug_info 0 : { *(.debug_info \
805 .gnu.linkonce.wi.*) } \
806 .debug_abbrev 0 : { *(.debug_abbrev) } \
807 .debug_line 0 : { *(.debug_line) } \
808 .debug_frame 0 : { *(.debug_frame) } \
809 .debug_str 0 : { *(.debug_str) } \
810 .debug_loc 0 : { *(.debug_loc) } \
811 .debug_macinfo 0 : { *(.debug_macinfo) } \
812 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
813 /* DWARF 3 */ \
814 .debug_ranges 0 : { *(.debug_ranges) } \
815 /* SGI/MIPS DWARF 2 extensions */ \
816 .debug_weaknames 0 : { *(.debug_weaknames) } \
817 .debug_funcnames 0 : { *(.debug_funcnames) } \
818 .debug_typenames 0 : { *(.debug_typenames) } \
819 .debug_varnames 0 : { *(.debug_varnames) } \
820 /* GNU DWARF 2 extensions */ \
821 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
822 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
823 /* DWARF 4 */ \
824 .debug_types 0 : { *(.debug_types) } \
825 /* DWARF 5 */ \
826 .debug_addr 0 : { *(.debug_addr) } \
827 .debug_line_str 0 : { *(.debug_line_str) } \
828 .debug_loclists 0 : { *(.debug_loclists) } \
829 .debug_macro 0 : { *(.debug_macro) } \
830 .debug_names 0 : { *(.debug_names) } \
831 .debug_rnglists 0 : { *(.debug_rnglists) } \
832 .debug_str_offsets 0 : { *(.debug_str_offsets) }
833
834/* Stabs debugging sections. */
835#define STABS_DEBUG \
836 .stab 0 : { *(.stab) } \
837 .stabstr 0 : { *(.stabstr) } \
838 .stab.excl 0 : { *(.stab.excl) } \
839 .stab.exclstr 0 : { *(.stab.exclstr) } \
840 .stab.index 0 : { *(.stab.index) } \
841 .stab.indexstr 0 : { *(.stab.indexstr) }
842
843/* Required sections not related to debugging. */
844#define ELF_DETAILS \
845 .comment 0 : { *(.comment) } \
846 .symtab 0 : { *(.symtab) } \
847 .strtab 0 : { *(.strtab) } \
848 .shstrtab 0 : { *(.shstrtab) }
849
850#ifdef CONFIG_GENERIC_BUG
851#define BUG_TABLE \
852 . = ALIGN(8); \
853 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
854 __start___bug_table = .; \
855 KEEP(*(__bug_table)) \
856 __stop___bug_table = .; \
857 }
858#else
859#define BUG_TABLE
860#endif
861
862#ifdef CONFIG_UNWINDER_ORC
863#define ORC_UNWIND_TABLE \
864 . = ALIGN(4); \
865 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
866 __start_orc_unwind_ip = .; \
867 KEEP(*(.orc_unwind_ip)) \
868 __stop_orc_unwind_ip = .; \
869 } \
870 . = ALIGN(2); \
871 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
872 __start_orc_unwind = .; \
873 KEEP(*(.orc_unwind)) \
874 __stop_orc_unwind = .; \
875 } \
876 . = ALIGN(4); \
877 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
878 orc_lookup = .; \
879 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) / \
880 LOOKUP_BLOCK_SIZE) + 1) * 4; \
881 orc_lookup_end = .; \
882 }
883#else
884#define ORC_UNWIND_TABLE
885#endif
886
887#ifdef CONFIG_PM_TRACE
888#define TRACEDATA \
889 . = ALIGN(4); \
890 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
891 __tracedata_start = .; \
892 KEEP(*(.tracedata)) \
893 __tracedata_end = .; \
894 }
895#else
896#define TRACEDATA
897#endif
898
899#ifdef CONFIG_PRINTK_INDEX
900#define PRINTK_INDEX \
901 .printk_index : AT(ADDR(.printk_index) - LOAD_OFFSET) { \
902 __start_printk_index = .; \
903 *(.printk_index) \
904 __stop_printk_index = .; \
905 }
906#else
907#define PRINTK_INDEX
908#endif
909
910#define NOTES \
911 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
912 __start_notes = .; \
913 KEEP(*(.note.*)) \
914 __stop_notes = .; \
915 } NOTES_HEADERS \
916 NOTES_HEADERS_RESTORE
917
918#define INIT_SETUP(initsetup_align) \
919 . = ALIGN(initsetup_align); \
920 __setup_start = .; \
921 KEEP(*(.init.setup)) \
922 __setup_end = .;
923
924#define INIT_CALLS_LEVEL(level) \
925 __initcall##level##_start = .; \
926 KEEP(*(.initcall##level##.init)) \
927 KEEP(*(.initcall##level##s.init)) \
928
929#define INIT_CALLS \
930 __initcall_start = .; \
931 KEEP(*(.initcallearly.init)) \
932 INIT_CALLS_LEVEL(0) \
933 INIT_CALLS_LEVEL(1) \
934 INIT_CALLS_LEVEL(2) \
935 INIT_CALLS_LEVEL(3) \
936 INIT_CALLS_LEVEL(4) \
937 INIT_CALLS_LEVEL(5) \
938 INIT_CALLS_LEVEL(rootfs) \
939 INIT_CALLS_LEVEL(6) \
940 INIT_CALLS_LEVEL(7) \
941 __initcall_end = .;
942
943#define CON_INITCALL \
944 __con_initcall_start = .; \
945 KEEP(*(.con_initcall.init)) \
946 __con_initcall_end = .;
947
948/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
949#define KUNIT_TABLE() \
950 . = ALIGN(8); \
951 __kunit_suites_start = .; \
952 KEEP(*(.kunit_test_suites)) \
953 __kunit_suites_end = .;
954
955#ifdef CONFIG_BLK_DEV_INITRD
956#define INIT_RAM_FS \
957 . = ALIGN(4); \
958 __initramfs_start = .; \
959 KEEP(*(.init.ramfs)) \
960 . = ALIGN(8); \
961 KEEP(*(.init.ramfs.info))
962#else
963#define INIT_RAM_FS
964#endif
965
966/*
967 * Memory encryption operates on a page basis. Since we need to clear
968 * the memory encryption mask for this section, it needs to be aligned
969 * on a page boundary and be a page-size multiple in length.
970 *
971 * Note: We use a separate section so that only this section gets
972 * decrypted to avoid exposing more than we wish.
973 */
974#ifdef CONFIG_AMD_MEM_ENCRYPT
975#define PERCPU_DECRYPTED_SECTION \
976 . = ALIGN(PAGE_SIZE); \
977 *(.data..decrypted) \
978 *(.data..percpu..decrypted) \
979 . = ALIGN(PAGE_SIZE);
980#else
981#define PERCPU_DECRYPTED_SECTION
982#endif
983
984
985/*
986 * Default discarded sections.
987 *
988 * Some archs want to discard exit text/data at runtime rather than
989 * link time due to cross-section references such as alt instructions,
990 * bug table, eh_frame, etc. DISCARDS must be the last of output
991 * section definitions so that such archs put those in earlier section
992 * definitions.
993 */
994#ifdef RUNTIME_DISCARD_EXIT
995#define EXIT_DISCARDS
996#else
997#define EXIT_DISCARDS \
998 EXIT_TEXT \
999 EXIT_DATA
1000#endif
1001
1002/*
1003 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
1004 * -fsanitize=thread produce unwanted sections (.eh_frame
1005 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
1006 * keep any .init_array.* sections.
1007 * https://bugs.llvm.org/show_bug.cgi?id=46478
1008 */
1009#if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN) || \
1010 defined(CONFIG_CFI_CLANG)
1011# ifdef CONFIG_CONSTRUCTORS
1012# define SANITIZER_DISCARDS \
1013 *(.eh_frame)
1014# else
1015# define SANITIZER_DISCARDS \
1016 *(.init_array) *(.init_array.*) \
1017 *(.eh_frame)
1018# endif
1019#else
1020# define SANITIZER_DISCARDS
1021#endif
1022
1023#define COMMON_DISCARDS \
1024 SANITIZER_DISCARDS \
1025 *(.discard) \
1026 *(.discard.*) \
1027 *(.modinfo) \
1028 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1029 *(.gnu.version*) \
1030
1031#define DISCARDS \
1032 /DISCARD/ : { \
1033 EXIT_DISCARDS \
1034 EXIT_CALL \
1035 COMMON_DISCARDS \
1036 }
1037
1038/**
1039 * PERCPU_INPUT - the percpu input sections
1040 * @cacheline: cacheline size
1041 *
1042 * The core percpu section names and core symbols which do not rely
1043 * directly upon load addresses.
1044 *
1045 * @cacheline is used to align subsections to avoid false cacheline
1046 * sharing between subsections for different purposes.
1047 */
1048#define PERCPU_INPUT(cacheline) \
1049 __per_cpu_start = .; \
1050 *(.data..percpu..first) \
1051 . = ALIGN(PAGE_SIZE); \
1052 *(.data..percpu..page_aligned) \
1053 . = ALIGN(cacheline); \
1054 *(.data..percpu..read_mostly) \
1055 . = ALIGN(cacheline); \
1056 *(.data..percpu) \
1057 *(.data..percpu..shared_aligned) \
1058 PERCPU_DECRYPTED_SECTION \
1059 __per_cpu_end = .;
1060
1061/**
1062 * PERCPU_VADDR - define output section for percpu area
1063 * @cacheline: cacheline size
1064 * @vaddr: explicit base address (optional)
1065 * @phdr: destination PHDR (optional)
1066 *
1067 * Macro which expands to output section for percpu area.
1068 *
1069 * @cacheline is used to align subsections to avoid false cacheline
1070 * sharing between subsections for different purposes.
1071 *
1072 * If @vaddr is not blank, it specifies explicit base address and all
1073 * percpu symbols will be offset from the given address. If blank,
1074 * @vaddr always equals @laddr + LOAD_OFFSET.
1075 *
1076 * @phdr defines the output PHDR to use if not blank. Be warned that
1077 * output PHDR is sticky. If @phdr is specified, the next output
1078 * section in the linker script will go there too. @phdr should have
1079 * a leading colon.
1080 *
1081 * Note that this macros defines __per_cpu_load as an absolute symbol.
1082 * If there is no need to put the percpu section at a predetermined
1083 * address, use PERCPU_SECTION.
1084 */
1085#define PERCPU_VADDR(cacheline, vaddr, phdr) \
1086 __per_cpu_load = .; \
1087 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1088 PERCPU_INPUT(cacheline) \
1089 } phdr \
1090 . = __per_cpu_load + SIZEOF(.data..percpu);
1091
1092/**
1093 * PERCPU_SECTION - define output section for percpu area, simple version
1094 * @cacheline: cacheline size
1095 *
1096 * Align to PAGE_SIZE and outputs output section for percpu area. This
1097 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1098 * __per_cpu_start will be identical.
1099 *
1100 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1101 * except that __per_cpu_load is defined as a relative symbol against
1102 * .data..percpu which is required for relocatable x86_32 configuration.
1103 */
1104#define PERCPU_SECTION(cacheline) \
1105 . = ALIGN(PAGE_SIZE); \
1106 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1107 __per_cpu_load = .; \
1108 PERCPU_INPUT(cacheline) \
1109 }
1110
1111
1112/*
1113 * Definition of the high level *_SECTION macros
1114 * They will fit only a subset of the architectures
1115 */
1116
1117
1118/*
1119 * Writeable data.
1120 * All sections are combined in a single .data section.
1121 * The sections following CONSTRUCTORS are arranged so their
1122 * typical alignment matches.
1123 * A cacheline is typical/always less than a PAGE_SIZE so
1124 * the sections that has this restriction (or similar)
1125 * is located before the ones requiring PAGE_SIZE alignment.
1126 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1127 * matches the requirement of PAGE_ALIGNED_DATA.
1128 *
1129 * use 0 as page_align if page_aligned data is not used */
1130#define RW_DATA(cacheline, pagealigned, inittask) \
1131 . = ALIGN(PAGE_SIZE); \
1132 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1133 INIT_TASK_DATA(inittask) \
1134 NOSAVE_DATA \
1135 PAGE_ALIGNED_DATA(pagealigned) \
1136 CACHELINE_ALIGNED_DATA(cacheline) \
1137 READ_MOSTLY_DATA(cacheline) \
1138 DATA_DATA \
1139 CONSTRUCTORS \
1140 } \
1141 BUG_TABLE \
1142
1143#define INIT_TEXT_SECTION(inittext_align) \
1144 . = ALIGN(inittext_align); \
1145 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1146 _sinittext = .; \
1147 INIT_TEXT \
1148 _einittext = .; \
1149 }
1150
1151#define INIT_DATA_SECTION(initsetup_align) \
1152 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1153 INIT_DATA \
1154 INIT_SETUP(initsetup_align) \
1155 INIT_CALLS \
1156 CON_INITCALL \
1157 INIT_RAM_FS \
1158 }
1159
1160#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1161 . = ALIGN(sbss_align); \
1162 __bss_start = .; \
1163 SBSS(sbss_align) \
1164 BSS(bss_align) \
1165 . = ALIGN(stop_align); \
1166 __bss_stop = .;