Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#ifndef LOAD_OFFSET
54#define LOAD_OFFSET 0
55#endif
56
57/*
58 * Only some architectures want to have the .notes segment visible in
59 * a separate PT_NOTE ELF Program Header. When this happens, it needs
60 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
61 * Program Headers. In this case, though, the PT_LOAD needs to be made
62 * the default again so that all the following sections don't also end
63 * up in the PT_NOTE Program Header.
64 */
65#ifdef EMITS_PT_NOTE
66#define NOTES_HEADERS :text :note
67#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
68#else
69#define NOTES_HEADERS
70#define NOTES_HEADERS_RESTORE
71#endif
72
73/*
74 * Some architectures have non-executable read-only exception tables.
75 * They can be added to the RO_DATA segment by specifying their desired
76 * alignment.
77 */
78#ifdef RO_EXCEPTION_TABLE_ALIGN
79#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
80#else
81#define RO_EXCEPTION_TABLE
82#endif
83
84/* Align . to a 8 byte boundary equals to maximum function alignment. */
85#define ALIGN_FUNCTION() . = ALIGN(8)
86
87/*
88 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
89 * generates .data.identifier sections, which need to be pulled in with
90 * .data. We don't want to pull in .data..other sections, which Linux
91 * has defined. Same for text and bss.
92 *
93 * With LTO_CLANG, the linker also splits sections by default, so we need
94 * these macros to combine the sections during the final link.
95 *
96 * RODATA_MAIN is not used because existing code already defines .rodata.x
97 * sections to be brought in with rodata.
98 */
99#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
100#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
101#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
102#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
103#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
104#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..compoundliteral*
105#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
106#else
107#define TEXT_MAIN .text
108#define DATA_MAIN .data
109#define SDATA_MAIN .sdata
110#define RODATA_MAIN .rodata
111#define BSS_MAIN .bss
112#define SBSS_MAIN .sbss
113#endif
114
115/*
116 * GCC 4.5 and later have a 32 bytes section alignment for structures.
117 * Except GCC 4.9, that feels the need to align on 64 bytes.
118 */
119#if __GNUC__ == 4 && __GNUC_MINOR__ == 9
120#define STRUCT_ALIGNMENT 64
121#else
122#define STRUCT_ALIGNMENT 32
123#endif
124#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
125
126/*
127 * The order of the sched class addresses are important, as they are
128 * used to determine the order of the priority of each sched class in
129 * relation to each other.
130 */
131#define SCHED_DATA \
132 STRUCT_ALIGN(); \
133 __begin_sched_classes = .; \
134 *(__idle_sched_class) \
135 *(__fair_sched_class) \
136 *(__rt_sched_class) \
137 *(__dl_sched_class) \
138 *(__stop_sched_class) \
139 __end_sched_classes = .;
140
141/* The actual configuration determine if the init/exit sections
142 * are handled as text/data or they can be discarded (which
143 * often happens at runtime)
144 */
145#ifdef CONFIG_HOTPLUG_CPU
146#define CPU_KEEP(sec) *(.cpu##sec)
147#define CPU_DISCARD(sec)
148#else
149#define CPU_KEEP(sec)
150#define CPU_DISCARD(sec) *(.cpu##sec)
151#endif
152
153#if defined(CONFIG_MEMORY_HOTPLUG)
154#define MEM_KEEP(sec) *(.mem##sec)
155#define MEM_DISCARD(sec)
156#else
157#define MEM_KEEP(sec)
158#define MEM_DISCARD(sec) *(.mem##sec)
159#endif
160
161#ifdef CONFIG_FTRACE_MCOUNT_RECORD
162/*
163 * The ftrace call sites are logged to a section whose name depends on the
164 * compiler option used. A given kernel image will only use one, AKA
165 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
166 * dependencies for FTRACE_CALLSITE_SECTION's definition.
167 *
168 * Need to also make ftrace_stub_graph point to ftrace_stub
169 * so that the same stub location may have different protocols
170 * and not mess up with C verifiers.
171 */
172#define MCOUNT_REC() . = ALIGN(8); \
173 __start_mcount_loc = .; \
174 KEEP(*(__mcount_loc)) \
175 KEEP(*(__patchable_function_entries)) \
176 __stop_mcount_loc = .; \
177 ftrace_stub_graph = ftrace_stub;
178#else
179# ifdef CONFIG_FUNCTION_TRACER
180# define MCOUNT_REC() ftrace_stub_graph = ftrace_stub;
181# else
182# define MCOUNT_REC()
183# endif
184#endif
185
186#ifdef CONFIG_TRACE_BRANCH_PROFILING
187#define LIKELY_PROFILE() __start_annotated_branch_profile = .; \
188 KEEP(*(_ftrace_annotated_branch)) \
189 __stop_annotated_branch_profile = .;
190#else
191#define LIKELY_PROFILE()
192#endif
193
194#ifdef CONFIG_PROFILE_ALL_BRANCHES
195#define BRANCH_PROFILE() __start_branch_profile = .; \
196 KEEP(*(_ftrace_branch)) \
197 __stop_branch_profile = .;
198#else
199#define BRANCH_PROFILE()
200#endif
201
202#ifdef CONFIG_KPROBES
203#define KPROBE_BLACKLIST() . = ALIGN(8); \
204 __start_kprobe_blacklist = .; \
205 KEEP(*(_kprobe_blacklist)) \
206 __stop_kprobe_blacklist = .;
207#else
208#define KPROBE_BLACKLIST()
209#endif
210
211#ifdef CONFIG_FUNCTION_ERROR_INJECTION
212#define ERROR_INJECT_WHITELIST() STRUCT_ALIGN(); \
213 __start_error_injection_whitelist = .; \
214 KEEP(*(_error_injection_whitelist)) \
215 __stop_error_injection_whitelist = .;
216#else
217#define ERROR_INJECT_WHITELIST()
218#endif
219
220#ifdef CONFIG_EVENT_TRACING
221#define FTRACE_EVENTS() . = ALIGN(8); \
222 __start_ftrace_events = .; \
223 KEEP(*(_ftrace_events)) \
224 __stop_ftrace_events = .; \
225 __start_ftrace_eval_maps = .; \
226 KEEP(*(_ftrace_eval_map)) \
227 __stop_ftrace_eval_maps = .;
228#else
229#define FTRACE_EVENTS()
230#endif
231
232#ifdef CONFIG_TRACING
233#define TRACE_PRINTKS() __start___trace_bprintk_fmt = .; \
234 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
235 __stop___trace_bprintk_fmt = .;
236#define TRACEPOINT_STR() __start___tracepoint_str = .; \
237 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
238 __stop___tracepoint_str = .;
239#else
240#define TRACE_PRINTKS()
241#define TRACEPOINT_STR()
242#endif
243
244#ifdef CONFIG_FTRACE_SYSCALLS
245#define TRACE_SYSCALLS() . = ALIGN(8); \
246 __start_syscalls_metadata = .; \
247 KEEP(*(__syscalls_metadata)) \
248 __stop_syscalls_metadata = .;
249#else
250#define TRACE_SYSCALLS()
251#endif
252
253#ifdef CONFIG_BPF_EVENTS
254#define BPF_RAW_TP() STRUCT_ALIGN(); \
255 __start__bpf_raw_tp = .; \
256 KEEP(*(__bpf_raw_tp_map)) \
257 __stop__bpf_raw_tp = .;
258#else
259#define BPF_RAW_TP()
260#endif
261
262#ifdef CONFIG_SERIAL_EARLYCON
263#define EARLYCON_TABLE() . = ALIGN(8); \
264 __earlycon_table = .; \
265 KEEP(*(__earlycon_table)) \
266 __earlycon_table_end = .;
267#else
268#define EARLYCON_TABLE()
269#endif
270
271#ifdef CONFIG_SECURITY
272#define LSM_TABLE() . = ALIGN(8); \
273 __start_lsm_info = .; \
274 KEEP(*(.lsm_info.init)) \
275 __end_lsm_info = .;
276#define EARLY_LSM_TABLE() . = ALIGN(8); \
277 __start_early_lsm_info = .; \
278 KEEP(*(.early_lsm_info.init)) \
279 __end_early_lsm_info = .;
280#else
281#define LSM_TABLE()
282#define EARLY_LSM_TABLE()
283#endif
284
285#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
286#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
287#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
288#define _OF_TABLE_0(name)
289#define _OF_TABLE_1(name) \
290 . = ALIGN(8); \
291 __##name##_of_table = .; \
292 KEEP(*(__##name##_of_table)) \
293 KEEP(*(__##name##_of_table_end))
294
295#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
296#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
297#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
298#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
299#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
300#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
301
302#ifdef CONFIG_ACPI
303#define ACPI_PROBE_TABLE(name) \
304 . = ALIGN(8); \
305 __##name##_acpi_probe_table = .; \
306 KEEP(*(__##name##_acpi_probe_table)) \
307 __##name##_acpi_probe_table_end = .;
308#else
309#define ACPI_PROBE_TABLE(name)
310#endif
311
312#ifdef CONFIG_THERMAL
313#define THERMAL_TABLE(name) \
314 . = ALIGN(8); \
315 __##name##_thermal_table = .; \
316 KEEP(*(__##name##_thermal_table)) \
317 __##name##_thermal_table_end = .;
318#else
319#define THERMAL_TABLE(name)
320#endif
321
322#ifdef CONFIG_DTPM
323#define DTPM_TABLE() \
324 . = ALIGN(8); \
325 __dtpm_table = .; \
326 KEEP(*(__dtpm_table)) \
327 __dtpm_table_end = .;
328#else
329#define DTPM_TABLE()
330#endif
331
332#define KERNEL_DTB() \
333 STRUCT_ALIGN(); \
334 __dtb_start = .; \
335 KEEP(*(.dtb.init.rodata)) \
336 __dtb_end = .;
337
338/*
339 * .data section
340 */
341#define DATA_DATA \
342 *(.xiptext) \
343 *(DATA_MAIN) \
344 *(.ref.data) \
345 *(.data..shared_aligned) /* percpu related */ \
346 MEM_KEEP(init.data*) \
347 MEM_KEEP(exit.data*) \
348 *(.data.unlikely) \
349 __start_once = .; \
350 *(.data.once) \
351 __end_once = .; \
352 STRUCT_ALIGN(); \
353 *(__tracepoints) \
354 /* implement dynamic printk debug */ \
355 . = ALIGN(8); \
356 __start___dyndbg = .; \
357 KEEP(*(__dyndbg)) \
358 __stop___dyndbg = .; \
359 LIKELY_PROFILE() \
360 BRANCH_PROFILE() \
361 TRACE_PRINTKS() \
362 BPF_RAW_TP() \
363 TRACEPOINT_STR()
364
365/*
366 * Data section helpers
367 */
368#define NOSAVE_DATA \
369 . = ALIGN(PAGE_SIZE); \
370 __nosave_begin = .; \
371 *(.data..nosave) \
372 . = ALIGN(PAGE_SIZE); \
373 __nosave_end = .;
374
375#define PAGE_ALIGNED_DATA(page_align) \
376 . = ALIGN(page_align); \
377 *(.data..page_aligned) \
378 . = ALIGN(page_align);
379
380#define READ_MOSTLY_DATA(align) \
381 . = ALIGN(align); \
382 *(.data..read_mostly) \
383 . = ALIGN(align);
384
385#define CACHELINE_ALIGNED_DATA(align) \
386 . = ALIGN(align); \
387 *(.data..cacheline_aligned)
388
389#define INIT_TASK_DATA(align) \
390 . = ALIGN(align); \
391 __start_init_task = .; \
392 init_thread_union = .; \
393 init_stack = .; \
394 KEEP(*(.data..init_task)) \
395 KEEP(*(.data..init_thread_info)) \
396 . = __start_init_task + THREAD_SIZE; \
397 __end_init_task = .;
398
399#define JUMP_TABLE_DATA \
400 . = ALIGN(8); \
401 __start___jump_table = .; \
402 KEEP(*(__jump_table)) \
403 __stop___jump_table = .;
404
405#define STATIC_CALL_DATA \
406 . = ALIGN(8); \
407 __start_static_call_sites = .; \
408 KEEP(*(.static_call_sites)) \
409 __stop_static_call_sites = .; \
410 __start_static_call_tramp_key = .; \
411 KEEP(*(.static_call_tramp_key)) \
412 __stop_static_call_tramp_key = .;
413
414/*
415 * Allow architectures to handle ro_after_init data on their
416 * own by defining an empty RO_AFTER_INIT_DATA.
417 */
418#ifndef RO_AFTER_INIT_DATA
419#define RO_AFTER_INIT_DATA \
420 . = ALIGN(8); \
421 __start_ro_after_init = .; \
422 *(.data..ro_after_init) \
423 JUMP_TABLE_DATA \
424 STATIC_CALL_DATA \
425 __end_ro_after_init = .;
426#endif
427
428/*
429 * Read only Data
430 */
431#define RO_DATA(align) \
432 . = ALIGN((align)); \
433 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
434 __start_rodata = .; \
435 *(.rodata) *(.rodata.*) \
436 SCHED_DATA \
437 RO_AFTER_INIT_DATA /* Read only after init */ \
438 . = ALIGN(8); \
439 __start___tracepoints_ptrs = .; \
440 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
441 __stop___tracepoints_ptrs = .; \
442 *(__tracepoints_strings)/* Tracepoints: strings */ \
443 } \
444 \
445 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
446 *(.rodata1) \
447 } \
448 \
449 /* PCI quirks */ \
450 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
451 __start_pci_fixups_early = .; \
452 KEEP(*(.pci_fixup_early)) \
453 __end_pci_fixups_early = .; \
454 __start_pci_fixups_header = .; \
455 KEEP(*(.pci_fixup_header)) \
456 __end_pci_fixups_header = .; \
457 __start_pci_fixups_final = .; \
458 KEEP(*(.pci_fixup_final)) \
459 __end_pci_fixups_final = .; \
460 __start_pci_fixups_enable = .; \
461 KEEP(*(.pci_fixup_enable)) \
462 __end_pci_fixups_enable = .; \
463 __start_pci_fixups_resume = .; \
464 KEEP(*(.pci_fixup_resume)) \
465 __end_pci_fixups_resume = .; \
466 __start_pci_fixups_resume_early = .; \
467 KEEP(*(.pci_fixup_resume_early)) \
468 __end_pci_fixups_resume_early = .; \
469 __start_pci_fixups_suspend = .; \
470 KEEP(*(.pci_fixup_suspend)) \
471 __end_pci_fixups_suspend = .; \
472 __start_pci_fixups_suspend_late = .; \
473 KEEP(*(.pci_fixup_suspend_late)) \
474 __end_pci_fixups_suspend_late = .; \
475 } \
476 \
477 /* Built-in firmware blobs */ \
478 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
479 __start_builtin_fw = .; \
480 KEEP(*(.builtin_fw)) \
481 __end_builtin_fw = .; \
482 } \
483 \
484 TRACEDATA \
485 \
486 /* Kernel symbol table: Normal symbols */ \
487 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
488 __start___ksymtab = .; \
489 KEEP(*(SORT(___ksymtab+*))) \
490 __stop___ksymtab = .; \
491 } \
492 \
493 /* Kernel symbol table: GPL-only symbols */ \
494 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
495 __start___ksymtab_gpl = .; \
496 KEEP(*(SORT(___ksymtab_gpl+*))) \
497 __stop___ksymtab_gpl = .; \
498 } \
499 \
500 /* Kernel symbol table: Normal symbols */ \
501 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
502 __start___kcrctab = .; \
503 KEEP(*(SORT(___kcrctab+*))) \
504 __stop___kcrctab = .; \
505 } \
506 \
507 /* Kernel symbol table: GPL-only symbols */ \
508 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
509 __start___kcrctab_gpl = .; \
510 KEEP(*(SORT(___kcrctab_gpl+*))) \
511 __stop___kcrctab_gpl = .; \
512 } \
513 \
514 /* Kernel symbol table: strings */ \
515 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
516 *(__ksymtab_strings) \
517 } \
518 \
519 /* __*init sections */ \
520 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
521 *(.ref.rodata) \
522 MEM_KEEP(init.rodata) \
523 MEM_KEEP(exit.rodata) \
524 } \
525 \
526 /* Built-in module parameters. */ \
527 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
528 __start___param = .; \
529 KEEP(*(__param)) \
530 __stop___param = .; \
531 } \
532 \
533 /* Built-in module versions. */ \
534 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
535 __start___modver = .; \
536 KEEP(*(__modver)) \
537 __stop___modver = .; \
538 } \
539 \
540 RO_EXCEPTION_TABLE \
541 NOTES \
542 BTF \
543 \
544 . = ALIGN((align)); \
545 __end_rodata = .;
546
547/*
548 * Non-instrumentable text section
549 */
550#define NOINSTR_TEXT \
551 ALIGN_FUNCTION(); \
552 __noinstr_text_start = .; \
553 *(.noinstr.text) \
554 __noinstr_text_end = .;
555
556/*
557 * .text section. Map to function alignment to avoid address changes
558 * during second ld run in second ld pass when generating System.map
559 *
560 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
561 * code elimination is enabled, so these sections should be converted
562 * to use ".." first.
563 */
564#define TEXT_TEXT \
565 ALIGN_FUNCTION(); \
566 *(.text.hot .text.hot.*) \
567 *(TEXT_MAIN .text.fixup) \
568 *(.text.unlikely .text.unlikely.*) \
569 *(.text.unknown .text.unknown.*) \
570 NOINSTR_TEXT \
571 *(.text..refcount) \
572 *(.ref.text) \
573 MEM_KEEP(init.text*) \
574 MEM_KEEP(exit.text*) \
575
576
577/* sched.text is aling to function alignment to secure we have same
578 * address even at second ld pass when generating System.map */
579#define SCHED_TEXT \
580 ALIGN_FUNCTION(); \
581 __sched_text_start = .; \
582 *(.sched.text) \
583 __sched_text_end = .;
584
585/* spinlock.text is aling to function alignment to secure we have same
586 * address even at second ld pass when generating System.map */
587#define LOCK_TEXT \
588 ALIGN_FUNCTION(); \
589 __lock_text_start = .; \
590 *(.spinlock.text) \
591 __lock_text_end = .;
592
593#define CPUIDLE_TEXT \
594 ALIGN_FUNCTION(); \
595 __cpuidle_text_start = .; \
596 *(.cpuidle.text) \
597 __cpuidle_text_end = .;
598
599#define KPROBES_TEXT \
600 ALIGN_FUNCTION(); \
601 __kprobes_text_start = .; \
602 *(.kprobes.text) \
603 __kprobes_text_end = .;
604
605#define ENTRY_TEXT \
606 ALIGN_FUNCTION(); \
607 __entry_text_start = .; \
608 *(.entry.text) \
609 __entry_text_end = .;
610
611#define IRQENTRY_TEXT \
612 ALIGN_FUNCTION(); \
613 __irqentry_text_start = .; \
614 *(.irqentry.text) \
615 __irqentry_text_end = .;
616
617#define SOFTIRQENTRY_TEXT \
618 ALIGN_FUNCTION(); \
619 __softirqentry_text_start = .; \
620 *(.softirqentry.text) \
621 __softirqentry_text_end = .;
622
623#define STATIC_CALL_TEXT \
624 ALIGN_FUNCTION(); \
625 __static_call_text_start = .; \
626 *(.static_call.text) \
627 __static_call_text_end = .;
628
629/* Section used for early init (in .S files) */
630#define HEAD_TEXT KEEP(*(.head.text))
631
632#define HEAD_TEXT_SECTION \
633 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
634 HEAD_TEXT \
635 }
636
637/*
638 * Exception table
639 */
640#define EXCEPTION_TABLE(align) \
641 . = ALIGN(align); \
642 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
643 __start___ex_table = .; \
644 KEEP(*(__ex_table)) \
645 __stop___ex_table = .; \
646 }
647
648/*
649 * .BTF
650 */
651#ifdef CONFIG_DEBUG_INFO_BTF
652#define BTF \
653 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
654 __start_BTF = .; \
655 KEEP(*(.BTF)) \
656 __stop_BTF = .; \
657 } \
658 . = ALIGN(4); \
659 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
660 *(.BTF_ids) \
661 }
662#else
663#define BTF
664#endif
665
666/*
667 * Init task
668 */
669#define INIT_TASK_DATA_SECTION(align) \
670 . = ALIGN(align); \
671 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
672 INIT_TASK_DATA(align) \
673 }
674
675#ifdef CONFIG_CONSTRUCTORS
676#define KERNEL_CTORS() . = ALIGN(8); \
677 __ctors_start = .; \
678 KEEP(*(SORT(.ctors.*))) \
679 KEEP(*(.ctors)) \
680 KEEP(*(SORT(.init_array.*))) \
681 KEEP(*(.init_array)) \
682 __ctors_end = .;
683#else
684#define KERNEL_CTORS()
685#endif
686
687/* init and exit section handling */
688#define INIT_DATA \
689 KEEP(*(SORT(___kentry+*))) \
690 *(.init.data init.data.*) \
691 MEM_DISCARD(init.data*) \
692 KERNEL_CTORS() \
693 MCOUNT_REC() \
694 *(.init.rodata .init.rodata.*) \
695 FTRACE_EVENTS() \
696 TRACE_SYSCALLS() \
697 KPROBE_BLACKLIST() \
698 ERROR_INJECT_WHITELIST() \
699 MEM_DISCARD(init.rodata) \
700 CLK_OF_TABLES() \
701 RESERVEDMEM_OF_TABLES() \
702 TIMER_OF_TABLES() \
703 CPU_METHOD_OF_TABLES() \
704 CPUIDLE_METHOD_OF_TABLES() \
705 KERNEL_DTB() \
706 IRQCHIP_OF_MATCH_TABLE() \
707 ACPI_PROBE_TABLE(irqchip) \
708 ACPI_PROBE_TABLE(timer) \
709 THERMAL_TABLE(governor) \
710 DTPM_TABLE() \
711 EARLYCON_TABLE() \
712 LSM_TABLE() \
713 EARLY_LSM_TABLE() \
714 KUNIT_TABLE()
715
716#define INIT_TEXT \
717 *(.init.text .init.text.*) \
718 *(.text.startup) \
719 MEM_DISCARD(init.text*)
720
721#define EXIT_DATA \
722 *(.exit.data .exit.data.*) \
723 *(.fini_array .fini_array.*) \
724 *(.dtors .dtors.*) \
725 MEM_DISCARD(exit.data*) \
726 MEM_DISCARD(exit.rodata*)
727
728#define EXIT_TEXT \
729 *(.exit.text) \
730 *(.text.exit) \
731 MEM_DISCARD(exit.text)
732
733#define EXIT_CALL \
734 *(.exitcall.exit)
735
736/*
737 * bss (Block Started by Symbol) - uninitialized data
738 * zeroed during startup
739 */
740#define SBSS(sbss_align) \
741 . = ALIGN(sbss_align); \
742 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
743 *(.dynsbss) \
744 *(SBSS_MAIN) \
745 *(.scommon) \
746 }
747
748/*
749 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
750 * sections to the front of bss.
751 */
752#ifndef BSS_FIRST_SECTIONS
753#define BSS_FIRST_SECTIONS
754#endif
755
756#define BSS(bss_align) \
757 . = ALIGN(bss_align); \
758 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
759 BSS_FIRST_SECTIONS \
760 . = ALIGN(PAGE_SIZE); \
761 *(.bss..page_aligned) \
762 . = ALIGN(PAGE_SIZE); \
763 *(.dynbss) \
764 *(BSS_MAIN) \
765 *(COMMON) \
766 }
767
768/*
769 * DWARF debug sections.
770 * Symbols in the DWARF debugging sections are relative to
771 * the beginning of the section so we begin them at 0.
772 */
773#define DWARF_DEBUG \
774 /* DWARF 1 */ \
775 .debug 0 : { *(.debug) } \
776 .line 0 : { *(.line) } \
777 /* GNU DWARF 1 extensions */ \
778 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
779 .debug_sfnames 0 : { *(.debug_sfnames) } \
780 /* DWARF 1.1 and DWARF 2 */ \
781 .debug_aranges 0 : { *(.debug_aranges) } \
782 .debug_pubnames 0 : { *(.debug_pubnames) } \
783 /* DWARF 2 */ \
784 .debug_info 0 : { *(.debug_info \
785 .gnu.linkonce.wi.*) } \
786 .debug_abbrev 0 : { *(.debug_abbrev) } \
787 .debug_line 0 : { *(.debug_line) } \
788 .debug_frame 0 : { *(.debug_frame) } \
789 .debug_str 0 : { *(.debug_str) } \
790 .debug_loc 0 : { *(.debug_loc) } \
791 .debug_macinfo 0 : { *(.debug_macinfo) } \
792 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
793 /* DWARF 3 */ \
794 .debug_ranges 0 : { *(.debug_ranges) } \
795 /* SGI/MIPS DWARF 2 extensions */ \
796 .debug_weaknames 0 : { *(.debug_weaknames) } \
797 .debug_funcnames 0 : { *(.debug_funcnames) } \
798 .debug_typenames 0 : { *(.debug_typenames) } \
799 .debug_varnames 0 : { *(.debug_varnames) } \
800 /* GNU DWARF 2 extensions */ \
801 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
802 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
803 /* DWARF 4 */ \
804 .debug_types 0 : { *(.debug_types) } \
805 /* DWARF 5 */ \
806 .debug_addr 0 : { *(.debug_addr) } \
807 .debug_line_str 0 : { *(.debug_line_str) } \
808 .debug_loclists 0 : { *(.debug_loclists) } \
809 .debug_macro 0 : { *(.debug_macro) } \
810 .debug_names 0 : { *(.debug_names) } \
811 .debug_rnglists 0 : { *(.debug_rnglists) } \
812 .debug_str_offsets 0 : { *(.debug_str_offsets) }
813
814/* Stabs debugging sections. */
815#define STABS_DEBUG \
816 .stab 0 : { *(.stab) } \
817 .stabstr 0 : { *(.stabstr) } \
818 .stab.excl 0 : { *(.stab.excl) } \
819 .stab.exclstr 0 : { *(.stab.exclstr) } \
820 .stab.index 0 : { *(.stab.index) } \
821 .stab.indexstr 0 : { *(.stab.indexstr) }
822
823/* Required sections not related to debugging. */
824#define ELF_DETAILS \
825 .comment 0 : { *(.comment) } \
826 .symtab 0 : { *(.symtab) } \
827 .strtab 0 : { *(.strtab) } \
828 .shstrtab 0 : { *(.shstrtab) }
829
830#ifdef CONFIG_GENERIC_BUG
831#define BUG_TABLE \
832 . = ALIGN(8); \
833 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
834 __start___bug_table = .; \
835 KEEP(*(__bug_table)) \
836 __stop___bug_table = .; \
837 }
838#else
839#define BUG_TABLE
840#endif
841
842#ifdef CONFIG_UNWINDER_ORC
843#define ORC_UNWIND_TABLE \
844 . = ALIGN(4); \
845 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
846 __start_orc_unwind_ip = .; \
847 KEEP(*(.orc_unwind_ip)) \
848 __stop_orc_unwind_ip = .; \
849 } \
850 . = ALIGN(2); \
851 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
852 __start_orc_unwind = .; \
853 KEEP(*(.orc_unwind)) \
854 __stop_orc_unwind = .; \
855 } \
856 . = ALIGN(4); \
857 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
858 orc_lookup = .; \
859 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) / \
860 LOOKUP_BLOCK_SIZE) + 1) * 4; \
861 orc_lookup_end = .; \
862 }
863#else
864#define ORC_UNWIND_TABLE
865#endif
866
867#ifdef CONFIG_PM_TRACE
868#define TRACEDATA \
869 . = ALIGN(4); \
870 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
871 __tracedata_start = .; \
872 KEEP(*(.tracedata)) \
873 __tracedata_end = .; \
874 }
875#else
876#define TRACEDATA
877#endif
878
879#define NOTES \
880 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
881 __start_notes = .; \
882 KEEP(*(.note.*)) \
883 __stop_notes = .; \
884 } NOTES_HEADERS \
885 NOTES_HEADERS_RESTORE
886
887#define INIT_SETUP(initsetup_align) \
888 . = ALIGN(initsetup_align); \
889 __setup_start = .; \
890 KEEP(*(.init.setup)) \
891 __setup_end = .;
892
893#define INIT_CALLS_LEVEL(level) \
894 __initcall##level##_start = .; \
895 KEEP(*(.initcall##level##.init)) \
896 KEEP(*(.initcall##level##s.init)) \
897
898#define INIT_CALLS \
899 __initcall_start = .; \
900 KEEP(*(.initcallearly.init)) \
901 INIT_CALLS_LEVEL(0) \
902 INIT_CALLS_LEVEL(1) \
903 INIT_CALLS_LEVEL(2) \
904 INIT_CALLS_LEVEL(3) \
905 INIT_CALLS_LEVEL(4) \
906 INIT_CALLS_LEVEL(5) \
907 INIT_CALLS_LEVEL(rootfs) \
908 INIT_CALLS_LEVEL(6) \
909 INIT_CALLS_LEVEL(7) \
910 __initcall_end = .;
911
912#define CON_INITCALL \
913 __con_initcall_start = .; \
914 KEEP(*(.con_initcall.init)) \
915 __con_initcall_end = .;
916
917/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
918#define KUNIT_TABLE() \
919 . = ALIGN(8); \
920 __kunit_suites_start = .; \
921 KEEP(*(.kunit_test_suites)) \
922 __kunit_suites_end = .;
923
924#ifdef CONFIG_BLK_DEV_INITRD
925#define INIT_RAM_FS \
926 . = ALIGN(4); \
927 __initramfs_start = .; \
928 KEEP(*(.init.ramfs)) \
929 . = ALIGN(8); \
930 KEEP(*(.init.ramfs.info))
931#else
932#define INIT_RAM_FS
933#endif
934
935/*
936 * Memory encryption operates on a page basis. Since we need to clear
937 * the memory encryption mask for this section, it needs to be aligned
938 * on a page boundary and be a page-size multiple in length.
939 *
940 * Note: We use a separate section so that only this section gets
941 * decrypted to avoid exposing more than we wish.
942 */
943#ifdef CONFIG_AMD_MEM_ENCRYPT
944#define PERCPU_DECRYPTED_SECTION \
945 . = ALIGN(PAGE_SIZE); \
946 *(.data..percpu..decrypted) \
947 . = ALIGN(PAGE_SIZE);
948#else
949#define PERCPU_DECRYPTED_SECTION
950#endif
951
952
953/*
954 * Default discarded sections.
955 *
956 * Some archs want to discard exit text/data at runtime rather than
957 * link time due to cross-section references such as alt instructions,
958 * bug table, eh_frame, etc. DISCARDS must be the last of output
959 * section definitions so that such archs put those in earlier section
960 * definitions.
961 */
962#ifdef RUNTIME_DISCARD_EXIT
963#define EXIT_DISCARDS
964#else
965#define EXIT_DISCARDS \
966 EXIT_TEXT \
967 EXIT_DATA
968#endif
969
970/*
971 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
972 * -fsanitize=thread produce unwanted sections (.eh_frame
973 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
974 * keep any .init_array.* sections.
975 * https://bugs.llvm.org/show_bug.cgi?id=46478
976 */
977#if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN)
978# ifdef CONFIG_CONSTRUCTORS
979# define SANITIZER_DISCARDS \
980 *(.eh_frame)
981# else
982# define SANITIZER_DISCARDS \
983 *(.init_array) *(.init_array.*) \
984 *(.eh_frame)
985# endif
986#else
987# define SANITIZER_DISCARDS
988#endif
989
990#define COMMON_DISCARDS \
991 SANITIZER_DISCARDS \
992 *(.discard) \
993 *(.discard.*) \
994 *(.modinfo) \
995 /* ld.bfd warns about .gnu.version* even when not emitted */ \
996 *(.gnu.version*) \
997
998#define DISCARDS \
999 /DISCARD/ : { \
1000 EXIT_DISCARDS \
1001 EXIT_CALL \
1002 COMMON_DISCARDS \
1003 }
1004
1005/**
1006 * PERCPU_INPUT - the percpu input sections
1007 * @cacheline: cacheline size
1008 *
1009 * The core percpu section names and core symbols which do not rely
1010 * directly upon load addresses.
1011 *
1012 * @cacheline is used to align subsections to avoid false cacheline
1013 * sharing between subsections for different purposes.
1014 */
1015#define PERCPU_INPUT(cacheline) \
1016 __per_cpu_start = .; \
1017 *(.data..percpu..first) \
1018 . = ALIGN(PAGE_SIZE); \
1019 *(.data..percpu..page_aligned) \
1020 . = ALIGN(cacheline); \
1021 *(.data..percpu..read_mostly) \
1022 . = ALIGN(cacheline); \
1023 *(.data..percpu) \
1024 *(.data..percpu..shared_aligned) \
1025 PERCPU_DECRYPTED_SECTION \
1026 __per_cpu_end = .;
1027
1028/**
1029 * PERCPU_VADDR - define output section for percpu area
1030 * @cacheline: cacheline size
1031 * @vaddr: explicit base address (optional)
1032 * @phdr: destination PHDR (optional)
1033 *
1034 * Macro which expands to output section for percpu area.
1035 *
1036 * @cacheline is used to align subsections to avoid false cacheline
1037 * sharing between subsections for different purposes.
1038 *
1039 * If @vaddr is not blank, it specifies explicit base address and all
1040 * percpu symbols will be offset from the given address. If blank,
1041 * @vaddr always equals @laddr + LOAD_OFFSET.
1042 *
1043 * @phdr defines the output PHDR to use if not blank. Be warned that
1044 * output PHDR is sticky. If @phdr is specified, the next output
1045 * section in the linker script will go there too. @phdr should have
1046 * a leading colon.
1047 *
1048 * Note that this macros defines __per_cpu_load as an absolute symbol.
1049 * If there is no need to put the percpu section at a predetermined
1050 * address, use PERCPU_SECTION.
1051 */
1052#define PERCPU_VADDR(cacheline, vaddr, phdr) \
1053 __per_cpu_load = .; \
1054 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1055 PERCPU_INPUT(cacheline) \
1056 } phdr \
1057 . = __per_cpu_load + SIZEOF(.data..percpu);
1058
1059/**
1060 * PERCPU_SECTION - define output section for percpu area, simple version
1061 * @cacheline: cacheline size
1062 *
1063 * Align to PAGE_SIZE and outputs output section for percpu area. This
1064 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1065 * __per_cpu_start will be identical.
1066 *
1067 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1068 * except that __per_cpu_load is defined as a relative symbol against
1069 * .data..percpu which is required for relocatable x86_32 configuration.
1070 */
1071#define PERCPU_SECTION(cacheline) \
1072 . = ALIGN(PAGE_SIZE); \
1073 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1074 __per_cpu_load = .; \
1075 PERCPU_INPUT(cacheline) \
1076 }
1077
1078
1079/*
1080 * Definition of the high level *_SECTION macros
1081 * They will fit only a subset of the architectures
1082 */
1083
1084
1085/*
1086 * Writeable data.
1087 * All sections are combined in a single .data section.
1088 * The sections following CONSTRUCTORS are arranged so their
1089 * typical alignment matches.
1090 * A cacheline is typical/always less than a PAGE_SIZE so
1091 * the sections that has this restriction (or similar)
1092 * is located before the ones requiring PAGE_SIZE alignment.
1093 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1094 * matches the requirement of PAGE_ALIGNED_DATA.
1095 *
1096 * use 0 as page_align if page_aligned data is not used */
1097#define RW_DATA(cacheline, pagealigned, inittask) \
1098 . = ALIGN(PAGE_SIZE); \
1099 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1100 INIT_TASK_DATA(inittask) \
1101 NOSAVE_DATA \
1102 PAGE_ALIGNED_DATA(pagealigned) \
1103 CACHELINE_ALIGNED_DATA(cacheline) \
1104 READ_MOSTLY_DATA(cacheline) \
1105 DATA_DATA \
1106 CONSTRUCTORS \
1107 } \
1108 BUG_TABLE \
1109
1110#define INIT_TEXT_SECTION(inittext_align) \
1111 . = ALIGN(inittext_align); \
1112 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1113 _sinittext = .; \
1114 INIT_TEXT \
1115 _einittext = .; \
1116 }
1117
1118#define INIT_DATA_SECTION(initsetup_align) \
1119 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1120 INIT_DATA \
1121 INIT_SETUP(initsetup_align) \
1122 INIT_CALLS \
1123 CON_INITCALL \
1124 INIT_RAM_FS \
1125 }
1126
1127#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1128 . = ALIGN(sbss_align); \
1129 __bss_start = .; \
1130 SBSS(sbss_align) \
1131 BSS(bss_align) \
1132 . = ALIGN(stop_align); \
1133 __bss_stop = .;