Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1#!/usr/bin/perl -w
2# (c) 2008, Steven Rostedt <srostedt@redhat.com>
3# Licensed under the terms of the GNU GPL License version 2
4#
5# recordmcount.pl - makes a section called __mcount_loc that holds
6# all the offsets to the calls to mcount.
7#
8#
9# What we want to end up with this is that each object file will have a
10# section called __mcount_loc that will hold the list of pointers to mcount
11# callers. After final linking, the vmlinux will have within .init.data the
12# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
13# Later on boot up, the kernel will read this list, save the locations and turn
14# them into nops. When tracing or profiling is later enabled, these locations
15# will then be converted back to pointers to some function.
16#
17# This is no easy feat. This script is called just after the original
18# object is compiled and before it is linked.
19#
20# When parse this object file using 'objdump', the references to the call
21# sites are offsets from the section that the call site is in. Hence, all
22# functions in a section that has a call site to mcount, will have the
23# offset from the beginning of the section and not the beginning of the
24# function.
25#
26# But where this section will reside finally in vmlinx is undetermined at
27# this point. So we can't use this kind of offsets to record the final
28# address of this call site.
29#
30# The trick is to change the call offset referring the start of a section to
31# referring a function symbol in this section. During the link step, 'ld' will
32# compute the final address according to the information we record.
33#
34# e.g.
35#
36# .section ".sched.text", "ax"
37# [...]
38# func1:
39# [...]
40# call mcount (offset: 0x10)
41# [...]
42# ret
43# .globl fun2
44# func2: (offset: 0x20)
45# [...]
46# [...]
47# ret
48# func3:
49# [...]
50# call mcount (offset: 0x30)
51# [...]
52#
53# Both relocation offsets for the mcounts in the above example will be
54# offset from .sched.text. If we choose global symbol func2 as a reference and
55# make another file called tmp.s with the new offsets:
56#
57# .section __mcount_loc
58# .quad func2 - 0x10
59# .quad func2 + 0x10
60#
61# We can then compile this tmp.s into tmp.o, and link it back to the original
62# object.
63#
64# In our algorithm, we will choose the first global function we meet in this
65# section as the reference. But this gets hard if there is no global functions
66# in this section. In such a case we have to select a local one. E.g. func1:
67#
68# .section ".sched.text", "ax"
69# func1:
70# [...]
71# call mcount (offset: 0x10)
72# [...]
73# ret
74# func2:
75# [...]
76# call mcount (offset: 0x20)
77# [...]
78# .section "other.section"
79#
80# If we make the tmp.s the same as above, when we link together with
81# the original object, we will end up with two symbols for func1:
82# one local, one global. After final compile, we will end up with
83# an undefined reference to func1 or a wrong reference to another global
84# func1 in other files.
85#
86# Since local objects can reference local variables, we need to find
87# a way to make tmp.o reference the local objects of the original object
88# file after it is linked together. To do this, we convert func1
89# into a global symbol before linking tmp.o. Then after we link tmp.o
90# we will only have a single symbol for func1 that is global.
91# We can convert func1 back into a local symbol and we are done.
92#
93# Here are the steps we take:
94#
95# 1) Record all the local and weak symbols by using 'nm'
96# 2) Use objdump to find all the call site offsets and sections for
97# mcount.
98# 3) Compile the list into its own object.
99# 4) Do we have to deal with local functions? If not, go to step 8.
100# 5) Make an object that converts these local functions to global symbols
101# with objcopy.
102# 6) Link together this new object with the list object.
103# 7) Convert the local functions back to local symbols and rename
104# the result as the original object.
105# 8) Link the object with the list object.
106# 9) Move the result back to the original object.
107#
108
109use strict;
110
111my $P = $0;
112$P =~ s@.*/@@g;
113
114my $V = '0.1';
115
116if ($#ARGV != 11) {
117 print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
118 print "version: $V\n";
119 exit(1);
120}
121
122my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
123 $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
124
125# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
126if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
127 exit(0);
128}
129
130# Acceptable sections to record.
131my %text_sections = (
132 ".text" => 1,
133 ".ref.text" => 1,
134 ".sched.text" => 1,
135 ".spinlock.text" => 1,
136 ".irqentry.text" => 1,
137 ".softirqentry.text" => 1,
138 ".kprobes.text" => 1,
139 ".text.unlikely" => 1,
140);
141
142# Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
143$objdump = 'objdump' if (!$objdump);
144$objcopy = 'objcopy' if (!$objcopy);
145$cc = 'gcc' if (!$cc);
146$ld = 'ld' if (!$ld);
147$nm = 'nm' if (!$nm);
148$rm = 'rm' if (!$rm);
149$mv = 'mv' if (!$mv);
150
151#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
152# "'$nm' '$rm' '$mv' '$inputfile'\n";
153
154my %locals; # List of local (static) functions
155my %weak; # List of weak functions
156my %convert; # List of local functions used that needs conversion
157
158my $type;
159my $local_regex; # Match a local function (return function)
160my $weak_regex; # Match a weak function (return function)
161my $section_regex; # Find the start of a section
162my $function_regex; # Find the name of a function
163 # (return offset and func name)
164my $mcount_regex; # Find the call site to mcount (return offset)
165my $mcount_adjust; # Address adjustment to mcount offset
166my $alignment; # The .align value to use for $mcount_section
167my $section_type; # Section header plus possible alignment command
168my $can_use_local = 0; # If we can use local function references
169
170# Shut up recordmcount if user has older objcopy
171my $quiet_recordmcount = ".tmp_quiet_recordmcount";
172my $print_warning = 1;
173$print_warning = 0 if ( -f $quiet_recordmcount);
174
175##
176# check_objcopy - whether objcopy supports --globalize-symbols
177#
178# --globalize-symbols came out in 2.17, we must test the version
179# of objcopy, and if it is less than 2.17, then we can not
180# record local functions.
181sub check_objcopy
182{
183 open (IN, "$objcopy --version |") or die "error running $objcopy";
184 while (<IN>) {
185 if (/objcopy.*\s(\d+)\.(\d+)/) {
186 $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
187 last;
188 }
189 }
190 close (IN);
191
192 if (!$can_use_local && $print_warning) {
193 print STDERR "WARNING: could not find objcopy version or version " .
194 "is less than 2.17.\n" .
195 "\tLocal function references are disabled.\n";
196 open (QUIET, ">$quiet_recordmcount");
197 printf QUIET "Disables the warning from recordmcount.pl\n";
198 close QUIET;
199 }
200}
201
202if ($arch =~ /(x86(_64)?)|(i386)/) {
203 if ($bits == 64) {
204 $arch = "x86_64";
205 } else {
206 $arch = "i386";
207 }
208}
209
210#
211# We base the defaults off of i386, the other archs may
212# feel free to change them in the below if statements.
213#
214$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
215$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
216$section_regex = "Disassembly of section\\s+(\\S+):";
217$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
218$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
219$section_type = '@progbits';
220$mcount_adjust = 0;
221$type = ".long";
222
223if ($arch eq "x86_64") {
224 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
225 $type = ".quad";
226 $alignment = 8;
227 $mcount_adjust = -1;
228
229 # force flags for this arch
230 $ld .= " -m elf_x86_64";
231 $objdump .= " -M x86-64";
232 $objcopy .= " -O elf64-x86-64";
233 $cc .= " -m64";
234
235} elsif ($arch eq "i386") {
236 $alignment = 4;
237 $mcount_adjust = -1;
238
239 # force flags for this arch
240 $ld .= " -m elf_i386";
241 $objdump .= " -M i386";
242 $objcopy .= " -O elf32-i386";
243 $cc .= " -m32";
244
245} elsif ($arch eq "s390" && $bits == 64) {
246 if ($cc =~ /-DCC_USING_HOTPATCH/) {
247 $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
248 $mcount_adjust = 0;
249 } else {
250 $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
251 $mcount_adjust = -14;
252 }
253 $alignment = 8;
254 $type = ".quad";
255 $ld .= " -m elf64_s390";
256 $cc .= " -m64";
257
258} elsif ($arch eq "sh") {
259 $alignment = 2;
260
261 # force flags for this arch
262 $ld .= " -m shlelf_linux";
263 $objcopy .= " -O elf32-sh-linux";
264
265} elsif ($arch eq "powerpc") {
266 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
267 # See comment in the sparc64 section for why we use '\w'.
268 $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
269 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
270
271 if ($bits == 64) {
272 $type = ".quad";
273 }
274
275} elsif ($arch eq "arm") {
276 $alignment = 2;
277 $section_type = '%progbits';
278 $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
279 "\\s+(__gnu_mcount_nc|mcount)\$";
280
281} elsif ($arch eq "arm64") {
282 $alignment = 3;
283 $section_type = '%progbits';
284 $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
285 $type = ".quad";
286} elsif ($arch eq "ia64") {
287 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
288 $type = "data8";
289
290 if ($is_module eq "0") {
291 $cc .= " -mconstant-gp";
292 }
293} elsif ($arch eq "sparc64") {
294 # In the objdump output there are giblets like:
295 # 0000000000000000 <igmp_net_exit-0x18>:
296 # As there's some data blobs that get emitted into the
297 # text section before the first instructions and the first
298 # real symbols. We don't want to match that, so to combat
299 # this we use '\w' so we'll match just plain symbol names,
300 # and not those that also include hex offsets inside of the
301 # '<>' brackets. Actually the generic function_regex setting
302 # could safely use this too.
303 $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
304
305 # Sparc64 calls '_mcount' instead of plain 'mcount'.
306 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
307
308 $alignment = 8;
309 $type = ".xword";
310 $ld .= " -m elf64_sparc";
311 $cc .= " -m64";
312 $objcopy .= " -O elf64-sparc";
313} elsif ($arch eq "mips") {
314 # To enable module support, we need to enable the -mlong-calls option
315 # of gcc for module, after using this option, we can not get the real
316 # offset of the calling to _mcount, but the offset of the lui
317 # instruction or the addiu one. herein, we record the address of the
318 # first one, and then we can replace this instruction by a branch
319 # instruction to jump over the profiling function to filter the
320 # indicated functions, or swith back to the lui instruction to trace
321 # them, which means dynamic tracing.
322 #
323 # c: 3c030000 lui v1,0x0
324 # c: R_MIPS_HI16 _mcount
325 # c: R_MIPS_NONE *ABS*
326 # c: R_MIPS_NONE *ABS*
327 # 10: 64630000 daddiu v1,v1,0
328 # 10: R_MIPS_LO16 _mcount
329 # 10: R_MIPS_NONE *ABS*
330 # 10: R_MIPS_NONE *ABS*
331 # 14: 03e0082d move at,ra
332 # 18: 0060f809 jalr v1
333 #
334 # for the kernel:
335 #
336 # 10: 03e0082d move at,ra
337 # 14: 0c000000 jal 0 <loongson_halt>
338 # 14: R_MIPS_26 _mcount
339 # 14: R_MIPS_NONE *ABS*
340 # 14: R_MIPS_NONE *ABS*
341 # 18: 00020021 nop
342 if ($is_module eq "0") {
343 $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
344 } else {
345 $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
346 }
347 $objdump .= " -Melf-trad".$endian."mips ";
348
349 if ($endian eq "big") {
350 $endian = " -EB ";
351 $ld .= " -melf".$bits."btsmip";
352 } else {
353 $endian = " -EL ";
354 $ld .= " -melf".$bits."ltsmip";
355 }
356
357 $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
358 $ld .= $endian;
359
360 if ($bits == 64) {
361 $function_regex =
362 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
363 $type = ".dword";
364 }
365} elsif ($arch eq "microblaze") {
366 # Microblaze calls '_mcount' instead of plain 'mcount'.
367 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
368} elsif ($arch eq "blackfin") {
369 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
370 $mcount_adjust = -4;
371} elsif ($arch eq "tilegx" || $arch eq "tile") {
372 # Default to the newer TILE-Gx architecture if only "tile" is given.
373 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
374 $type = ".quad";
375 $alignment = 8;
376} else {
377 die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
378}
379
380my $text_found = 0;
381my $read_function = 0;
382my $opened = 0;
383my $mcount_section = "__mcount_loc";
384
385my $dirname;
386my $filename;
387my $prefix;
388my $ext;
389
390if ($inputfile =~ m,^(.*)/([^/]*)$,) {
391 $dirname = $1;
392 $filename = $2;
393} else {
394 $dirname = ".";
395 $filename = $inputfile;
396}
397
398if ($filename =~ m,^(.*)(\.\S),) {
399 $prefix = $1;
400 $ext = $2;
401} else {
402 $prefix = $filename;
403 $ext = "";
404}
405
406my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
407my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
408
409check_objcopy();
410
411#
412# Step 1: find all the local (static functions) and weak symbols.
413# 't' is local, 'w/W' is weak
414#
415open (IN, "$nm $inputfile|") || die "error running $nm";
416while (<IN>) {
417 if (/$local_regex/) {
418 $locals{$1} = 1;
419 } elsif (/$weak_regex/) {
420 $weak{$2} = $1;
421 }
422}
423close(IN);
424
425my @offsets; # Array of offsets of mcount callers
426my $ref_func; # reference function to use for offsets
427my $offset = 0; # offset of ref_func to section beginning
428
429##
430# update_funcs - print out the current mcount callers
431#
432# Go through the list of offsets to callers and write them to
433# the output file in a format that can be read by an assembler.
434#
435sub update_funcs
436{
437 return unless ($ref_func and @offsets);
438
439 # Sanity check on weak function. A weak function may be overwritten by
440 # another function of the same name, making all these offsets incorrect.
441 if (defined $weak{$ref_func}) {
442 die "$inputfile: ERROR: referencing weak function" .
443 " $ref_func for mcount\n";
444 }
445
446 # is this function static? If so, note this fact.
447 if (defined $locals{$ref_func}) {
448
449 # only use locals if objcopy supports globalize-symbols
450 if (!$can_use_local) {
451 return;
452 }
453 $convert{$ref_func} = 1;
454 }
455
456 # Loop through all the mcount caller offsets and print a reference
457 # to the caller based from the ref_func.
458 if (!$opened) {
459 open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
460 $opened = 1;
461 print FILE "\t.section $mcount_section,\"a\",$section_type\n";
462 print FILE "\t.align $alignment\n" if (defined($alignment));
463 }
464 foreach my $cur_offset (@offsets) {
465 printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
466 }
467}
468
469#
470# Step 2: find the sections and mcount call sites
471#
472open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
473
474my $text;
475
476
477# read headers first
478my $read_headers = 1;
479
480while (<IN>) {
481
482 if ($read_headers && /$mcount_section/) {
483 #
484 # Somehow the make process can execute this script on an
485 # object twice. If it does, we would duplicate the mcount
486 # section and it will cause the function tracer self test
487 # to fail. Check if the mcount section exists, and if it does,
488 # warn and exit.
489 #
490 print STDERR "ERROR: $mcount_section already in $inputfile\n" .
491 "\tThis may be an indication that your build is corrupted.\n" .
492 "\tDelete $inputfile and try again. If the same object file\n" .
493 "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
494 exit(-1);
495 }
496
497 # is it a section?
498 if (/$section_regex/) {
499 $read_headers = 0;
500
501 # Only record text sections that we know are safe
502 $read_function = defined($text_sections{$1});
503 # print out any recorded offsets
504 update_funcs();
505
506 # reset all markers and arrays
507 $text_found = 0;
508 undef($ref_func);
509 undef(@offsets);
510
511 # section found, now is this a start of a function?
512 } elsif ($read_function && /$function_regex/) {
513 $text_found = 1;
514 $text = $2;
515
516 # if this is either a local function or a weak function
517 # keep looking for functions that are global that
518 # we can use safely.
519 if (!defined($locals{$text}) && !defined($weak{$text})) {
520 $ref_func = $text;
521 $read_function = 0;
522 $offset = hex $1;
523 } else {
524 # if we already have a function, and this is weak, skip it
525 if (!defined($ref_func) && !defined($weak{$text}) &&
526 # PPC64 can have symbols that start with .L and
527 # gcc considers these special. Don't use them!
528 $text !~ /^\.L/) {
529 $ref_func = $text;
530 $offset = hex $1;
531 }
532 }
533 }
534 # is this a call site to mcount? If so, record it to print later
535 if ($text_found && /$mcount_regex/) {
536 push(@offsets, (hex $1) + $mcount_adjust);
537 }
538}
539
540# dump out anymore offsets that may have been found
541update_funcs();
542
543# If we did not find any mcount callers, we are done (do nothing).
544if (!$opened) {
545 exit(0);
546}
547
548close(FILE);
549
550#
551# Step 3: Compile the file that holds the list of call sites to mcount.
552#
553`$cc -o $mcount_o -c $mcount_s`;
554
555my @converts = keys %convert;
556
557#
558# Step 4: Do we have sections that started with local functions?
559#
560if ($#converts >= 0) {
561 my $globallist = "";
562 my $locallist = "";
563
564 foreach my $con (@converts) {
565 $globallist .= " --globalize-symbol $con";
566 $locallist .= " --localize-symbol $con";
567 }
568
569 my $globalobj = $dirname . "/.tmp_gl_" . $filename;
570 my $globalmix = $dirname . "/.tmp_mx_" . $filename;
571
572 #
573 # Step 5: set up each local function as a global
574 #
575 `$objcopy $globallist $inputfile $globalobj`;
576
577 #
578 # Step 6: Link the global version to our list.
579 #
580 `$ld -r $globalobj $mcount_o -o $globalmix`;
581
582 #
583 # Step 7: Convert the local functions back into local symbols
584 #
585 `$objcopy $locallist $globalmix $inputfile`;
586
587 # Remove the temp files
588 `$rm $globalobj $globalmix`;
589
590} else {
591
592 my $mix = $dirname . "/.tmp_mx_" . $filename;
593
594 #
595 # Step 8: Link the object with our list of call sites object.
596 #
597 `$ld -r $inputfile $mcount_o -o $mix`;
598
599 #
600 # Step 9: Move the result back to the original object.
601 #
602 `$mv $mix $inputfile`;
603}
604
605# Clean up the temp files
606`$rm $mcount_o $mcount_s`;
607
608exit(0);