Monorepo for Tangled
tangled.org
tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 htmx-ws-src = {
15 # strange errors in consle that i can't really make out
16 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
17 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
18 flake = false;
19 };
20 lucide-src = {
21 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
22 flake = false;
23 };
24 inter-fonts-src = {
25 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
26 flake = false;
27 };
28 ibm-plex-mono-src = {
29 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
30 flake = false;
31 };
32 sqlite-lib-src = {
33 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
34 flake = false;
35 };
36 gitignore = {
37 url = "github:hercules-ci/gitignore.nix";
38 inputs.nixpkgs.follows = "nixpkgs";
39 };
40 };
41
42 outputs = {
43 self,
44 nixpkgs,
45 indigo,
46 htmx-src,
47 htmx-ws-src,
48 lucide-src,
49 gitignore,
50 inter-fonts-src,
51 sqlite-lib-src,
52 ibm-plex-mono-src,
53 }: let
54 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
55 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
56 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
57
58 mkPackageSet = pkgs:
59 pkgs.lib.makeScope pkgs.newScope (self: {
60 goModHash = "sha256-SLi+nALwCd/Lzn3aljwPqCo2UaM9hl/4OAjcHQLt2Bk=";
61 inherit (gitignore.lib) gitignoreSource;
62 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
63 inherit (pkgs) gcc;
64 inherit sqlite-lib-src;
65 };
66 genjwks = self.callPackage ./nix/pkgs/genjwks.nix {};
67 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
68 appview = self.callPackage ./nix/pkgs/appview.nix {
69 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src;
70 };
71 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
72 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
73 knot = self.callPackage ./nix/pkgs/knot.nix {};
74 });
75 in {
76 overlays.default = final: prev: {
77 inherit (mkPackageSet final) lexgen sqlite-lib genjwks spindle knot-unwrapped knot appview;
78 };
79
80 packages = forAllSystems (system: let
81 pkgs = nixpkgsFor.${system};
82 packages = mkPackageSet pkgs;
83 staticPackages = mkPackageSet pkgs.pkgsStatic;
84 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
85 in {
86 appview = packages.appview;
87 lexgen = packages.lexgen;
88 knot = packages.knot;
89 knot-unwrapped = packages.knot-unwrapped;
90 spindle = packages.spindle;
91 genjwks = packages.genjwks;
92 sqlite-lib = packages.sqlite-lib;
93
94 pkgsStatic-appview = staticPackages.appview;
95 pkgsStatic-knot = staticPackages.knot;
96 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
97 pkgsStatic-spindle = staticPackages.spindle;
98 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
99
100 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
101 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
102 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
103 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
104 });
105 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
106 formatter = forAllSystems (system: nixpkgsFor.${system}.alejandra);
107 devShells = forAllSystems (system: let
108 pkgs = nixpkgsFor.${system};
109 packages' = self.packages.${system};
110 staticShell = pkgs.mkShell.override {
111 stdenv = pkgs.pkgsStatic.stdenv;
112 };
113 in {
114 default = staticShell {
115 nativeBuildInputs = [
116 pkgs.go
117 pkgs.air
118 pkgs.gopls
119 pkgs.httpie
120 pkgs.litecli
121 pkgs.websocat
122 pkgs.tailwindcss
123 pkgs.nixos-shell
124 pkgs.redis
125 packages'.lexgen
126 ];
127 shellHook = ''
128 mkdir -p appview/pages/static/{fonts,icons}
129 cp -f ${htmx-src} appview/pages/static/htmx.min.js
130 cp -f ${htmx-ws-src} appview/pages/static/htmx-ext-ws.min.js
131 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
132 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
133 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
134 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
135 export TANGLED_OAUTH_JWKS="$(${packages'.genjwks}/bin/genjwks)"
136 '';
137 env.CGO_ENABLED = 1;
138 };
139 });
140 apps = forAllSystems (system: let
141 pkgs = nixpkgsFor."${system}";
142 air-watcher = name: arg:
143 pkgs.writeShellScriptBin "run"
144 ''
145 ${pkgs.air}/bin/air -c /dev/null \
146 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
147 -build.bin "./out/${name}.out ${arg}" \
148 -build.stop_on_error "true" \
149 -build.include_ext "go"
150 '';
151 tailwind-watcher =
152 pkgs.writeShellScriptBin "run"
153 ''
154 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
155 '';
156 in {
157 watch-appview = {
158 type = "app";
159 program = ''${air-watcher "appview" ""}/bin/run'';
160 };
161 watch-knot = {
162 type = "app";
163 program = ''${air-watcher "knot" "server"}/bin/run'';
164 };
165 watch-tailwind = {
166 type = "app";
167 program = ''${tailwind-watcher}/bin/run'';
168 };
169 vm = {
170 type = "app";
171 program = toString (pkgs.writeShellScript "vm" ''
172 ${pkgs.nixos-shell}/bin/nixos-shell --flake .#vm
173 '');
174 };
175 });
176
177 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
178 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
179 nixosModules.spindle = import ./nix/modules/spindle.nix {inherit self;};
180 nixosConfigurations.vm = import ./nix/vm.nix {inherit self nixpkgs;};
181 };
182}