flake.nix at master · tangled.org/core

tangled.org / core
Monorepo for Tangled tangled.org
core / flake.nix
at master 11 kB view raw
  1{
  2  description = "atproto github";
  3
  4  inputs = {
  5    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  6    gomod2nix = {
  7      url = "github:nix-community/gomod2nix";
  8      inputs.nixpkgs.follows = "nixpkgs";
  9    };
 10    flake-compat = {
 11      url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
 12      flake = false;
 13    };
 14    indigo = {
 15      url = "github:oppiliappan/indigo";
 16      flake = false;
 17    };
 18    htmx-src = {
 19      url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
 20      flake = false;
 21    };
 22    htmx-ws-src = {
 23      # strange errors in consle that i can't really make out
 24      # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
 25      url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
 26      flake = false;
 27    };
 28    lucide-src = {
 29      url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
 30      flake = false;
 31    };
 32    inter-fonts-src = {
 33      url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
 34      flake = false;
 35    };
 36    actor-typeahead-src = {
 37      url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
 38      flake = false;
 39    };
 40    ibm-plex-mono-src = {
 41      url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
 42      flake = false;
 43    };
 44    sqlite-lib-src = {
 45      url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
 46      flake = false;
 47    };
 48  };
 49
 50  outputs = {
 51    self,
 52    nixpkgs,
 53    gomod2nix,
 54    indigo,
 55    htmx-src,
 56    htmx-ws-src,
 57    lucide-src,
 58    inter-fonts-src,
 59    sqlite-lib-src,
 60    ibm-plex-mono-src,
 61    actor-typeahead-src,
 62    ...
 63  }: let
 64    supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
 65    forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
 66    nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
 67
 68    mkPackageSet = pkgs:
 69      pkgs.lib.makeScope pkgs.newScope (self: {
 70        src = let
 71          fs = pkgs.lib.fileset;
 72        in
 73          fs.toSource {
 74            root = ./.;
 75            fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
 76          };
 77        buildGoApplication =
 78          (self.callPackage "${gomod2nix}/builder" {
 79            gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
 80          }).buildGoApplication;
 81        modules = ./nix/gomod2nix.toml;
 82        sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
 83          inherit sqlite-lib-src;
 84        };
 85        lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
 86        goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
 87        appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
 88          inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src;
 89        };
 90        appview = self.callPackage ./nix/pkgs/appview.nix {};
 91        docs = self.callPackage ./nix/pkgs/docs.nix {
 92          inherit inter-fonts-src ibm-plex-mono-src lucide-src;
 93        };
 94        spindle = self.callPackage ./nix/pkgs/spindle.nix {};
 95        knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
 96        knot = self.callPackage ./nix/pkgs/knot.nix {};
 97      });
 98  in {
 99    overlays.default = final: prev: {
100      inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs;
101    };
102
103    packages = forAllSystems (system: let
104      pkgs = nixpkgsFor.${system};
105      packages = mkPackageSet pkgs;
106      staticPackages = mkPackageSet pkgs.pkgsStatic;
107      crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
108    in {
109      inherit (packages) appview appview-static-files lexgen goat spindle knot knot-unwrapped sqlite-lib docs;
110
111      pkgsStatic-appview = staticPackages.appview;
112      pkgsStatic-knot = staticPackages.knot;
113      pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
114      pkgsStatic-spindle = staticPackages.spindle;
115      pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
116
117      pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
118      pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
119      pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
120      pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
121
122      treefmt-wrapper = pkgs.treefmt.withConfig {
123        settings.formatter = {
124          alejandra = {
125            command = pkgs.lib.getExe pkgs.alejandra;
126            includes = ["*.nix"];
127          };
128
129          gofmt = {
130            command = pkgs.lib.getExe' pkgs.go "gofmt";
131            options = ["-w"];
132            includes = ["*.go"];
133          };
134
135          # prettier = let
136          #   wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
137          #     makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
138          #   '';
139          # in {
140          #   command = wrapper;
141          #   options = ["-w"];
142          #   includes = ["*.html"];
143          #   # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
144          #   excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
145          # };
146        };
147      };
148    });
149    defaultPackage = forAllSystems (system: self.packages.${system}.appview);
150    devShells = forAllSystems (system: let
151      pkgs = nixpkgsFor.${system};
152      packages' = self.packages.${system};
153      staticShell = pkgs.mkShell.override {
154        stdenv = pkgs.pkgsStatic.stdenv;
155      };
156    in {
157      default = staticShell {
158        nativeBuildInputs = [
159          pkgs.go
160          pkgs.air
161          pkgs.gopls
162          pkgs.httpie
163          pkgs.litecli
164          pkgs.websocat
165          pkgs.tailwindcss
166          pkgs.nixos-shell
167          pkgs.redis
168          pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
169          packages'.lexgen
170          packages'.treefmt-wrapper
171        ];
172        shellHook = ''
173          mkdir -p appview/pages/static
174          # no preserve is needed because watch-tailwind will want to be able to overwrite
175          cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
176          export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
177          export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
178        '';
179        env.CGO_ENABLED = 1;
180      };
181    });
182    apps = forAllSystems (system: let
183      pkgs = nixpkgsFor."${system}";
184      packages' = self.packages.${system};
185      air-watcher = name: arg:
186        pkgs.writeShellScriptBin "run"
187        ''
188          export PATH=${pkgs.go}/bin:$PATH
189          ${pkgs.air}/bin/air -c ./.air/${name}.toml \
190            -build.args_bin "${arg}"
191        '';
192      tailwind-watcher =
193        pkgs.writeShellScriptBin "run"
194        ''
195          ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
196        '';
197    in {
198      fmt = {
199        type = "app";
200        program = pkgs.lib.getExe packages'.treefmt-wrapper;
201      };
202      watch-appview = {
203        type = "app";
204        program = toString (pkgs.writeShellScript "watch-appview" ''
205          echo "copying static files to appview/pages/static..."
206          ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership ${packages'.appview-static-files}/* appview/pages/static
207          ${air-watcher "appview" ""}/bin/run
208        '');
209      };
210      watch-knot = {
211        type = "app";
212        program = ''${air-watcher "knot" "server"}/bin/run'';
213      };
214      watch-spindle = {
215        type = "app";
216        program = ''${air-watcher "spindle" ""}/bin/run'';
217      };
218      watch-tailwind = {
219        type = "app";
220        program = ''${tailwind-watcher}/bin/run'';
221      };
222      vm = let
223        guestSystem =
224          if pkgs.stdenv.hostPlatform.isAarch64
225          then "aarch64-linux"
226          else "x86_64-linux";
227      in {
228        type = "app";
229        program =
230          (pkgs.writeShellApplication {
231            name = "launch-vm";
232            text = ''
233              rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
234              cd "$rootDir"
235
236              mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
237
238              export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
239              exec ${pkgs.lib.getExe
240                (import ./nix/vm.nix {
241                  inherit nixpkgs self;
242                  system = guestSystem;
243                  hostSystem = system;
244                }).config.system.build.vm}
245            '';
246          })
247          + /bin/launch-vm;
248      };
249      gomod2nix = {
250        type = "app";
251        program = toString (pkgs.writeShellScript "gomod2nix" ''
252          ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
253        '');
254      };
255      lexgen = {
256        type = "app";
257        program =
258          (pkgs.writeShellApplication {
259            name = "lexgen";
260            text = ''
261              if ! command -v lexgen > /dev/null; then
262                echo "error: must be executed from devshell"
263                exit 1
264              fi
265
266              rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
267              cd "$rootDir"
268
269              rm -f api/tangled/*
270              lexgen --build-file lexicon-build-config.json lexicons
271              sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
272              ${pkgs.gotools}/bin/goimports -w api/tangled/*
273              go run ./cmd/cborgen/
274              lexgen --build-file lexicon-build-config.json lexicons
275              rm api/tangled/*.bak
276            '';
277          })
278          + /bin/lexgen;
279      };
280    });
281
282    nixosModules.appview = {
283      lib,
284      pkgs,
285      ...
286    }: {
287      imports = [./nix/modules/appview.nix];
288
289      services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
290    };
291    nixosModules.knot = {
292      lib,
293      pkgs,
294      ...
295    }: {
296      imports = [./nix/modules/knot.nix];
297
298      services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
299    };
300    nixosModules.spindle = {
301      lib,
302      pkgs,
303      ...
304    }: {
305      imports = [./nix/modules/spindle.nix];
306
307      services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
308    };
309  };
310}