Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1#!/usr/bin/perl -w
2# (c) 2008, Steven Rostedt <srostedt@redhat.com>
3# Licensed under the terms of the GNU GPL License version 2
4#
5# recordmcount.pl - makes a section called __mcount_loc that holds
6# all the offsets to the calls to mcount.
7#
8#
9# What we want to end up with this is that each object file will have a
10# section called __mcount_loc that will hold the list of pointers to mcount
11# callers. After final linking, the vmlinux will have within .init.data the
12# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
13# Later on boot up, the kernel will read this list, save the locations and turn
14# them into nops. When tracing or profiling is later enabled, these locations
15# will then be converted back to pointers to some function.
16#
17# This is no easy feat. This script is called just after the original
18# object is compiled and before it is linked.
19#
20# When parse this object file using 'objdump', the references to the call
21# sites are offsets from the section that the call site is in. Hence, all
22# functions in a section that has a call site to mcount, will have the
23# offset from the beginning of the section and not the beginning of the
24# function.
25#
26# But where this section will reside finally in vmlinx is undetermined at
27# this point. So we can't use this kind of offsets to record the final
28# address of this call site.
29#
30# The trick is to change the call offset referring the start of a section to
31# referring a function symbol in this section. During the link step, 'ld' will
32# compute the final address according to the information we record.
33#
34# e.g.
35#
36# .section ".sched.text", "ax"
37# [...]
38# func1:
39# [...]
40# call mcount (offset: 0x10)
41# [...]
42# ret
43# .globl fun2
44# func2: (offset: 0x20)
45# [...]
46# [...]
47# ret
48# func3:
49# [...]
50# call mcount (offset: 0x30)
51# [...]
52#
53# Both relocation offsets for the mcounts in the above example will be
54# offset from .sched.text. If we choose global symbol func2 as a reference and
55# make another file called tmp.s with the new offsets:
56#
57# .section __mcount_loc
58# .quad func2 - 0x10
59# .quad func2 + 0x10
60#
61# We can then compile this tmp.s into tmp.o, and link it back to the original
62# object.
63#
64# In our algorithm, we will choose the first global function we meet in this
65# section as the reference. But this gets hard if there is no global functions
66# in this section. In such a case we have to select a local one. E.g. func1:
67#
68# .section ".sched.text", "ax"
69# func1:
70# [...]
71# call mcount (offset: 0x10)
72# [...]
73# ret
74# func2:
75# [...]
76# call mcount (offset: 0x20)
77# [...]
78# .section "other.section"
79#
80# If we make the tmp.s the same as above, when we link together with
81# the original object, we will end up with two symbols for func1:
82# one local, one global. After final compile, we will end up with
83# an undefined reference to func1 or a wrong reference to another global
84# func1 in other files.
85#
86# Since local objects can reference local variables, we need to find
87# a way to make tmp.o reference the local objects of the original object
88# file after it is linked together. To do this, we convert func1
89# into a global symbol before linking tmp.o. Then after we link tmp.o
90# we will only have a single symbol for func1 that is global.
91# We can convert func1 back into a local symbol and we are done.
92#
93# Here are the steps we take:
94#
95# 1) Record all the local and weak symbols by using 'nm'
96# 2) Use objdump to find all the call site offsets and sections for
97# mcount.
98# 3) Compile the list into its own object.
99# 4) Do we have to deal with local functions? If not, go to step 8.
100# 5) Make an object that converts these local functions to global symbols
101# with objcopy.
102# 6) Link together this new object with the list object.
103# 7) Convert the local functions back to local symbols and rename
104# the result as the original object.
105# 8) Link the object with the list object.
106# 9) Move the result back to the original object.
107#
108
109use strict;
110
111my $P = $0;
112$P =~ s@.*/@@g;
113
114my $V = '0.1';
115
116if ($#ARGV != 11) {
117 print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
118 print "version: $V\n";
119 exit(1);
120}
121
122my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
123 $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
124
125# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
126if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
127 exit(0);
128}
129
130# Acceptable sections to record.
131my %text_sections = (
132 ".text" => 1,
133 ".ref.text" => 1,
134 ".sched.text" => 1,
135 ".spinlock.text" => 1,
136 ".irqentry.text" => 1,
137 ".kprobes.text" => 1,
138 ".text.unlikely" => 1,
139);
140
141# Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
142$objdump = 'objdump' if (!$objdump);
143$objcopy = 'objcopy' if (!$objcopy);
144$cc = 'gcc' if (!$cc);
145$ld = 'ld' if (!$ld);
146$nm = 'nm' if (!$nm);
147$rm = 'rm' if (!$rm);
148$mv = 'mv' if (!$mv);
149
150#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
151# "'$nm' '$rm' '$mv' '$inputfile'\n";
152
153my %locals; # List of local (static) functions
154my %weak; # List of weak functions
155my %convert; # List of local functions used that needs conversion
156
157my $type;
158my $local_regex; # Match a local function (return function)
159my $weak_regex; # Match a weak function (return function)
160my $section_regex; # Find the start of a section
161my $function_regex; # Find the name of a function
162 # (return offset and func name)
163my $mcount_regex; # Find the call site to mcount (return offset)
164my $mcount_adjust; # Address adjustment to mcount offset
165my $alignment; # The .align value to use for $mcount_section
166my $section_type; # Section header plus possible alignment command
167my $can_use_local = 0; # If we can use local function references
168
169# Shut up recordmcount if user has older objcopy
170my $quiet_recordmcount = ".tmp_quiet_recordmcount";
171my $print_warning = 1;
172$print_warning = 0 if ( -f $quiet_recordmcount);
173
174##
175# check_objcopy - whether objcopy supports --globalize-symbols
176#
177# --globalize-symbols came out in 2.17, we must test the version
178# of objcopy, and if it is less than 2.17, then we can not
179# record local functions.
180sub check_objcopy
181{
182 open (IN, "$objcopy --version |") or die "error running $objcopy";
183 while (<IN>) {
184 if (/objcopy.*\s(\d+)\.(\d+)/) {
185 $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
186 last;
187 }
188 }
189 close (IN);
190
191 if (!$can_use_local && $print_warning) {
192 print STDERR "WARNING: could not find objcopy version or version " .
193 "is less than 2.17.\n" .
194 "\tLocal function references are disabled.\n";
195 open (QUIET, ">$quiet_recordmcount");
196 printf QUIET "Disables the warning from recordmcount.pl\n";
197 close QUIET;
198 }
199}
200
201if ($arch =~ /(x86(_64)?)|(i386)/) {
202 if ($bits == 64) {
203 $arch = "x86_64";
204 } else {
205 $arch = "i386";
206 }
207}
208
209#
210# We base the defaults off of i386, the other archs may
211# feel free to change them in the below if statements.
212#
213$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
214$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
215$section_regex = "Disassembly of section\\s+(\\S+):";
216$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
217$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
218$section_type = '@progbits';
219$mcount_adjust = 0;
220$type = ".long";
221
222if ($arch eq "x86_64") {
223 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
224 $type = ".quad";
225 $alignment = 8;
226 $mcount_adjust = -1;
227
228 # force flags for this arch
229 $ld .= " -m elf_x86_64";
230 $objdump .= " -M x86-64";
231 $objcopy .= " -O elf64-x86-64";
232 $cc .= " -m64";
233
234} elsif ($arch eq "i386") {
235 $alignment = 4;
236 $mcount_adjust = -1;
237
238 # force flags for this arch
239 $ld .= " -m elf_i386";
240 $objdump .= " -M i386";
241 $objcopy .= " -O elf32-i386";
242 $cc .= " -m32";
243
244} elsif ($arch eq "s390" && $bits == 64) {
245 $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
246 $mcount_adjust = -14;
247 $alignment = 8;
248 $type = ".quad";
249 $ld .= " -m elf64_s390";
250 $cc .= " -m64";
251
252} elsif ($arch eq "sh") {
253 $alignment = 2;
254
255 # force flags for this arch
256 $ld .= " -m shlelf_linux";
257 $objcopy .= " -O elf32-sh-linux";
258
259} elsif ($arch eq "powerpc") {
260 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
261 $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
262 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
263
264 if ($bits == 64) {
265 $type = ".quad";
266 }
267
268} elsif ($arch eq "arm") {
269 $alignment = 2;
270 $section_type = '%progbits';
271 $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
272 "\\s+(__gnu_mcount_nc|mcount)\$";
273
274} elsif ($arch eq "arm64") {
275 $alignment = 3;
276 $section_type = '%progbits';
277 $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
278 $type = ".quad";
279} elsif ($arch eq "ia64") {
280 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
281 $type = "data8";
282
283 if ($is_module eq "0") {
284 $cc .= " -mconstant-gp";
285 }
286} elsif ($arch eq "sparc64") {
287 # In the objdump output there are giblets like:
288 # 0000000000000000 <igmp_net_exit-0x18>:
289 # As there's some data blobs that get emitted into the
290 # text section before the first instructions and the first
291 # real symbols. We don't want to match that, so to combat
292 # this we use '\w' so we'll match just plain symbol names,
293 # and not those that also include hex offsets inside of the
294 # '<>' brackets. Actually the generic function_regex setting
295 # could safely use this too.
296 $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
297
298 # Sparc64 calls '_mcount' instead of plain 'mcount'.
299 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
300
301 $alignment = 8;
302 $type = ".xword";
303 $ld .= " -m elf64_sparc";
304 $cc .= " -m64";
305 $objcopy .= " -O elf64-sparc";
306} elsif ($arch eq "mips") {
307 # To enable module support, we need to enable the -mlong-calls option
308 # of gcc for module, after using this option, we can not get the real
309 # offset of the calling to _mcount, but the offset of the lui
310 # instruction or the addiu one. herein, we record the address of the
311 # first one, and then we can replace this instruction by a branch
312 # instruction to jump over the profiling function to filter the
313 # indicated functions, or swith back to the lui instruction to trace
314 # them, which means dynamic tracing.
315 #
316 # c: 3c030000 lui v1,0x0
317 # c: R_MIPS_HI16 _mcount
318 # c: R_MIPS_NONE *ABS*
319 # c: R_MIPS_NONE *ABS*
320 # 10: 64630000 daddiu v1,v1,0
321 # 10: R_MIPS_LO16 _mcount
322 # 10: R_MIPS_NONE *ABS*
323 # 10: R_MIPS_NONE *ABS*
324 # 14: 03e0082d move at,ra
325 # 18: 0060f809 jalr v1
326 #
327 # for the kernel:
328 #
329 # 10: 03e0082d move at,ra
330 # 14: 0c000000 jal 0 <loongson_halt>
331 # 14: R_MIPS_26 _mcount
332 # 14: R_MIPS_NONE *ABS*
333 # 14: R_MIPS_NONE *ABS*
334 # 18: 00020021 nop
335 if ($is_module eq "0") {
336 $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
337 } else {
338 $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
339 }
340 $objdump .= " -Melf-trad".$endian."mips ";
341
342 if ($endian eq "big") {
343 $endian = " -EB ";
344 $ld .= " -melf".$bits."btsmip";
345 } else {
346 $endian = " -EL ";
347 $ld .= " -melf".$bits."ltsmip";
348 }
349
350 $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
351 $ld .= $endian;
352
353 if ($bits == 64) {
354 $function_regex =
355 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
356 $type = ".dword";
357 }
358} elsif ($arch eq "microblaze") {
359 # Microblaze calls '_mcount' instead of plain 'mcount'.
360 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
361} elsif ($arch eq "blackfin") {
362 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
363 $mcount_adjust = -4;
364} elsif ($arch eq "tilegx" || $arch eq "tile") {
365 # Default to the newer TILE-Gx architecture if only "tile" is given.
366 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
367 $type = ".quad";
368 $alignment = 8;
369} else {
370 die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
371}
372
373my $text_found = 0;
374my $read_function = 0;
375my $opened = 0;
376my $mcount_section = "__mcount_loc";
377
378my $dirname;
379my $filename;
380my $prefix;
381my $ext;
382
383if ($inputfile =~ m,^(.*)/([^/]*)$,) {
384 $dirname = $1;
385 $filename = $2;
386} else {
387 $dirname = ".";
388 $filename = $inputfile;
389}
390
391if ($filename =~ m,^(.*)(\.\S),) {
392 $prefix = $1;
393 $ext = $2;
394} else {
395 $prefix = $filename;
396 $ext = "";
397}
398
399my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
400my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
401
402check_objcopy();
403
404#
405# Step 1: find all the local (static functions) and weak symbols.
406# 't' is local, 'w/W' is weak
407#
408open (IN, "$nm $inputfile|") || die "error running $nm";
409while (<IN>) {
410 if (/$local_regex/) {
411 $locals{$1} = 1;
412 } elsif (/$weak_regex/) {
413 $weak{$2} = $1;
414 }
415}
416close(IN);
417
418my @offsets; # Array of offsets of mcount callers
419my $ref_func; # reference function to use for offsets
420my $offset = 0; # offset of ref_func to section beginning
421
422##
423# update_funcs - print out the current mcount callers
424#
425# Go through the list of offsets to callers and write them to
426# the output file in a format that can be read by an assembler.
427#
428sub update_funcs
429{
430 return unless ($ref_func and @offsets);
431
432 # Sanity check on weak function. A weak function may be overwritten by
433 # another function of the same name, making all these offsets incorrect.
434 if (defined $weak{$ref_func}) {
435 die "$inputfile: ERROR: referencing weak function" .
436 " $ref_func for mcount\n";
437 }
438
439 # is this function static? If so, note this fact.
440 if (defined $locals{$ref_func}) {
441
442 # only use locals if objcopy supports globalize-symbols
443 if (!$can_use_local) {
444 return;
445 }
446 $convert{$ref_func} = 1;
447 }
448
449 # Loop through all the mcount caller offsets and print a reference
450 # to the caller based from the ref_func.
451 if (!$opened) {
452 open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
453 $opened = 1;
454 print FILE "\t.section $mcount_section,\"a\",$section_type\n";
455 print FILE "\t.align $alignment\n" if (defined($alignment));
456 }
457 foreach my $cur_offset (@offsets) {
458 printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
459 }
460}
461
462#
463# Step 2: find the sections and mcount call sites
464#
465open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
466
467my $text;
468
469
470# read headers first
471my $read_headers = 1;
472
473while (<IN>) {
474
475 if ($read_headers && /$mcount_section/) {
476 #
477 # Somehow the make process can execute this script on an
478 # object twice. If it does, we would duplicate the mcount
479 # section and it will cause the function tracer self test
480 # to fail. Check if the mcount section exists, and if it does,
481 # warn and exit.
482 #
483 print STDERR "ERROR: $mcount_section already in $inputfile\n" .
484 "\tThis may be an indication that your build is corrupted.\n" .
485 "\tDelete $inputfile and try again. If the same object file\n" .
486 "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
487 exit(-1);
488 }
489
490 # is it a section?
491 if (/$section_regex/) {
492 $read_headers = 0;
493
494 # Only record text sections that we know are safe
495 $read_function = defined($text_sections{$1});
496 # print out any recorded offsets
497 update_funcs();
498
499 # reset all markers and arrays
500 $text_found = 0;
501 undef($ref_func);
502 undef(@offsets);
503
504 # section found, now is this a start of a function?
505 } elsif ($read_function && /$function_regex/) {
506 $text_found = 1;
507 $text = $2;
508
509 # if this is either a local function or a weak function
510 # keep looking for functions that are global that
511 # we can use safely.
512 if (!defined($locals{$text}) && !defined($weak{$text})) {
513 $ref_func = $text;
514 $read_function = 0;
515 $offset = hex $1;
516 } else {
517 # if we already have a function, and this is weak, skip it
518 if (!defined($ref_func) && !defined($weak{$text}) &&
519 # PPC64 can have symbols that start with .L and
520 # gcc considers these special. Don't use them!
521 $text !~ /^\.L/) {
522 $ref_func = $text;
523 $offset = hex $1;
524 }
525 }
526 }
527 # is this a call site to mcount? If so, record it to print later
528 if ($text_found && /$mcount_regex/) {
529 push(@offsets, (hex $1) + $mcount_adjust);
530 }
531}
532
533# dump out anymore offsets that may have been found
534update_funcs();
535
536# If we did not find any mcount callers, we are done (do nothing).
537if (!$opened) {
538 exit(0);
539}
540
541close(FILE);
542
543#
544# Step 3: Compile the file that holds the list of call sites to mcount.
545#
546`$cc -o $mcount_o -c $mcount_s`;
547
548my @converts = keys %convert;
549
550#
551# Step 4: Do we have sections that started with local functions?
552#
553if ($#converts >= 0) {
554 my $globallist = "";
555 my $locallist = "";
556
557 foreach my $con (@converts) {
558 $globallist .= " --globalize-symbol $con";
559 $locallist .= " --localize-symbol $con";
560 }
561
562 my $globalobj = $dirname . "/.tmp_gl_" . $filename;
563 my $globalmix = $dirname . "/.tmp_mx_" . $filename;
564
565 #
566 # Step 5: set up each local function as a global
567 #
568 `$objcopy $globallist $inputfile $globalobj`;
569
570 #
571 # Step 6: Link the global version to our list.
572 #
573 `$ld -r $globalobj $mcount_o -o $globalmix`;
574
575 #
576 # Step 7: Convert the local functions back into local symbols
577 #
578 `$objcopy $locallist $globalmix $inputfile`;
579
580 # Remove the temp files
581 `$rm $globalobj $globalmix`;
582
583} else {
584
585 my $mix = $dirname . "/.tmp_mx_" . $filename;
586
587 #
588 # Step 8: Link the object with our list of call sites object.
589 #
590 `$ld -r $inputfile $mcount_o -o $mix`;
591
592 #
593 # Step 9: Move the result back to the original object.
594 #
595 `$mv $mix $inputfile`;
596}
597
598# Clean up the temp files
599`$rm $mcount_o $mcount_s`;
600
601exit(0);