tangled.org
Monorepo for Tangled
tangled.org
boltless.me
1{
2 nixpkgs,
3 system,
4 hostSystem,
5 self,
6}: let
7 envVar = name: let
8 var = builtins.getEnv name;
9 in
10 if var == ""
11 then throw "\$${name} must be defined, see https://docs.tangled.org/hacking-on-tangled.html#hacking-on-tangled for more details"
12 else var;
13 envVarOr = name: default: let
14 var = builtins.getEnv name;
15 in
16 if var != ""
17 then var
18 else default;
19
20 plcUrl = envVarOr "TANGLED_VM_PLC_URL" "https://plc.directory";
21 jetstream = envVarOr "TANGLED_VM_JETSTREAM_ENDPOINT" "wss://jetstream1.us-west.bsky.network/subscribe";
22in
23 nixpkgs.lib.nixosSystem {
24 inherit system;
25 modules = [
26 self.nixosModules.knot
27 self.nixosModules.spindle
28 self.nixosModules.knotmirror
29 ({
30 lib,
31 config,
32 pkgs,
33 ...
34 }: {
35 virtualisation.vmVariant.virtualisation = {
36 host.pkgs = import nixpkgs {system = hostSystem;};
37
38 graphics = false;
39 memorySize = 2048;
40 diskSize = 10 * 1024;
41 cores = 2;
42 forwardPorts = [
43 # ssh
44 {
45 from = "host";
46 host.port = 2222;
47 guest.port = 22;
48 }
49 # knot
50 {
51 from = "host";
52 host.port = 6444;
53 guest.port = 6444;
54 }
55 # spindle
56 {
57 from = "host";
58 host.port = 6555;
59 guest.port = 6555;
60 }
61 # knotmirror
62 {
63 from = "host";
64 host.port = 7007; # 7000 is deserved in macos for Airplay
65 guest.port = 7000;
66 }
67 # knotmirror-tap
68 {
69 from = "host";
70 host.port = 7480;
71 guest.port = 7480;
72 }
73 # knotmirror-admin
74 {
75 from = "host";
76 host.port = 7200;
77 guest.port = 7200;
78 }
79 ];
80 sharedDirectories = {
81 # We can't use the 9p mounts directly for most of these
82 # as SQLite is incompatible with them. So instead we
83 # mount the shared directories to a different location
84 # and copy the contents around on service start/stop.
85 knotData = {
86 source = "$TANGLED_VM_DATA_DIR/knot";
87 target = "/mnt/knot-data";
88 };
89 spindleData = {
90 source = "$TANGLED_VM_DATA_DIR/spindle";
91 target = "/mnt/spindle-data";
92 };
93 spindleLogs = {
94 source = "$TANGLED_VM_DATA_DIR/spindle-logs";
95 target = "/var/log/spindle";
96 };
97 };
98 };
99 # This is fine because any and all ports that are forwarded to host are explicitly marked above, we don't need a separate guest firewall
100 networking.firewall.enable = false;
101 time.timeZone = "Europe/London";
102 services.getty.autologinUser = "root";
103 environment.systemPackages = with pkgs; [curl vim git sqlite litecli postgresql_14];
104 services.tangled.knot = {
105 enable = true;
106 motd = "Welcome to the development knot!\n";
107 server = {
108 owner = envVar "TANGLED_VM_KNOT_OWNER";
109 hostname = envVarOr "TANGLED_VM_KNOT_HOST" "localhost:6444";
110 plcUrl = plcUrl;
111 jetstreamEndpoint = jetstream;
112 listenAddr = "0.0.0.0:6444";
113 dev = true;
114 };
115 knotmirrors = [
116 "http://localhost:7000"
117 ];
118 };
119 services.tangled.spindle = {
120 enable = true;
121 server = {
122 owner = envVar "TANGLED_VM_SPINDLE_OWNER";
123 hostname = envVarOr "TANGLED_VM_SPINDLE_HOST" "localhost:6555";
124 plcUrl = plcUrl;
125 jetstreamEndpoint = jetstream;
126 listenAddr = "0.0.0.0:6555";
127 dev = true;
128 queueSize = 100;
129 maxJobCount = 2;
130 secrets = {
131 provider = "sqlite";
132 };
133 };
134
135 pipelines = {
136 logBucket = envVarOr "SPINDLE_S3_LOG_BUCKET" "";
137 };
138 };
139 services.postgresql = {
140 enable = true;
141 package = pkgs.postgresql_14;
142 ensureDatabases = ["mirror" "tap"];
143 ensureUsers = [
144 {name = "tnglr";}
145 ];
146 authentication = ''
147 local all tnglr trust
148 host all tnglr 127.0.0.1/32 trust
149 '';
150 };
151 services.tangled.knotmirror = {
152 enable = true;
153 listenAddr = "0.0.0.0:7000";
154 adminListenAddr = "0.0.0.0:7200";
155 hostname = "localhost:7000";
156 dbUrl = "postgresql://tnglr@127.0.0.1:5432/mirror";
157 fullNetwork = false;
158 tap.dbUrl = "postgresql://tnglr@127.0.0.1:5432/tap";
159 };
160 users = {
161 # So we don't have to deal with permission clashing between
162 # blank disk VMs and existing state
163 users.${config.services.tangled.knot.gitUser}.uid = 666;
164 groups.${config.services.tangled.knot.gitUser}.gid = 666;
165
166 # TODO: separate spindle user
167 };
168 systemd.services = let
169 mkDataSyncScripts = source: target: {
170 enableStrictShellChecks = true;
171
172 preStart = lib.mkBefore ''
173 mkdir -p ${target}
174 ${lib.getExe pkgs.rsync} -a ${source}/ ${target}
175 '';
176
177 postStop = lib.mkAfter ''
178 ${lib.getExe pkgs.rsync} -a ${target}/ ${source}
179 '';
180
181 serviceConfig.PermissionsStartOnly = true;
182 };
183 in {
184 knot = mkDataSyncScripts "/mnt/knot-data" config.services.tangled.knot.stateDir;
185 spindle = mkDataSyncScripts "/mnt/spindle-data" (builtins.dirOf config.services.tangled.spindle.server.dbPath);
186 knotmirror.after = ["postgresql.target"];
187 tap-knotmirror.after = ["postgresql.target"];
188 };
189 })
190 ];
191 }