Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU(PAGE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA_SECTION(PAGE_SIZE)
27 * RW_DATA_SECTION(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 * NOTES
32 *
33 * BSS_SECTION(0, 0, 0)
34 * _end = .;
35 *
36 * STABS_DEBUG
37 * DWARF_DEBUG
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * [_stext, _etext] is the text section
44 * [_sdata, _edata] is the data section
45 *
46 * Some of the included output section have their own set of constants.
47 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
48 * [__nosave_begin, __nosave_end] for the nosave data
49 */
50
51#ifndef LOAD_OFFSET
52#define LOAD_OFFSET 0
53#endif
54
55#ifndef SYMBOL_PREFIX
56#define VMLINUX_SYMBOL(sym) sym
57#else
58#define PASTE2(x,y) x##y
59#define PASTE(x,y) PASTE2(x,y)
60#define VMLINUX_SYMBOL(sym) PASTE(SYMBOL_PREFIX, sym)
61#endif
62
63/* Align . to a 8 byte boundary equals to maximum function alignment. */
64#define ALIGN_FUNCTION() . = ALIGN(8)
65
66/* The actual configuration determine if the init/exit sections
67 * are handled as text/data or they can be discarded (which
68 * often happens at runtime)
69 */
70#ifdef CONFIG_HOTPLUG
71#define DEV_KEEP(sec) *(.dev##sec)
72#define DEV_DISCARD(sec)
73#else
74#define DEV_KEEP(sec)
75#define DEV_DISCARD(sec) *(.dev##sec)
76#endif
77
78#ifdef CONFIG_HOTPLUG_CPU
79#define CPU_KEEP(sec) *(.cpu##sec)
80#define CPU_DISCARD(sec)
81#else
82#define CPU_KEEP(sec)
83#define CPU_DISCARD(sec) *(.cpu##sec)
84#endif
85
86#if defined(CONFIG_MEMORY_HOTPLUG)
87#define MEM_KEEP(sec) *(.mem##sec)
88#define MEM_DISCARD(sec)
89#else
90#define MEM_KEEP(sec)
91#define MEM_DISCARD(sec) *(.mem##sec)
92#endif
93
94#ifdef CONFIG_FTRACE_MCOUNT_RECORD
95#define MCOUNT_REC() . = ALIGN(8); \
96 VMLINUX_SYMBOL(__start_mcount_loc) = .; \
97 *(__mcount_loc) \
98 VMLINUX_SYMBOL(__stop_mcount_loc) = .;
99#else
100#define MCOUNT_REC()
101#endif
102
103#ifdef CONFIG_TRACE_BRANCH_PROFILING
104#define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
105 *(_ftrace_annotated_branch) \
106 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
107#else
108#define LIKELY_PROFILE()
109#endif
110
111#ifdef CONFIG_PROFILE_ALL_BRANCHES
112#define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
113 *(_ftrace_branch) \
114 VMLINUX_SYMBOL(__stop_branch_profile) = .;
115#else
116#define BRANCH_PROFILE()
117#endif
118
119#ifdef CONFIG_EVENT_TRACING
120#define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .; \
121 *(_ftrace_events) \
122 VMLINUX_SYMBOL(__stop_ftrace_events) = .;
123#else
124#define FTRACE_EVENTS()
125#endif
126
127#ifdef CONFIG_TRACING
128#define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
129 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
130 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
131#else
132#define TRACE_PRINTKS()
133#endif
134
135#ifdef CONFIG_FTRACE_SYSCALLS
136#define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
137 *(__syscalls_metadata) \
138 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
139#else
140#define TRACE_SYSCALLS()
141#endif
142
143/* .data section */
144#define DATA_DATA \
145 *(.data) \
146 *(.ref.data) \
147 DEV_KEEP(init.data) \
148 DEV_KEEP(exit.data) \
149 CPU_KEEP(init.data) \
150 CPU_KEEP(exit.data) \
151 MEM_KEEP(init.data) \
152 MEM_KEEP(exit.data) \
153 . = ALIGN(8); \
154 VMLINUX_SYMBOL(__start___markers) = .; \
155 *(__markers) \
156 VMLINUX_SYMBOL(__stop___markers) = .; \
157 . = ALIGN(32); \
158 VMLINUX_SYMBOL(__start___tracepoints) = .; \
159 *(__tracepoints) \
160 VMLINUX_SYMBOL(__stop___tracepoints) = .; \
161 /* implement dynamic printk debug */ \
162 . = ALIGN(8); \
163 VMLINUX_SYMBOL(__start___verbose) = .; \
164 *(__verbose) \
165 VMLINUX_SYMBOL(__stop___verbose) = .; \
166 LIKELY_PROFILE() \
167 BRANCH_PROFILE() \
168 TRACE_PRINTKS() \
169 FTRACE_EVENTS() \
170 TRACE_SYSCALLS()
171
172/*
173 * Data section helpers
174 */
175#define NOSAVE_DATA \
176 . = ALIGN(PAGE_SIZE); \
177 VMLINUX_SYMBOL(__nosave_begin) = .; \
178 *(.data..nosave) \
179 . = ALIGN(PAGE_SIZE); \
180 VMLINUX_SYMBOL(__nosave_end) = .;
181
182#define PAGE_ALIGNED_DATA(page_align) \
183 . = ALIGN(page_align); \
184 *(.data..page_aligned)
185
186#define READ_MOSTLY_DATA(align) \
187 . = ALIGN(align); \
188 *(.data..read_mostly)
189
190#define CACHELINE_ALIGNED_DATA(align) \
191 . = ALIGN(align); \
192 *(.data..cacheline_aligned)
193
194#define INIT_TASK_DATA(align) \
195 . = ALIGN(align); \
196 *(.data..init_task)
197
198/*
199 * Read only Data
200 */
201#define RO_DATA_SECTION(align) \
202 . = ALIGN((align)); \
203 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
204 VMLINUX_SYMBOL(__start_rodata) = .; \
205 *(.rodata) *(.rodata.*) \
206 *(__vermagic) /* Kernel version magic */ \
207 *(__markers_strings) /* Markers: strings */ \
208 *(__tracepoints_strings)/* Tracepoints: strings */ \
209 } \
210 \
211 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
212 *(.rodata1) \
213 } \
214 \
215 BUG_TABLE \
216 \
217 /* PCI quirks */ \
218 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
219 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
220 *(.pci_fixup_early) \
221 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
222 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
223 *(.pci_fixup_header) \
224 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
225 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
226 *(.pci_fixup_final) \
227 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
228 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
229 *(.pci_fixup_enable) \
230 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
231 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
232 *(.pci_fixup_resume) \
233 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
234 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
235 *(.pci_fixup_resume_early) \
236 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
237 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
238 *(.pci_fixup_suspend) \
239 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
240 } \
241 \
242 /* Built-in firmware blobs */ \
243 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
244 VMLINUX_SYMBOL(__start_builtin_fw) = .; \
245 *(.builtin_fw) \
246 VMLINUX_SYMBOL(__end_builtin_fw) = .; \
247 } \
248 \
249 /* RapidIO route ops */ \
250 .rio_ops : AT(ADDR(.rio_ops) - LOAD_OFFSET) { \
251 VMLINUX_SYMBOL(__start_rio_switch_ops) = .; \
252 *(.rio_switch_ops) \
253 VMLINUX_SYMBOL(__end_rio_switch_ops) = .; \
254 } \
255 \
256 TRACEDATA \
257 \
258 /* Kernel symbol table: Normal symbols */ \
259 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
260 VMLINUX_SYMBOL(__start___ksymtab) = .; \
261 *(__ksymtab) \
262 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
263 } \
264 \
265 /* Kernel symbol table: GPL-only symbols */ \
266 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
267 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
268 *(__ksymtab_gpl) \
269 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
270 } \
271 \
272 /* Kernel symbol table: Normal unused symbols */ \
273 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
274 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
275 *(__ksymtab_unused) \
276 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
277 } \
278 \
279 /* Kernel symbol table: GPL-only unused symbols */ \
280 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
281 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
282 *(__ksymtab_unused_gpl) \
283 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
284 } \
285 \
286 /* Kernel symbol table: GPL-future-only symbols */ \
287 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
288 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
289 *(__ksymtab_gpl_future) \
290 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
291 } \
292 \
293 /* Kernel symbol table: Normal symbols */ \
294 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
295 VMLINUX_SYMBOL(__start___kcrctab) = .; \
296 *(__kcrctab) \
297 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
298 } \
299 \
300 /* Kernel symbol table: GPL-only symbols */ \
301 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
302 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
303 *(__kcrctab_gpl) \
304 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
305 } \
306 \
307 /* Kernel symbol table: Normal unused symbols */ \
308 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
309 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
310 *(__kcrctab_unused) \
311 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
312 } \
313 \
314 /* Kernel symbol table: GPL-only unused symbols */ \
315 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
316 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
317 *(__kcrctab_unused_gpl) \
318 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
319 } \
320 \
321 /* Kernel symbol table: GPL-future-only symbols */ \
322 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
323 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
324 *(__kcrctab_gpl_future) \
325 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
326 } \
327 \
328 /* Kernel symbol table: strings */ \
329 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
330 *(__ksymtab_strings) \
331 } \
332 \
333 /* __*init sections */ \
334 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
335 *(.ref.rodata) \
336 DEV_KEEP(init.rodata) \
337 DEV_KEEP(exit.rodata) \
338 CPU_KEEP(init.rodata) \
339 CPU_KEEP(exit.rodata) \
340 MEM_KEEP(init.rodata) \
341 MEM_KEEP(exit.rodata) \
342 } \
343 \
344 /* Built-in module parameters. */ \
345 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
346 VMLINUX_SYMBOL(__start___param) = .; \
347 *(__param) \
348 VMLINUX_SYMBOL(__stop___param) = .; \
349 . = ALIGN((align)); \
350 VMLINUX_SYMBOL(__end_rodata) = .; \
351 } \
352 . = ALIGN((align));
353
354/* RODATA & RO_DATA provided for backward compatibility.
355 * All archs are supposed to use RO_DATA() */
356#define RODATA RO_DATA_SECTION(4096)
357#define RO_DATA(align) RO_DATA_SECTION(align)
358
359#define SECURITY_INIT \
360 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
361 VMLINUX_SYMBOL(__security_initcall_start) = .; \
362 *(.security_initcall.init) \
363 VMLINUX_SYMBOL(__security_initcall_end) = .; \
364 }
365
366/* .text section. Map to function alignment to avoid address changes
367 * during second ld run in second ld pass when generating System.map */
368#define TEXT_TEXT \
369 ALIGN_FUNCTION(); \
370 *(.text.hot) \
371 *(.text) \
372 *(.ref.text) \
373 DEV_KEEP(init.text) \
374 DEV_KEEP(exit.text) \
375 CPU_KEEP(init.text) \
376 CPU_KEEP(exit.text) \
377 MEM_KEEP(init.text) \
378 MEM_KEEP(exit.text) \
379 *(.text.unlikely)
380
381
382/* sched.text is aling to function alignment to secure we have same
383 * address even at second ld pass when generating System.map */
384#define SCHED_TEXT \
385 ALIGN_FUNCTION(); \
386 VMLINUX_SYMBOL(__sched_text_start) = .; \
387 *(.sched.text) \
388 VMLINUX_SYMBOL(__sched_text_end) = .;
389
390/* spinlock.text is aling to function alignment to secure we have same
391 * address even at second ld pass when generating System.map */
392#define LOCK_TEXT \
393 ALIGN_FUNCTION(); \
394 VMLINUX_SYMBOL(__lock_text_start) = .; \
395 *(.spinlock.text) \
396 VMLINUX_SYMBOL(__lock_text_end) = .;
397
398#define KPROBES_TEXT \
399 ALIGN_FUNCTION(); \
400 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
401 *(.kprobes.text) \
402 VMLINUX_SYMBOL(__kprobes_text_end) = .;
403
404#ifdef CONFIG_FUNCTION_GRAPH_TRACER
405#define IRQENTRY_TEXT \
406 ALIGN_FUNCTION(); \
407 VMLINUX_SYMBOL(__irqentry_text_start) = .; \
408 *(.irqentry.text) \
409 VMLINUX_SYMBOL(__irqentry_text_end) = .;
410#else
411#define IRQENTRY_TEXT
412#endif
413
414/* Section used for early init (in .S files) */
415#define HEAD_TEXT *(.head.text)
416
417#define HEAD_TEXT_SECTION \
418 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
419 HEAD_TEXT \
420 }
421
422/*
423 * Exception table
424 */
425#define EXCEPTION_TABLE(align) \
426 . = ALIGN(align); \
427 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
428 VMLINUX_SYMBOL(__start___ex_table) = .; \
429 *(__ex_table) \
430 VMLINUX_SYMBOL(__stop___ex_table) = .; \
431 }
432
433/*
434 * Init task
435 */
436#define INIT_TASK_DATA_SECTION(align) \
437 . = ALIGN(align); \
438 .data..init_task : { \
439 INIT_TASK_DATA(align) \
440 }
441
442#ifdef CONFIG_CONSTRUCTORS
443#define KERNEL_CTORS() . = ALIGN(8); \
444 VMLINUX_SYMBOL(__ctors_start) = .; \
445 *(.ctors) \
446 VMLINUX_SYMBOL(__ctors_end) = .;
447#else
448#define KERNEL_CTORS()
449#endif
450
451/* init and exit section handling */
452#define INIT_DATA \
453 *(.init.data) \
454 DEV_DISCARD(init.data) \
455 CPU_DISCARD(init.data) \
456 MEM_DISCARD(init.data) \
457 KERNEL_CTORS() \
458 *(.init.rodata) \
459 MCOUNT_REC() \
460 DEV_DISCARD(init.rodata) \
461 CPU_DISCARD(init.rodata) \
462 MEM_DISCARD(init.rodata)
463
464#define INIT_TEXT \
465 *(.init.text) \
466 DEV_DISCARD(init.text) \
467 CPU_DISCARD(init.text) \
468 MEM_DISCARD(init.text)
469
470#define EXIT_DATA \
471 *(.exit.data) \
472 DEV_DISCARD(exit.data) \
473 DEV_DISCARD(exit.rodata) \
474 CPU_DISCARD(exit.data) \
475 CPU_DISCARD(exit.rodata) \
476 MEM_DISCARD(exit.data) \
477 MEM_DISCARD(exit.rodata)
478
479#define EXIT_TEXT \
480 *(.exit.text) \
481 DEV_DISCARD(exit.text) \
482 CPU_DISCARD(exit.text) \
483 MEM_DISCARD(exit.text)
484
485#define EXIT_CALL \
486 *(.exitcall.exit)
487
488/*
489 * bss (Block Started by Symbol) - uninitialized data
490 * zeroed during startup
491 */
492#define SBSS(sbss_align) \
493 . = ALIGN(sbss_align); \
494 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
495 *(.sbss) \
496 *(.scommon) \
497 }
498
499#define BSS(bss_align) \
500 . = ALIGN(bss_align); \
501 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
502 *(.bss..page_aligned) \
503 *(.dynbss) \
504 *(.bss) \
505 *(COMMON) \
506 }
507
508/*
509 * DWARF debug sections.
510 * Symbols in the DWARF debugging sections are relative to
511 * the beginning of the section so we begin them at 0.
512 */
513#define DWARF_DEBUG \
514 /* DWARF 1 */ \
515 .debug 0 : { *(.debug) } \
516 .line 0 : { *(.line) } \
517 /* GNU DWARF 1 extensions */ \
518 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
519 .debug_sfnames 0 : { *(.debug_sfnames) } \
520 /* DWARF 1.1 and DWARF 2 */ \
521 .debug_aranges 0 : { *(.debug_aranges) } \
522 .debug_pubnames 0 : { *(.debug_pubnames) } \
523 /* DWARF 2 */ \
524 .debug_info 0 : { *(.debug_info \
525 .gnu.linkonce.wi.*) } \
526 .debug_abbrev 0 : { *(.debug_abbrev) } \
527 .debug_line 0 : { *(.debug_line) } \
528 .debug_frame 0 : { *(.debug_frame) } \
529 .debug_str 0 : { *(.debug_str) } \
530 .debug_loc 0 : { *(.debug_loc) } \
531 .debug_macinfo 0 : { *(.debug_macinfo) } \
532 /* SGI/MIPS DWARF 2 extensions */ \
533 .debug_weaknames 0 : { *(.debug_weaknames) } \
534 .debug_funcnames 0 : { *(.debug_funcnames) } \
535 .debug_typenames 0 : { *(.debug_typenames) } \
536 .debug_varnames 0 : { *(.debug_varnames) } \
537
538 /* Stabs debugging sections. */
539#define STABS_DEBUG \
540 .stab 0 : { *(.stab) } \
541 .stabstr 0 : { *(.stabstr) } \
542 .stab.excl 0 : { *(.stab.excl) } \
543 .stab.exclstr 0 : { *(.stab.exclstr) } \
544 .stab.index 0 : { *(.stab.index) } \
545 .stab.indexstr 0 : { *(.stab.indexstr) } \
546 .comment 0 : { *(.comment) }
547
548#ifdef CONFIG_GENERIC_BUG
549#define BUG_TABLE \
550 . = ALIGN(8); \
551 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
552 VMLINUX_SYMBOL(__start___bug_table) = .; \
553 *(__bug_table) \
554 VMLINUX_SYMBOL(__stop___bug_table) = .; \
555 }
556#else
557#define BUG_TABLE
558#endif
559
560#ifdef CONFIG_PM_TRACE
561#define TRACEDATA \
562 . = ALIGN(4); \
563 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
564 VMLINUX_SYMBOL(__tracedata_start) = .; \
565 *(.tracedata) \
566 VMLINUX_SYMBOL(__tracedata_end) = .; \
567 }
568#else
569#define TRACEDATA
570#endif
571
572#define NOTES \
573 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
574 VMLINUX_SYMBOL(__start_notes) = .; \
575 *(.note.*) \
576 VMLINUX_SYMBOL(__stop_notes) = .; \
577 }
578
579#define INIT_SETUP(initsetup_align) \
580 . = ALIGN(initsetup_align); \
581 VMLINUX_SYMBOL(__setup_start) = .; \
582 *(.init.setup) \
583 VMLINUX_SYMBOL(__setup_end) = .;
584
585#define INITCALLS \
586 *(.initcallearly.init) \
587 VMLINUX_SYMBOL(__early_initcall_end) = .; \
588 *(.initcall0.init) \
589 *(.initcall0s.init) \
590 *(.initcall1.init) \
591 *(.initcall1s.init) \
592 *(.initcall2.init) \
593 *(.initcall2s.init) \
594 *(.initcall3.init) \
595 *(.initcall3s.init) \
596 *(.initcall4.init) \
597 *(.initcall4s.init) \
598 *(.initcall5.init) \
599 *(.initcall5s.init) \
600 *(.initcallrootfs.init) \
601 *(.initcall6.init) \
602 *(.initcall6s.init) \
603 *(.initcall7.init) \
604 *(.initcall7s.init)
605
606#define INIT_CALLS \
607 VMLINUX_SYMBOL(__initcall_start) = .; \
608 INITCALLS \
609 VMLINUX_SYMBOL(__initcall_end) = .;
610
611#define CON_INITCALL \
612 VMLINUX_SYMBOL(__con_initcall_start) = .; \
613 *(.con_initcall.init) \
614 VMLINUX_SYMBOL(__con_initcall_end) = .;
615
616#define SECURITY_INITCALL \
617 VMLINUX_SYMBOL(__security_initcall_start) = .; \
618 *(.security_initcall.init) \
619 VMLINUX_SYMBOL(__security_initcall_end) = .;
620
621#ifdef CONFIG_BLK_DEV_INITRD
622#define INIT_RAM_FS \
623 . = ALIGN(PAGE_SIZE); \
624 VMLINUX_SYMBOL(__initramfs_start) = .; \
625 *(.init.ramfs) \
626 VMLINUX_SYMBOL(__initramfs_end) = .;
627#else
628#define INIT_RAM_FS
629#endif
630
631/*
632 * Default discarded sections.
633 *
634 * Some archs want to discard exit text/data at runtime rather than
635 * link time due to cross-section references such as alt instructions,
636 * bug table, eh_frame, etc. DISCARDS must be the last of output
637 * section definitions so that such archs put those in earlier section
638 * definitions.
639 */
640#define DISCARDS \
641 /DISCARD/ : { \
642 EXIT_TEXT \
643 EXIT_DATA \
644 EXIT_CALL \
645 *(.discard) \
646 }
647
648/**
649 * PERCPU_VADDR - define output section for percpu area
650 * @vaddr: explicit base address (optional)
651 * @phdr: destination PHDR (optional)
652 *
653 * Macro which expands to output section for percpu area. If @vaddr
654 * is not blank, it specifies explicit base address and all percpu
655 * symbols will be offset from the given address. If blank, @vaddr
656 * always equals @laddr + LOAD_OFFSET.
657 *
658 * @phdr defines the output PHDR to use if not blank. Be warned that
659 * output PHDR is sticky. If @phdr is specified, the next output
660 * section in the linker script will go there too. @phdr should have
661 * a leading colon.
662 *
663 * Note that this macros defines __per_cpu_load as an absolute symbol.
664 * If there is no need to put the percpu section at a predetermined
665 * address, use PERCPU().
666 */
667#define PERCPU_VADDR(vaddr, phdr) \
668 VMLINUX_SYMBOL(__per_cpu_load) = .; \
669 .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
670 - LOAD_OFFSET) { \
671 VMLINUX_SYMBOL(__per_cpu_start) = .; \
672 *(.data..percpu..first) \
673 *(.data..percpu..page_aligned) \
674 *(.data..percpu) \
675 *(.data..percpu..shared_aligned) \
676 VMLINUX_SYMBOL(__per_cpu_end) = .; \
677 } phdr \
678 . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
679
680/**
681 * PERCPU - define output section for percpu area, simple version
682 * @align: required alignment
683 *
684 * Align to @align and outputs output section for percpu area. This
685 * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
686 * __per_cpu_start will be identical.
687 *
688 * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
689 * that __per_cpu_load is defined as a relative symbol against
690 * .data..percpu which is required for relocatable x86_32
691 * configuration.
692 */
693#define PERCPU(align) \
694 . = ALIGN(align); \
695 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
696 VMLINUX_SYMBOL(__per_cpu_load) = .; \
697 VMLINUX_SYMBOL(__per_cpu_start) = .; \
698 *(.data..percpu..first) \
699 *(.data..percpu..page_aligned) \
700 *(.data..percpu) \
701 *(.data..percpu..shared_aligned) \
702 VMLINUX_SYMBOL(__per_cpu_end) = .; \
703 }
704
705
706/*
707 * Definition of the high level *_SECTION macros
708 * They will fit only a subset of the architectures
709 */
710
711
712/*
713 * Writeable data.
714 * All sections are combined in a single .data section.
715 * The sections following CONSTRUCTORS are arranged so their
716 * typical alignment matches.
717 * A cacheline is typical/always less than a PAGE_SIZE so
718 * the sections that has this restriction (or similar)
719 * is located before the ones requiring PAGE_SIZE alignment.
720 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
721 * matches the requirment of PAGE_ALIGNED_DATA.
722 *
723 * use 0 as page_align if page_aligned data is not used */
724#define RW_DATA_SECTION(cacheline, pagealigned, inittask) \
725 . = ALIGN(PAGE_SIZE); \
726 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
727 INIT_TASK_DATA(inittask) \
728 NOSAVE_DATA \
729 PAGE_ALIGNED_DATA(pagealigned) \
730 CACHELINE_ALIGNED_DATA(cacheline) \
731 READ_MOSTLY_DATA(cacheline) \
732 DATA_DATA \
733 CONSTRUCTORS \
734 }
735
736#define INIT_TEXT_SECTION(inittext_align) \
737 . = ALIGN(inittext_align); \
738 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
739 VMLINUX_SYMBOL(_sinittext) = .; \
740 INIT_TEXT \
741 VMLINUX_SYMBOL(_einittext) = .; \
742 }
743
744#define INIT_DATA_SECTION(initsetup_align) \
745 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
746 INIT_DATA \
747 INIT_SETUP(initsetup_align) \
748 INIT_CALLS \
749 CON_INITCALL \
750 SECURITY_INITCALL \
751 INIT_RAM_FS \
752 }
753
754#define BSS_SECTION(sbss_align, bss_align, stop_align) \
755 . = ALIGN(sbss_align); \
756 VMLINUX_SYMBOL(__bss_start) = .; \
757 SBSS(sbss_align) \
758 BSS(bss_align) \
759 . = ALIGN(stop_align); \
760 VMLINUX_SYMBOL(__bss_stop) = .;