Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1#ifndef LOAD_OFFSET
2#define LOAD_OFFSET 0
3#endif
4
5#ifndef VMLINUX_SYMBOL
6#define VMLINUX_SYMBOL(_sym_) _sym_
7#endif
8
9/* Align . to a 8 byte boundary equals to maximum function alignment. */
10#define ALIGN_FUNCTION() . = ALIGN(8)
11
12#define RODATA \
13 . = ALIGN(4096); \
14 __start_rodata = .; \
15 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
16 *(.rodata) *(.rodata.*) \
17 *(__vermagic) /* Kernel version magic */ \
18 } \
19 \
20 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
21 *(.rodata1) \
22 } \
23 \
24 /* PCI quirks */ \
25 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
26 VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
27 *(.pci_fixup_early) \
28 VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
29 VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
30 *(.pci_fixup_header) \
31 VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
32 VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
33 *(.pci_fixup_final) \
34 VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
35 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
36 *(.pci_fixup_enable) \
37 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
38 } \
39 \
40 /* RapidIO route ops */ \
41 .rio_route : AT(ADDR(.rio_route) - LOAD_OFFSET) { \
42 VMLINUX_SYMBOL(__start_rio_route_ops) = .; \
43 *(.rio_route_ops) \
44 VMLINUX_SYMBOL(__end_rio_route_ops) = .; \
45 } \
46 \
47 /* Kernel symbol table: Normal symbols */ \
48 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
49 VMLINUX_SYMBOL(__start___ksymtab) = .; \
50 *(__ksymtab) \
51 VMLINUX_SYMBOL(__stop___ksymtab) = .; \
52 } \
53 \
54 /* Kernel symbol table: GPL-only symbols */ \
55 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
56 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
57 *(__ksymtab_gpl) \
58 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
59 } \
60 \
61 /* Kernel symbol table: Normal unused symbols */ \
62 __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
63 VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
64 *(__ksymtab_unused) \
65 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
66 } \
67 \
68 /* Kernel symbol table: GPL-only unused symbols */ \
69 __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
70 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
71 *(__ksymtab_unused_gpl) \
72 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
73 } \
74 \
75 /* Kernel symbol table: GPL-future-only symbols */ \
76 __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
77 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
78 *(__ksymtab_gpl_future) \
79 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
80 } \
81 \
82 /* Kernel symbol table: Normal symbols */ \
83 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
84 VMLINUX_SYMBOL(__start___kcrctab) = .; \
85 *(__kcrctab) \
86 VMLINUX_SYMBOL(__stop___kcrctab) = .; \
87 } \
88 \
89 /* Kernel symbol table: GPL-only symbols */ \
90 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
91 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
92 *(__kcrctab_gpl) \
93 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
94 } \
95 \
96 /* Kernel symbol table: Normal unused symbols */ \
97 __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
98 VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
99 *(__kcrctab_unused) \
100 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
101 } \
102 \
103 /* Kernel symbol table: GPL-only unused symbols */ \
104 __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
105 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
106 *(__kcrctab_unused_gpl) \
107 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
108 } \
109 \
110 /* Kernel symbol table: GPL-future-only symbols */ \
111 __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
112 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
113 *(__kcrctab_gpl_future) \
114 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
115 } \
116 \
117 /* Kernel symbol table: strings */ \
118 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
119 *(__ksymtab_strings) \
120 } \
121 \
122 /* Built-in module parameters. */ \
123 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
124 VMLINUX_SYMBOL(__start___param) = .; \
125 *(__param) \
126 VMLINUX_SYMBOL(__stop___param) = .; \
127 } \
128 \
129 /* Unwind data binary search table */ \
130 EH_FRAME_HDR \
131 \
132 __end_rodata = .; \
133 . = ALIGN(4096);
134
135#define SECURITY_INIT \
136 .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
137 VMLINUX_SYMBOL(__security_initcall_start) = .; \
138 *(.security_initcall.init) \
139 VMLINUX_SYMBOL(__security_initcall_end) = .; \
140 }
141
142/* sched.text is aling to function alignment to secure we have same
143 * address even at second ld pass when generating System.map */
144#define SCHED_TEXT \
145 ALIGN_FUNCTION(); \
146 VMLINUX_SYMBOL(__sched_text_start) = .; \
147 *(.sched.text) \
148 VMLINUX_SYMBOL(__sched_text_end) = .;
149
150/* spinlock.text is aling to function alignment to secure we have same
151 * address even at second ld pass when generating System.map */
152#define LOCK_TEXT \
153 ALIGN_FUNCTION(); \
154 VMLINUX_SYMBOL(__lock_text_start) = .; \
155 *(.spinlock.text) \
156 VMLINUX_SYMBOL(__lock_text_end) = .;
157
158#define KPROBES_TEXT \
159 ALIGN_FUNCTION(); \
160 VMLINUX_SYMBOL(__kprobes_text_start) = .; \
161 *(.kprobes.text) \
162 VMLINUX_SYMBOL(__kprobes_text_end) = .;
163
164#ifdef CONFIG_STACK_UNWIND
165 /* Unwind data binary search table */
166#define EH_FRAME_HDR \
167 .eh_frame_hdr : AT(ADDR(.eh_frame_hdr) - LOAD_OFFSET) { \
168 VMLINUX_SYMBOL(__start_unwind_hdr) = .; \
169 *(.eh_frame_hdr) \
170 VMLINUX_SYMBOL(__end_unwind_hdr) = .; \
171 }
172#else
173#define EH_FRAME_HDR
174#endif
175
176 /* DWARF debug sections.
177 Symbols in the DWARF debugging sections are relative to
178 the beginning of the section so we begin them at 0. */
179#define DWARF_DEBUG \
180 /* DWARF 1 */ \
181 .debug 0 : { *(.debug) } \
182 .line 0 : { *(.line) } \
183 /* GNU DWARF 1 extensions */ \
184 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
185 .debug_sfnames 0 : { *(.debug_sfnames) } \
186 /* DWARF 1.1 and DWARF 2 */ \
187 .debug_aranges 0 : { *(.debug_aranges) } \
188 .debug_pubnames 0 : { *(.debug_pubnames) } \
189 /* DWARF 2 */ \
190 .debug_info 0 : { *(.debug_info \
191 .gnu.linkonce.wi.*) } \
192 .debug_abbrev 0 : { *(.debug_abbrev) } \
193 .debug_line 0 : { *(.debug_line) } \
194 .debug_frame 0 : { *(.debug_frame) } \
195 .debug_str 0 : { *(.debug_str) } \
196 .debug_loc 0 : { *(.debug_loc) } \
197 .debug_macinfo 0 : { *(.debug_macinfo) } \
198 /* SGI/MIPS DWARF 2 extensions */ \
199 .debug_weaknames 0 : { *(.debug_weaknames) } \
200 .debug_funcnames 0 : { *(.debug_funcnames) } \
201 .debug_typenames 0 : { *(.debug_typenames) } \
202 .debug_varnames 0 : { *(.debug_varnames) } \
203
204 /* Stabs debugging sections. */
205#define STABS_DEBUG \
206 .stab 0 : { *(.stab) } \
207 .stabstr 0 : { *(.stabstr) } \
208 .stab.excl 0 : { *(.stab.excl) } \
209 .stab.exclstr 0 : { *(.stab.exclstr) } \
210 .stab.index 0 : { *(.stab.index) } \
211 .stab.indexstr 0 : { *(.stab.indexstr) } \
212 .comment 0 : { *(.comment) }
213
214#define NOTES \
215 .notes : { *(.note.*) } :note
216
217#define INITCALLS \
218 *(.initcall1.init) \
219 *(.initcall1s.init) \
220 *(.initcall2.init) \
221 *(.initcall2s.init) \
222 *(.initcall3.init) \
223 *(.initcall3s.init) \
224 *(.initcall4.init) \
225 *(.initcall4s.init) \
226 *(.initcall5.init) \
227 *(.initcall5s.init) \
228 *(.initcall6.init) \
229 *(.initcall6s.init) \
230 *(.initcall7.init) \
231 *(.initcall7s.init)
232