Monorepo for Tangled
tangled.org
tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 indigo = {
7 url = "github:oppiliappan/indigo";
8 flake = false;
9 };
10 htmx-src = {
11 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
12 flake = false;
13 };
14 lucide-src = {
15 url = "https://github.com/lucide-icons/lucide/releases/download/0.483.0/lucide-icons-0.483.0.zip";
16 flake = false;
17 };
18 inter-fonts-src = {
19 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
20 flake = false;
21 };
22 ibm-plex-mono-src = {
23 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
24 flake = false;
25 };
26 sqlite-lib-src = {
27 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
28 flake = false;
29 };
30 gitignore = {
31 url = "github:hercules-ci/gitignore.nix";
32 inputs.nixpkgs.follows = "nixpkgs";
33 };
34 };
35
36 outputs = {
37 self,
38 nixpkgs,
39 indigo,
40 htmx-src,
41 lucide-src,
42 gitignore,
43 inter-fonts-src,
44 sqlite-lib-src,
45 ibm-plex-mono-src,
46 }: let
47 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
48 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
49 nixpkgsFor = forAllSystems (system:
50 import nixpkgs {
51 inherit system;
52 overlays = [self.overlays.default];
53 });
54 inherit (gitignore.lib) gitignoreSource;
55 in {
56 overlays.default = final: prev: let
57 goModHash = "sha256-ZckpIPqFk7/XBiEJUbmrAzdjAxV62hv896xqAXF2aZs=";
58 appviewBuildAttrs = final:
59 with final; {
60 pname = "appview";
61 version = "0.1.0";
62 src = gitignoreSource ./.;
63 postUnpack = ''
64 pushd source
65 mkdir -p appview/pages/static/{fonts,icons}
66 cp -f ${htmx-src} appview/pages/static/htmx.min.js
67 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
68 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
69 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
70 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
71 ${pkgs.tailwindcss}/bin/tailwindcss -i input.css -o appview/pages/static/tw.css
72 popd
73 '';
74 doCheck = false;
75 subPackages = ["cmd/appview"];
76 vendorHash = goModHash;
77 env.CGO_ENABLED = 1;
78 stdenv = pkgsStatic.stdenv;
79 };
80 knotBuildAttrs = final:
81 with final; {
82 pname = "knot";
83 version = "0.1.0";
84 src = gitignoreSource ./.;
85 subPackages = ["cmd/knot"];
86 vendorHash = goModHash;
87 env.CGO_ENABLED = 1;
88 };
89 in {
90 lexgen = final.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
91 sqlite-lib = final.pkgsStatic.callPackage ./nix/pkgs/sqlite-lib.nix {
92 inherit (final.pkgsStatic) gcc;
93 inherit sqlite-lib-src;
94 };
95
96 # appview packages
97 appview = final.pkgsStatic.buildGoModule (appviewBuildAttrs final);
98 appview-cross = final.pkgsCross.gnu64.pkgsStatic.buildGoModule (appviewBuildAttrs final);
99
100 # knot packages
101 knot = with final;
102 final.pkgsStatic.buildGoModule ((knotBuildAttrs final)
103 // {
104 nativeBuildInputs = [final.makeWrapper];
105 installPhase = ''
106 runHook preInstall
107
108 mkdir -p $out/bin
109 cp $GOPATH/bin/knot $out/bin/knot
110
111 wrapProgram $out/bin/knot \
112 --prefix PATH : ${pkgs.git}/bin
113
114 runHook postInstall
115 '';
116 });
117 knot-cross = final.pkgsCross.gnu64.pkgsStatic.buildGoModule (knotBuildAttrs final); # cross-compile on darwin to x86_64-linux
118 knot-unwrapped = final.pkgsStatic.buildGoModule (knotBuildAttrs final);
119
120 genjwks = final.callPackage ./nix/pkgs/genjwks.nix {inherit goModHash gitignoreSource;};
121 };
122 packages = forAllSystems (system: {
123 inherit
124 (nixpkgsFor."${system}")
125 lexgen
126 appview
127 appview-cross
128 knot
129 knot-cross
130 knot-unwrapped
131 genjwks
132 ;
133 });
134 defaultPackage = forAllSystems (system: nixpkgsFor.${system}.appview);
135 formatter = forAllSystems (system: nixpkgsFor."${system}".alejandra);
136 devShells = forAllSystems (system: let
137 pkgs = nixpkgsFor.${system};
138 staticShell = pkgs.mkShell.override {
139 stdenv = pkgs.pkgsStatic.stdenv;
140 };
141 in {
142 default = staticShell {
143 nativeBuildInputs = [
144 pkgs.go
145 pkgs.air
146 pkgs.gopls
147 pkgs.httpie
148 pkgs.lexgen
149 pkgs.litecli
150 pkgs.websocat
151 pkgs.tailwindcss
152 pkgs.nixos-shell
153 pkgs.redis
154 ];
155 shellHook = ''
156 mkdir -p appview/pages/static/{fonts,icons}
157 cp -f ${htmx-src} appview/pages/static/htmx.min.js
158 cp -rf ${lucide-src}/*.svg appview/pages/static/icons/
159 cp -f ${inter-fonts-src}/web/InterVariable*.woff2 appview/pages/static/fonts/
160 cp -f ${inter-fonts-src}/web/InterDisplay*.woff2 appview/pages/static/fonts/
161 cp -f ${ibm-plex-mono-src}/fonts/complete/woff2/IBMPlexMono-Regular.woff2 appview/pages/static/fonts/
162 export TANGLED_OAUTH_JWKS="$(${pkgs.genjwks}/bin/genjwks)"
163 '';
164 env.CGO_ENABLED = 1;
165 };
166 });
167 apps = forAllSystems (system: let
168 pkgs = nixpkgsFor."${system}";
169 air-watcher = name: arg:
170 pkgs.writeShellScriptBin "run"
171 ''
172 ${pkgs.air}/bin/air -c /dev/null \
173 -build.cmd "${pkgs.go}/bin/go build -o ./out/${name}.out ./cmd/${name}/main.go" \
174 -build.bin "./out/${name}.out ${arg}" \
175 -build.stop_on_error "true" \
176 -build.include_ext "go"
177 '';
178 tailwind-watcher =
179 pkgs.writeShellScriptBin "run"
180 ''
181 ${pkgs.tailwindcss}/bin/tailwindcss -w -i input.css -o ./appview/pages/static/tw.css
182 '';
183 in {
184 watch-appview = {
185 type = "app";
186 program = ''${air-watcher "appview" ""}/bin/run'';
187 };
188 watch-knot = {
189 type = "app";
190 program = ''${air-watcher "knot" "server"}/bin/run'';
191 };
192 watch-tailwind = {
193 type = "app";
194 program = ''${tailwind-watcher}/bin/run'';
195 };
196 });
197
198 nixosModules.appview = import ./nix/modules/appview.nix {inherit self;};
199 nixosModules.knot = import ./nix/modules/knot.nix {inherit self;};
200 nixosConfigurations.knotVM = import ./nix/vm.nix {inherit self nixpkgs;};
201 };
202}