Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1/*
2 * Common module linker script, always used when linking a module.
3 * Archs are free to supply their own linker scripts. ld will
4 * combine them automatically.
5 */
6SECTIONS {
7 /DISCARD/ : {
8 *(.discard)
9 *(.discard.*)
10 }
11
12 __ksymtab 0 : { *(SORT(___ksymtab+*)) }
13 __ksymtab_gpl 0 : { *(SORT(___ksymtab_gpl+*)) }
14 __kcrctab 0 : { *(SORT(___kcrctab+*)) }
15 __kcrctab_gpl 0 : { *(SORT(___kcrctab_gpl+*)) }
16
17 .init_array 0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
18
19 __jump_table 0 : ALIGN(8) { KEEP(*(__jump_table)) }
20
21 __patchable_function_entries : { *(__patchable_function_entries) }
22
23#ifdef CONFIG_LTO_CLANG
24 /*
25 * With CONFIG_LTO_CLANG, LLD always enables -fdata-sections and
26 * -ffunction-sections, which increases the size of the final module.
27 * Merge the split sections in the final binary.
28 */
29 .bss : {
30 *(.bss .bss.[0-9a-zA-Z_]*)
31 *(.bss..L*)
32 }
33
34 .data : {
35 *(.data .data.[0-9a-zA-Z_]*)
36 *(.data..L*)
37 }
38
39 .rodata : {
40 *(.rodata .rodata.[0-9a-zA-Z_]*)
41 *(.rodata..L*)
42 }
43
44 .text : { *(.text .text.[0-9a-zA-Z_]*) }
45#endif
46}
47
48/* bring in arch-specific sections */
49#include <asm/module.lds.h>