Linux kernel mirror (for testing)
git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git
tjh.dev
kernel
os
linux
1/*
2 * Common module linker script, always used when linking a module.
3 * Archs are free to supply their own linker scripts. ld will
4 * combine them automatically.
5 */
6#ifdef CONFIG_UNWIND_TABLES
7#define DISCARD_EH_FRAME
8#else
9#define DISCARD_EH_FRAME *(.eh_frame)
10#endif
11
12#include <asm-generic/codetag.lds.h>
13
14SECTIONS {
15 /DISCARD/ : {
16 *(.discard)
17 *(.discard.*)
18 *(.export_symbol)
19 *(.no_trim_symbol)
20 }
21
22 __ksymtab 0 : ALIGN(8) { *(SORT(___ksymtab+*)) }
23 __ksymtab_gpl 0 : ALIGN(8) { *(SORT(___ksymtab_gpl+*)) }
24 __kcrctab 0 : ALIGN(4) { *(SORT(___kcrctab+*)) }
25 __kcrctab_gpl 0 : ALIGN(4) { *(SORT(___kcrctab_gpl+*)) }
26
27 .ctors 0 : ALIGN(8) { *(SORT(.ctors.*)) *(.ctors) }
28 .init_array 0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
29
30 .altinstructions 0 : ALIGN(8) { KEEP(*(.altinstructions)) }
31 __bug_table 0 : ALIGN(8) { KEEP(*(__bug_table)) }
32 __jump_table 0 : ALIGN(8) { KEEP(*(__jump_table)) }
33 __ex_table 0 : ALIGN(4) { KEEP(*(__ex_table)) }
34
35 __patchable_function_entries : { *(__patchable_function_entries) }
36
37 __klp_funcs 0: ALIGN(8) { KEEP(*(__klp_funcs)) }
38
39 __klp_objects 0: ALIGN(8) {
40 __start_klp_objects = .;
41 KEEP(*(__klp_objects))
42 __stop_klp_objects = .;
43 }
44
45#ifdef CONFIG_ARCH_USES_CFI_TRAPS
46 __kcfi_traps : { KEEP(*(.kcfi_traps)) }
47#endif
48
49 .text : {
50 *(.text .text.[0-9a-zA-Z_]*)
51 }
52
53 .bss : {
54 *(.bss .bss.[0-9a-zA-Z_]*)
55 *(.bss..L*)
56 }
57
58 .data : {
59 *(.data .data.[0-9a-zA-Z_]*)
60 *(.data..L*)
61 }
62
63 .rodata : {
64 *(.rodata .rodata.[0-9a-zA-Z_]*)
65 *(.rodata..L*)
66 }
67
68 MOD_SEPARATE_CODETAG_SECTIONS()
69}
70
71/* bring in arch-specific sections */
72#include <asm/module.lds.h>