Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1#!/usr/bin/awk -f
2# SPDX-License-Identifier: GPL-2.0
3# Before running this script please ensure that your PATH is
4# typical as you use for compilation/installation. I use
5# /bin /sbin /usr/bin /usr/sbin /usr/local/bin, but it may
6# differ on your system.
7
8BEGIN {
9 usage = "If some fields are empty or look unusual you may have an old version.\n"
10 usage = usage "Compare to the current minimal requirements in Documentation/Changes.\n"
11 print usage
12
13 system("uname -a")
14 printf("\n")
15
16 vernum = "[0-9]+([.]?[0-9]+)+"
17 libc = "libc[.]so[.][0-9]+$"
18 libcpp = "(libg|stdc)[+]+[.]so([.][0-9]+)+$"
19
20 printversion("GNU C", version("gcc -dumpversion"))
21 printversion("GNU Make", version("make --version"))
22 printversion("Binutils", version("ld -v"))
23 printversion("Util-linux", version("mount --version"))
24 printversion("Mount", version("mount --version"))
25 printversion("Module-init-tools", version("depmod -V"))
26 printversion("E2fsprogs", version("tune2fs"))
27 printversion("Jfsutils", version("fsck.jfs -V"))
28 printversion("Xfsprogs", version("xfs_db -V"))
29 printversion("Pcmciautils", version("pccardctl -V"))
30 printversion("Pcmcia-cs", version("cardmgr -V"))
31 printversion("Quota-tools", version("quota -V"))
32 printversion("PPP", version("pppd --version"))
33 printversion("Isdn4k-utils", version("isdnctrl"))
34 printversion("Nfs-utils", version("showmount --version"))
35 printversion("Bison", version("bison --version"))
36 printversion("Flex", version("flex --version"))
37
38 while ("ldconfig -p 2>/dev/null" | getline > 0)
39 if ($NF ~ libc || $NF ~ libcpp)
40 if (!seen[ver = version("readlink " $NF)]++)
41 printversion("Linux C" ($NF ~ libcpp? "++" : "") " Library", ver)
42
43 printversion("Dynamic linker (ldd)", version("ldd --version"))
44 printversion("Procps", version("ps --version"))
45 printversion("Net-tools", version("ifconfig --version"))
46 printversion("Kbd", version("loadkeys -V"))
47 printversion("Console-tools", version("loadkeys -V"))
48 printversion("Sh-utils", version("expr --v"))
49 printversion("Udev", version("udevadm --version"))
50 printversion("Wireless-tools", version("iwconfig --version"))
51
52 while ("sort /proc/modules" | getline > 0) {
53 mods = mods sep $1
54 sep = " "
55 }
56 printversion("Modules Loaded", mods)
57}
58
59function version(cmd, ver) {
60 cmd = cmd " 2>&1"
61 while (cmd | getline > 0) {
62 if (match($0, vernum)) {
63 ver = substr($0, RSTART, RLENGTH)
64 break
65 }
66 }
67 close(cmd)
68 return ver
69}
70
71function printversion(name, value, ofmt) {
72 if (value != "") {
73 ofmt = "%-20s\t%s\n"
74 printf(ofmt, name, value)
75 }
76}