Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#ifndef LOAD_OFFSET
54#define LOAD_OFFSET 0
55#endif
56
57/*
58 * Only some architectures want to have the .notes segment visible in
59 * a separate PT_NOTE ELF Program Header. When this happens, it needs
60 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
61 * Program Headers. In this case, though, the PT_LOAD needs to be made
62 * the default again so that all the following sections don't also end
63 * up in the PT_NOTE Program Header.
64 */
65#ifdef EMITS_PT_NOTE
66#define NOTES_HEADERS :text :note
67#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
68#else
69#define NOTES_HEADERS
70#define NOTES_HEADERS_RESTORE
71#endif
72
73/*
74 * Some architectures have non-executable read-only exception tables.
75 * They can be added to the RO_DATA segment by specifying their desired
76 * alignment.
77 */
78#ifdef RO_EXCEPTION_TABLE_ALIGN
79#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
80#else
81#define RO_EXCEPTION_TABLE
82#endif
83
84/* Align . to a 8 byte boundary equals to maximum function alignment. */
85#define ALIGN_FUNCTION() . = ALIGN(8)
86
87/*
88 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
89 * generates .data.identifier sections, which need to be pulled in with
90 * .data. We don't want to pull in .data..other sections, which Linux
91 * has defined. Same for text and bss.
92 *
93 * RODATA_MAIN is not used because existing code already defines .rodata.x
94 * sections to be brought in with rodata.
95 */
96#ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
97#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
98#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..LPBX*
99#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
100#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]*
101#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
102#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
103#else
104#define TEXT_MAIN .text
105#define DATA_MAIN .data
106#define SDATA_MAIN .sdata
107#define RODATA_MAIN .rodata
108#define BSS_MAIN .bss
109#define SBSS_MAIN .sbss
110#endif
111
112/*
113 * GCC 4.5 and later have a 32 bytes section alignment for structures.
114 * Except GCC 4.9, that feels the need to align on 64 bytes.
115 */
116#if __GNUC__ == 4 && __GNUC_MINOR__ == 9
117#define STRUCT_ALIGNMENT 64
118#else
119#define STRUCT_ALIGNMENT 32
120#endif
121#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
122
123/*
124 * The order of the sched class addresses are important, as they are
125 * used to determine the order of the priority of each sched class in
126 * relation to each other.
127 */
128#define SCHED_DATA \
129 STRUCT_ALIGN(); \
130 __begin_sched_classes = .; \
131 *(__idle_sched_class) \
132 *(__fair_sched_class) \
133 *(__rt_sched_class) \
134 *(__dl_sched_class) \
135 *(__stop_sched_class) \
136 __end_sched_classes = .;
137
138/* The actual configuration determine if the init/exit sections
139 * are handled as text/data or they can be discarded (which
140 * often happens at runtime)
141 */
142#ifdef CONFIG_HOTPLUG_CPU
143#define CPU_KEEP(sec) *(.cpu##sec)
144#define CPU_DISCARD(sec)
145#else
146#define CPU_KEEP(sec)
147#define CPU_DISCARD(sec) *(.cpu##sec)
148#endif
149
150#if defined(CONFIG_MEMORY_HOTPLUG)
151#define MEM_KEEP(sec) *(.mem##sec)
152#define MEM_DISCARD(sec)
153#else
154#define MEM_KEEP(sec)
155#define MEM_DISCARD(sec) *(.mem##sec)
156#endif
157
158#ifdef CONFIG_FTRACE_MCOUNT_RECORD
159/*
160 * The ftrace call sites are logged to a section whose name depends on the
161 * compiler option used. A given kernel image will only use one, AKA
162 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
163 * dependencies for FTRACE_CALLSITE_SECTION's definition.
164 *
165 * Need to also make ftrace_stub_graph point to ftrace_stub
166 * so that the same stub location may have different protocols
167 * and not mess up with C verifiers.
168 */
169#define MCOUNT_REC() . = ALIGN(8); \
170 __start_mcount_loc = .; \
171 KEEP(*(__mcount_loc)) \
172 KEEP(*(__patchable_function_entries)) \
173 __stop_mcount_loc = .; \
174 ftrace_stub_graph = ftrace_stub;
175#else
176# ifdef CONFIG_FUNCTION_TRACER
177# define MCOUNT_REC() ftrace_stub_graph = ftrace_stub;
178# else
179# define MCOUNT_REC()
180# endif
181#endif
182
183#ifdef CONFIG_TRACE_BRANCH_PROFILING
184#define LIKELY_PROFILE() __start_annotated_branch_profile = .; \
185 KEEP(*(_ftrace_annotated_branch)) \
186 __stop_annotated_branch_profile = .;
187#else
188#define LIKELY_PROFILE()
189#endif
190
191#ifdef CONFIG_PROFILE_ALL_BRANCHES
192#define BRANCH_PROFILE() __start_branch_profile = .; \
193 KEEP(*(_ftrace_branch)) \
194 __stop_branch_profile = .;
195#else
196#define BRANCH_PROFILE()
197#endif
198
199#ifdef CONFIG_KPROBES
200#define KPROBE_BLACKLIST() . = ALIGN(8); \
201 __start_kprobe_blacklist = .; \
202 KEEP(*(_kprobe_blacklist)) \
203 __stop_kprobe_blacklist = .;
204#else
205#define KPROBE_BLACKLIST()
206#endif
207
208#ifdef CONFIG_FUNCTION_ERROR_INJECTION
209#define ERROR_INJECT_WHITELIST() STRUCT_ALIGN(); \
210 __start_error_injection_whitelist = .; \
211 KEEP(*(_error_injection_whitelist)) \
212 __stop_error_injection_whitelist = .;
213#else
214#define ERROR_INJECT_WHITELIST()
215#endif
216
217#ifdef CONFIG_EVENT_TRACING
218#define FTRACE_EVENTS() . = ALIGN(8); \
219 __start_ftrace_events = .; \
220 KEEP(*(_ftrace_events)) \
221 __stop_ftrace_events = .; \
222 __start_ftrace_eval_maps = .; \
223 KEEP(*(_ftrace_eval_map)) \
224 __stop_ftrace_eval_maps = .;
225#else
226#define FTRACE_EVENTS()
227#endif
228
229#ifdef CONFIG_TRACING
230#define TRACE_PRINTKS() __start___trace_bprintk_fmt = .; \
231 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
232 __stop___trace_bprintk_fmt = .;
233#define TRACEPOINT_STR() __start___tracepoint_str = .; \
234 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
235 __stop___tracepoint_str = .;
236#else
237#define TRACE_PRINTKS()
238#define TRACEPOINT_STR()
239#endif
240
241#ifdef CONFIG_FTRACE_SYSCALLS
242#define TRACE_SYSCALLS() . = ALIGN(8); \
243 __start_syscalls_metadata = .; \
244 KEEP(*(__syscalls_metadata)) \
245 __stop_syscalls_metadata = .;
246#else
247#define TRACE_SYSCALLS()
248#endif
249
250#ifdef CONFIG_BPF_EVENTS
251#define BPF_RAW_TP() STRUCT_ALIGN(); \
252 __start__bpf_raw_tp = .; \
253 KEEP(*(__bpf_raw_tp_map)) \
254 __stop__bpf_raw_tp = .;
255#else
256#define BPF_RAW_TP()
257#endif
258
259#ifdef CONFIG_SERIAL_EARLYCON
260#define EARLYCON_TABLE() . = ALIGN(8); \
261 __earlycon_table = .; \
262 KEEP(*(__earlycon_table)) \
263 __earlycon_table_end = .;
264#else
265#define EARLYCON_TABLE()
266#endif
267
268#ifdef CONFIG_SECURITY
269#define LSM_TABLE() . = ALIGN(8); \
270 __start_lsm_info = .; \
271 KEEP(*(.lsm_info.init)) \
272 __end_lsm_info = .;
273#define EARLY_LSM_TABLE() . = ALIGN(8); \
274 __start_early_lsm_info = .; \
275 KEEP(*(.early_lsm_info.init)) \
276 __end_early_lsm_info = .;
277#else
278#define LSM_TABLE()
279#define EARLY_LSM_TABLE()
280#endif
281
282#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
283#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
284#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
285#define _OF_TABLE_0(name)
286#define _OF_TABLE_1(name) \
287 . = ALIGN(8); \
288 __##name##_of_table = .; \
289 KEEP(*(__##name##_of_table)) \
290 KEEP(*(__##name##_of_table_end))
291
292#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
293#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
294#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
295#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
296#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
297#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
298
299#ifdef CONFIG_ACPI
300#define ACPI_PROBE_TABLE(name) \
301 . = ALIGN(8); \
302 __##name##_acpi_probe_table = .; \
303 KEEP(*(__##name##_acpi_probe_table)) \
304 __##name##_acpi_probe_table_end = .;
305#else
306#define ACPI_PROBE_TABLE(name)
307#endif
308
309#ifdef CONFIG_THERMAL
310#define THERMAL_TABLE(name) \
311 . = ALIGN(8); \
312 __##name##_thermal_table = .; \
313 KEEP(*(__##name##_thermal_table)) \
314 __##name##_thermal_table_end = .;
315#else
316#define THERMAL_TABLE(name)
317#endif
318
319#define KERNEL_DTB() \
320 STRUCT_ALIGN(); \
321 __dtb_start = .; \
322 KEEP(*(.dtb.init.rodata)) \
323 __dtb_end = .;
324
325/*
326 * .data section
327 */
328#define DATA_DATA \
329 *(.xiptext) \
330 *(DATA_MAIN) \
331 *(.ref.data) \
332 *(.data..shared_aligned) /* percpu related */ \
333 MEM_KEEP(init.data*) \
334 MEM_KEEP(exit.data*) \
335 *(.data.unlikely) \
336 __start_once = .; \
337 *(.data.once) \
338 __end_once = .; \
339 STRUCT_ALIGN(); \
340 *(__tracepoints) \
341 /* implement dynamic printk debug */ \
342 . = ALIGN(8); \
343 __start___dyndbg = .; \
344 KEEP(*(__dyndbg)) \
345 __stop___dyndbg = .; \
346 LIKELY_PROFILE() \
347 BRANCH_PROFILE() \
348 TRACE_PRINTKS() \
349 BPF_RAW_TP() \
350 TRACEPOINT_STR()
351
352/*
353 * Data section helpers
354 */
355#define NOSAVE_DATA \
356 . = ALIGN(PAGE_SIZE); \
357 __nosave_begin = .; \
358 *(.data..nosave) \
359 . = ALIGN(PAGE_SIZE); \
360 __nosave_end = .;
361
362#define PAGE_ALIGNED_DATA(page_align) \
363 . = ALIGN(page_align); \
364 *(.data..page_aligned) \
365 . = ALIGN(page_align);
366
367#define READ_MOSTLY_DATA(align) \
368 . = ALIGN(align); \
369 *(.data..read_mostly) \
370 . = ALIGN(align);
371
372#define CACHELINE_ALIGNED_DATA(align) \
373 . = ALIGN(align); \
374 *(.data..cacheline_aligned)
375
376#define INIT_TASK_DATA(align) \
377 . = ALIGN(align); \
378 __start_init_task = .; \
379 init_thread_union = .; \
380 init_stack = .; \
381 KEEP(*(.data..init_task)) \
382 KEEP(*(.data..init_thread_info)) \
383 . = __start_init_task + THREAD_SIZE; \
384 __end_init_task = .;
385
386#define JUMP_TABLE_DATA \
387 . = ALIGN(8); \
388 __start___jump_table = .; \
389 KEEP(*(__jump_table)) \
390 __stop___jump_table = .;
391
392#define STATIC_CALL_DATA \
393 . = ALIGN(8); \
394 __start_static_call_sites = .; \
395 KEEP(*(.static_call_sites)) \
396 __stop_static_call_sites = .;
397
398/*
399 * Allow architectures to handle ro_after_init data on their
400 * own by defining an empty RO_AFTER_INIT_DATA.
401 */
402#ifndef RO_AFTER_INIT_DATA
403#define RO_AFTER_INIT_DATA \
404 . = ALIGN(8); \
405 __start_ro_after_init = .; \
406 *(.data..ro_after_init) \
407 JUMP_TABLE_DATA \
408 STATIC_CALL_DATA \
409 __end_ro_after_init = .;
410#endif
411
412/*
413 * Read only Data
414 */
415#define RO_DATA(align) \
416 . = ALIGN((align)); \
417 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
418 __start_rodata = .; \
419 *(.rodata) *(.rodata.*) \
420 SCHED_DATA \
421 RO_AFTER_INIT_DATA /* Read only after init */ \
422 . = ALIGN(8); \
423 __start___tracepoints_ptrs = .; \
424 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
425 __stop___tracepoints_ptrs = .; \
426 *(__tracepoints_strings)/* Tracepoints: strings */ \
427 } \
428 \
429 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
430 *(.rodata1) \
431 } \
432 \
433 /* PCI quirks */ \
434 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
435 __start_pci_fixups_early = .; \
436 KEEP(*(.pci_fixup_early)) \
437 __end_pci_fixups_early = .; \
438 __start_pci_fixups_header = .; \
439 KEEP(*(.pci_fixup_header)) \
440 __end_pci_fixups_header = .; \
441 __start_pci_fixups_final = .; \
442 KEEP(*(.pci_fixup_final)) \
443 __end_pci_fixups_final = .; \
444 __start_pci_fixups_enable = .; \
445 KEEP(*(.pci_fixup_enable)) \
446 __end_pci_fixups_enable = .; \
447 __start_pci_fixups_resume = .; \
448 KEEP(*(.pci_fixup_resume)) \
449 __end_pci_fixups_resume = .; \
450 __start_pci_fixups_resume_early = .; \
451 KEEP(*(.pci_fixup_resume_early)) \
452 __end_pci_fixups_resume_early = .; \
453 __start_pci_fixups_suspend = .; \
454 KEEP(*(.pci_fixup_suspend)) \
455 __end_pci_fixups_suspend = .; \
456 __start_pci_fixups_suspend_late = .; \
457 KEEP(*(.pci_fixup_suspend_late)) \
458 __end_pci_fixups_suspend_late = .; \
459 } \
460 \
461 /* Built-in firmware blobs */ \
462 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
463 __start_builtin_fw = .; \
464 KEEP(*(.builtin_fw)) \
465 __end_builtin_fw = .; \
466 } \
467 \
468 TRACEDATA \
469 \
470 /* Kernel symbol table: Normal symbols */ \
471 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
472 __start___ksymtab = .; \
473 KEEP(*(SORT(___ksymtab+*))) \
474 __stop___ksymtab = .; \
475 } \
476 \
477 /* Kernel symbol table: GPL-only symbols */ \
478 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
479 __start___ksymtab_gpl = .; \
480 KEEP(*(SORT(___ksymtab_gpl+*))) \
481 __stop___ksymtab_gpl = .; \
482 } \
483 \
484 /* Kernel symbol table: Normal unused symbols */ \
485 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
486 __start___ksymtab_unused = .; \
487 KEEP(*(SORT(___ksymtab_unused+*))) \
488 __stop___ksymtab_unused = .; \
489 } \
490 \
491 /* Kernel symbol table: GPL-only unused symbols */ \
492 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
493 __start___ksymtab_unused_gpl = .; \
494 KEEP(*(SORT(___ksymtab_unused_gpl+*))) \
495 __stop___ksymtab_unused_gpl = .; \
496 } \
497 \
498 /* Kernel symbol table: GPL-future-only symbols */ \
499 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
500 __start___ksymtab_gpl_future = .; \
501 KEEP(*(SORT(___ksymtab_gpl_future+*))) \
502 __stop___ksymtab_gpl_future = .; \
503 } \
504 \
505 /* Kernel symbol table: Normal symbols */ \
506 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
507 __start___kcrctab = .; \
508 KEEP(*(SORT(___kcrctab+*))) \
509 __stop___kcrctab = .; \
510 } \
511 \
512 /* Kernel symbol table: GPL-only symbols */ \
513 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
514 __start___kcrctab_gpl = .; \
515 KEEP(*(SORT(___kcrctab_gpl+*))) \
516 __stop___kcrctab_gpl = .; \
517 } \
518 \
519 /* Kernel symbol table: Normal unused symbols */ \
520 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
521 __start___kcrctab_unused = .; \
522 KEEP(*(SORT(___kcrctab_unused+*))) \
523 __stop___kcrctab_unused = .; \
524 } \
525 \
526 /* Kernel symbol table: GPL-only unused symbols */ \
527 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
528 __start___kcrctab_unused_gpl = .; \
529 KEEP(*(SORT(___kcrctab_unused_gpl+*))) \
530 __stop___kcrctab_unused_gpl = .; \
531 } \
532 \
533 /* Kernel symbol table: GPL-future-only symbols */ \
534 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
535 __start___kcrctab_gpl_future = .; \
536 KEEP(*(SORT(___kcrctab_gpl_future+*))) \
537 __stop___kcrctab_gpl_future = .; \
538 } \
539 \
540 /* Kernel symbol table: strings */ \
541 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
542 *(__ksymtab_strings) \
543 } \
544 \
545 /* __*init sections */ \
546 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
547 *(.ref.rodata) \
548 MEM_KEEP(init.rodata) \
549 MEM_KEEP(exit.rodata) \
550 } \
551 \
552 /* Built-in module parameters. */ \
553 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
554 __start___param = .; \
555 KEEP(*(__param)) \
556 __stop___param = .; \
557 } \
558 \
559 /* Built-in module versions. */ \
560 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
561 __start___modver = .; \
562 KEEP(*(__modver)) \
563 __stop___modver = .; \
564 } \
565 \
566 RO_EXCEPTION_TABLE \
567 NOTES \
568 BTF \
569 \
570 . = ALIGN((align)); \
571 __end_rodata = .;
572
573/*
574 * Non-instrumentable text section
575 */
576#define NOINSTR_TEXT \
577 ALIGN_FUNCTION(); \
578 __noinstr_text_start = .; \
579 *(.noinstr.text) \
580 __noinstr_text_end = .;
581
582/*
583 * .text section. Map to function alignment to avoid address changes
584 * during second ld run in second ld pass when generating System.map
585 *
586 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
587 * code elimination is enabled, so these sections should be converted
588 * to use ".." first.
589 */
590#define TEXT_TEXT \
591 ALIGN_FUNCTION(); \
592 *(.text.hot .text.hot.*) \
593 *(TEXT_MAIN .text.fixup) \
594 *(.text.unlikely .text.unlikely.*) \
595 *(.text.unknown .text.unknown.*) \
596 NOINSTR_TEXT \
597 *(.text..refcount) \
598 *(.ref.text) \
599 MEM_KEEP(init.text*) \
600 MEM_KEEP(exit.text*) \
601
602
603/* sched.text is aling to function alignment to secure we have same
604 * address even at second ld pass when generating System.map */
605#define SCHED_TEXT \
606 ALIGN_FUNCTION(); \
607 __sched_text_start = .; \
608 *(.sched.text) \
609 __sched_text_end = .;
610
611/* spinlock.text is aling to function alignment to secure we have same
612 * address even at second ld pass when generating System.map */
613#define LOCK_TEXT \
614 ALIGN_FUNCTION(); \
615 __lock_text_start = .; \
616 *(.spinlock.text) \
617 __lock_text_end = .;
618
619#define CPUIDLE_TEXT \
620 ALIGN_FUNCTION(); \
621 __cpuidle_text_start = .; \
622 *(.cpuidle.text) \
623 __cpuidle_text_end = .;
624
625#define KPROBES_TEXT \
626 ALIGN_FUNCTION(); \
627 __kprobes_text_start = .; \
628 *(.kprobes.text) \
629 __kprobes_text_end = .;
630
631#define ENTRY_TEXT \
632 ALIGN_FUNCTION(); \
633 __entry_text_start = .; \
634 *(.entry.text) \
635 __entry_text_end = .;
636
637#define IRQENTRY_TEXT \
638 ALIGN_FUNCTION(); \
639 __irqentry_text_start = .; \
640 *(.irqentry.text) \
641 __irqentry_text_end = .;
642
643#define SOFTIRQENTRY_TEXT \
644 ALIGN_FUNCTION(); \
645 __softirqentry_text_start = .; \
646 *(.softirqentry.text) \
647 __softirqentry_text_end = .;
648
649#define STATIC_CALL_TEXT \
650 ALIGN_FUNCTION(); \
651 __static_call_text_start = .; \
652 *(.static_call.text) \
653 __static_call_text_end = .;
654
655/* Section used for early init (in .S files) */
656#define HEAD_TEXT KEEP(*(.head.text))
657
658#define HEAD_TEXT_SECTION \
659 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
660 HEAD_TEXT \
661 }
662
663/*
664 * Exception table
665 */
666#define EXCEPTION_TABLE(align) \
667 . = ALIGN(align); \
668 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
669 __start___ex_table = .; \
670 KEEP(*(__ex_table)) \
671 __stop___ex_table = .; \
672 }
673
674/*
675 * .BTF
676 */
677#ifdef CONFIG_DEBUG_INFO_BTF
678#define BTF \
679 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
680 __start_BTF = .; \
681 KEEP(*(.BTF)) \
682 __stop_BTF = .; \
683 } \
684 . = ALIGN(4); \
685 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
686 *(.BTF_ids) \
687 }
688#else
689#define BTF
690#endif
691
692/*
693 * Init task
694 */
695#define INIT_TASK_DATA_SECTION(align) \
696 . = ALIGN(align); \
697 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
698 INIT_TASK_DATA(align) \
699 }
700
701#ifdef CONFIG_CONSTRUCTORS
702#define KERNEL_CTORS() . = ALIGN(8); \
703 __ctors_start = .; \
704 KEEP(*(SORT(.ctors.*))) \
705 KEEP(*(.ctors)) \
706 KEEP(*(SORT(.init_array.*))) \
707 KEEP(*(.init_array)) \
708 __ctors_end = .;
709#else
710#define KERNEL_CTORS()
711#endif
712
713/* init and exit section handling */
714#define INIT_DATA \
715 KEEP(*(SORT(___kentry+*))) \
716 *(.init.data init.data.*) \
717 MEM_DISCARD(init.data*) \
718 KERNEL_CTORS() \
719 MCOUNT_REC() \
720 *(.init.rodata .init.rodata.*) \
721 FTRACE_EVENTS() \
722 TRACE_SYSCALLS() \
723 KPROBE_BLACKLIST() \
724 ERROR_INJECT_WHITELIST() \
725 MEM_DISCARD(init.rodata) \
726 CLK_OF_TABLES() \
727 RESERVEDMEM_OF_TABLES() \
728 TIMER_OF_TABLES() \
729 CPU_METHOD_OF_TABLES() \
730 CPUIDLE_METHOD_OF_TABLES() \
731 KERNEL_DTB() \
732 IRQCHIP_OF_MATCH_TABLE() \
733 ACPI_PROBE_TABLE(irqchip) \
734 ACPI_PROBE_TABLE(timer) \
735 THERMAL_TABLE(governor) \
736 EARLYCON_TABLE() \
737 LSM_TABLE() \
738 EARLY_LSM_TABLE() \
739 KUNIT_TABLE()
740
741#define INIT_TEXT \
742 *(.init.text .init.text.*) \
743 *(.text.startup) \
744 MEM_DISCARD(init.text*)
745
746#define EXIT_DATA \
747 *(.exit.data .exit.data.*) \
748 *(.fini_array .fini_array.*) \
749 *(.dtors .dtors.*) \
750 MEM_DISCARD(exit.data*) \
751 MEM_DISCARD(exit.rodata*)
752
753#define EXIT_TEXT \
754 *(.exit.text) \
755 *(.text.exit) \
756 MEM_DISCARD(exit.text)
757
758#define EXIT_CALL \
759 *(.exitcall.exit)
760
761/*
762 * bss (Block Started by Symbol) - uninitialized data
763 * zeroed during startup
764 */
765#define SBSS(sbss_align) \
766 . = ALIGN(sbss_align); \
767 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
768 *(.dynsbss) \
769 *(SBSS_MAIN) \
770 *(.scommon) \
771 }
772
773/*
774 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
775 * sections to the front of bss.
776 */
777#ifndef BSS_FIRST_SECTIONS
778#define BSS_FIRST_SECTIONS
779#endif
780
781#define BSS(bss_align) \
782 . = ALIGN(bss_align); \
783 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
784 BSS_FIRST_SECTIONS \
785 . = ALIGN(PAGE_SIZE); \
786 *(.bss..page_aligned) \
787 . = ALIGN(PAGE_SIZE); \
788 *(.dynbss) \
789 *(BSS_MAIN) \
790 *(COMMON) \
791 }
792
793/*
794 * DWARF debug sections.
795 * Symbols in the DWARF debugging sections are relative to
796 * the beginning of the section so we begin them at 0.
797 */
798#define DWARF_DEBUG \
799 /* DWARF 1 */ \
800 .debug 0 : { *(.debug) } \
801 .line 0 : { *(.line) } \
802 /* GNU DWARF 1 extensions */ \
803 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
804 .debug_sfnames 0 : { *(.debug_sfnames) } \
805 /* DWARF 1.1 and DWARF 2 */ \
806 .debug_aranges 0 : { *(.debug_aranges) } \
807 .debug_pubnames 0 : { *(.debug_pubnames) } \
808 /* DWARF 2 */ \
809 .debug_info 0 : { *(.debug_info \
810 .gnu.linkonce.wi.*) } \
811 .debug_abbrev 0 : { *(.debug_abbrev) } \
812 .debug_line 0 : { *(.debug_line) } \
813 .debug_frame 0 : { *(.debug_frame) } \
814 .debug_str 0 : { *(.debug_str) } \
815 .debug_loc 0 : { *(.debug_loc) } \
816 .debug_macinfo 0 : { *(.debug_macinfo) } \
817 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
818 /* DWARF 3 */ \
819 .debug_ranges 0 : { *(.debug_ranges) } \
820 /* SGI/MIPS DWARF 2 extensions */ \
821 .debug_weaknames 0 : { *(.debug_weaknames) } \
822 .debug_funcnames 0 : { *(.debug_funcnames) } \
823 .debug_typenames 0 : { *(.debug_typenames) } \
824 .debug_varnames 0 : { *(.debug_varnames) } \
825 /* GNU DWARF 2 extensions */ \
826 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
827 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
828 /* DWARF 4 */ \
829 .debug_types 0 : { *(.debug_types) } \
830 /* DWARF 5 */ \
831 .debug_macro 0 : { *(.debug_macro) } \
832 .debug_addr 0 : { *(.debug_addr) }
833
834/* Stabs debugging sections. */
835#define STABS_DEBUG \
836 .stab 0 : { *(.stab) } \
837 .stabstr 0 : { *(.stabstr) } \
838 .stab.excl 0 : { *(.stab.excl) } \
839 .stab.exclstr 0 : { *(.stab.exclstr) } \
840 .stab.index 0 : { *(.stab.index) } \
841 .stab.indexstr 0 : { *(.stab.indexstr) }
842
843/* Required sections not related to debugging. */
844#define ELF_DETAILS \
845 .comment 0 : { *(.comment) } \
846 .symtab 0 : { *(.symtab) } \
847 .strtab 0 : { *(.strtab) } \
848 .shstrtab 0 : { *(.shstrtab) }
849
850#ifdef CONFIG_GENERIC_BUG
851#define BUG_TABLE \
852 . = ALIGN(8); \
853 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
854 __start___bug_table = .; \
855 KEEP(*(__bug_table)) \
856 __stop___bug_table = .; \
857 }
858#else
859#define BUG_TABLE
860#endif
861
862#ifdef CONFIG_UNWINDER_ORC
863#define ORC_UNWIND_TABLE \
864 . = ALIGN(4); \
865 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
866 __start_orc_unwind_ip = .; \
867 KEEP(*(.orc_unwind_ip)) \
868 __stop_orc_unwind_ip = .; \
869 } \
870 . = ALIGN(2); \
871 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
872 __start_orc_unwind = .; \
873 KEEP(*(.orc_unwind)) \
874 __stop_orc_unwind = .; \
875 } \
876 . = ALIGN(4); \
877 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
878 orc_lookup = .; \
879 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) / \
880 LOOKUP_BLOCK_SIZE) + 1) * 4; \
881 orc_lookup_end = .; \
882 }
883#else
884#define ORC_UNWIND_TABLE
885#endif
886
887#ifdef CONFIG_PM_TRACE
888#define TRACEDATA \
889 . = ALIGN(4); \
890 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
891 __tracedata_start = .; \
892 KEEP(*(.tracedata)) \
893 __tracedata_end = .; \
894 }
895#else
896#define TRACEDATA
897#endif
898
899#define NOTES \
900 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
901 __start_notes = .; \
902 KEEP(*(.note.*)) \
903 __stop_notes = .; \
904 } NOTES_HEADERS \
905 NOTES_HEADERS_RESTORE
906
907#define INIT_SETUP(initsetup_align) \
908 . = ALIGN(initsetup_align); \
909 __setup_start = .; \
910 KEEP(*(.init.setup)) \
911 __setup_end = .;
912
913#define INIT_CALLS_LEVEL(level) \
914 __initcall##level##_start = .; \
915 KEEP(*(.initcall##level##.init)) \
916 KEEP(*(.initcall##level##s.init)) \
917
918#define INIT_CALLS \
919 __initcall_start = .; \
920 KEEP(*(.initcallearly.init)) \
921 INIT_CALLS_LEVEL(0) \
922 INIT_CALLS_LEVEL(1) \
923 INIT_CALLS_LEVEL(2) \
924 INIT_CALLS_LEVEL(3) \
925 INIT_CALLS_LEVEL(4) \
926 INIT_CALLS_LEVEL(5) \
927 INIT_CALLS_LEVEL(rootfs) \
928 INIT_CALLS_LEVEL(6) \
929 INIT_CALLS_LEVEL(7) \
930 __initcall_end = .;
931
932#define CON_INITCALL \
933 __con_initcall_start = .; \
934 KEEP(*(.con_initcall.init)) \
935 __con_initcall_end = .;
936
937/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
938#define KUNIT_TABLE() \
939 . = ALIGN(8); \
940 __kunit_suites_start = .; \
941 KEEP(*(.kunit_test_suites)) \
942 __kunit_suites_end = .;
943
944#ifdef CONFIG_BLK_DEV_INITRD
945#define INIT_RAM_FS \
946 . = ALIGN(4); \
947 __initramfs_start = .; \
948 KEEP(*(.init.ramfs)) \
949 . = ALIGN(8); \
950 KEEP(*(.init.ramfs.info))
951#else
952#define INIT_RAM_FS
953#endif
954
955/*
956 * Memory encryption operates on a page basis. Since we need to clear
957 * the memory encryption mask for this section, it needs to be aligned
958 * on a page boundary and be a page-size multiple in length.
959 *
960 * Note: We use a separate section so that only this section gets
961 * decrypted to avoid exposing more than we wish.
962 */
963#ifdef CONFIG_AMD_MEM_ENCRYPT
964#define PERCPU_DECRYPTED_SECTION \
965 . = ALIGN(PAGE_SIZE); \
966 *(.data..percpu..decrypted) \
967 . = ALIGN(PAGE_SIZE);
968#else
969#define PERCPU_DECRYPTED_SECTION
970#endif
971
972
973/*
974 * Default discarded sections.
975 *
976 * Some archs want to discard exit text/data at runtime rather than
977 * link time due to cross-section references such as alt instructions,
978 * bug table, eh_frame, etc. DISCARDS must be the last of output
979 * section definitions so that such archs put those in earlier section
980 * definitions.
981 */
982#ifdef RUNTIME_DISCARD_EXIT
983#define EXIT_DISCARDS
984#else
985#define EXIT_DISCARDS \
986 EXIT_TEXT \
987 EXIT_DATA
988#endif
989
990/*
991 * Clang's -fsanitize=kernel-address and -fsanitize=thread produce
992 * unwanted sections (.eh_frame and .init_array.*), but
993 * CONFIG_CONSTRUCTORS wants to keep any .init_array.* sections.
994 * https://bugs.llvm.org/show_bug.cgi?id=46478
995 */
996#if defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN)
997# ifdef CONFIG_CONSTRUCTORS
998# define SANITIZER_DISCARDS \
999 *(.eh_frame)
1000# else
1001# define SANITIZER_DISCARDS \
1002 *(.init_array) *(.init_array.*) \
1003 *(.eh_frame)
1004# endif
1005#else
1006# define SANITIZER_DISCARDS
1007#endif
1008
1009#define COMMON_DISCARDS \
1010 SANITIZER_DISCARDS \
1011 *(.discard) \
1012 *(.discard.*) \
1013 *(.modinfo) \
1014 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1015 *(.gnu.version*) \
1016
1017#define DISCARDS \
1018 /DISCARD/ : { \
1019 EXIT_DISCARDS \
1020 EXIT_CALL \
1021 COMMON_DISCARDS \
1022 }
1023
1024/**
1025 * PERCPU_INPUT - the percpu input sections
1026 * @cacheline: cacheline size
1027 *
1028 * The core percpu section names and core symbols which do not rely
1029 * directly upon load addresses.
1030 *
1031 * @cacheline is used to align subsections to avoid false cacheline
1032 * sharing between subsections for different purposes.
1033 */
1034#define PERCPU_INPUT(cacheline) \
1035 __per_cpu_start = .; \
1036 *(.data..percpu..first) \
1037 . = ALIGN(PAGE_SIZE); \
1038 *(.data..percpu..page_aligned) \
1039 . = ALIGN(cacheline); \
1040 *(.data..percpu..read_mostly) \
1041 . = ALIGN(cacheline); \
1042 *(.data..percpu) \
1043 *(.data..percpu..shared_aligned) \
1044 PERCPU_DECRYPTED_SECTION \
1045 __per_cpu_end = .;
1046
1047/**
1048 * PERCPU_VADDR - define output section for percpu area
1049 * @cacheline: cacheline size
1050 * @vaddr: explicit base address (optional)
1051 * @phdr: destination PHDR (optional)
1052 *
1053 * Macro which expands to output section for percpu area.
1054 *
1055 * @cacheline is used to align subsections to avoid false cacheline
1056 * sharing between subsections for different purposes.
1057 *
1058 * If @vaddr is not blank, it specifies explicit base address and all
1059 * percpu symbols will be offset from the given address. If blank,
1060 * @vaddr always equals @laddr + LOAD_OFFSET.
1061 *
1062 * @phdr defines the output PHDR to use if not blank. Be warned that
1063 * output PHDR is sticky. If @phdr is specified, the next output
1064 * section in the linker script will go there too. @phdr should have
1065 * a leading colon.
1066 *
1067 * Note that this macros defines __per_cpu_load as an absolute symbol.
1068 * If there is no need to put the percpu section at a predetermined
1069 * address, use PERCPU_SECTION.
1070 */
1071#define PERCPU_VADDR(cacheline, vaddr, phdr) \
1072 __per_cpu_load = .; \
1073 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1074 PERCPU_INPUT(cacheline) \
1075 } phdr \
1076 . = __per_cpu_load + SIZEOF(.data..percpu);
1077
1078/**
1079 * PERCPU_SECTION - define output section for percpu area, simple version
1080 * @cacheline: cacheline size
1081 *
1082 * Align to PAGE_SIZE and outputs output section for percpu area. This
1083 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1084 * __per_cpu_start will be identical.
1085 *
1086 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1087 * except that __per_cpu_load is defined as a relative symbol against
1088 * .data..percpu which is required for relocatable x86_32 configuration.
1089 */
1090#define PERCPU_SECTION(cacheline) \
1091 . = ALIGN(PAGE_SIZE); \
1092 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1093 __per_cpu_load = .; \
1094 PERCPU_INPUT(cacheline) \
1095 }
1096
1097
1098/*
1099 * Definition of the high level *_SECTION macros
1100 * They will fit only a subset of the architectures
1101 */
1102
1103
1104/*
1105 * Writeable data.
1106 * All sections are combined in a single .data section.
1107 * The sections following CONSTRUCTORS are arranged so their
1108 * typical alignment matches.
1109 * A cacheline is typical/always less than a PAGE_SIZE so
1110 * the sections that has this restriction (or similar)
1111 * is located before the ones requiring PAGE_SIZE alignment.
1112 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1113 * matches the requirement of PAGE_ALIGNED_DATA.
1114 *
1115 * use 0 as page_align if page_aligned data is not used */
1116#define RW_DATA(cacheline, pagealigned, inittask) \
1117 . = ALIGN(PAGE_SIZE); \
1118 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1119 INIT_TASK_DATA(inittask) \
1120 NOSAVE_DATA \
1121 PAGE_ALIGNED_DATA(pagealigned) \
1122 CACHELINE_ALIGNED_DATA(cacheline) \
1123 READ_MOSTLY_DATA(cacheline) \
1124 DATA_DATA \
1125 CONSTRUCTORS \
1126 } \
1127 BUG_TABLE \
1128
1129#define INIT_TEXT_SECTION(inittext_align) \
1130 . = ALIGN(inittext_align); \
1131 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1132 _sinittext = .; \
1133 INIT_TEXT \
1134 _einittext = .; \
1135 }
1136
1137#define INIT_DATA_SECTION(initsetup_align) \
1138 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1139 INIT_DATA \
1140 INIT_SETUP(initsetup_align) \
1141 INIT_CALLS \
1142 CON_INITCALL \
1143 INIT_RAM_FS \
1144 }
1145
1146#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1147 . = ALIGN(sbss_align); \
1148 __bss_start = .; \
1149 SBSS(sbss_align) \
1150 BSS(bss_align) \
1151 . = ALIGN(stop_align); \
1152 __bss_stop = .;