Live video on the AT Protocol
stream.place
1project(
2 'streamplace',
3 'c',
4 'cpp',
5 default_options: {
6 'cpp_std': 'c++11',
7 'default_library': 'static',
8 'auto_features': 'disabled',
9 'force_fallback_for': 'gio-2.0,gstreamer-controller-1.0,gstreamer-app-1.0,gstreamer-pbutils-1.0,glib-2.0,gobject-2.0,gio-2.0,gio-unix-2.0,fdk-aac,zlib,libffi,pcre2,intl,x264,freetype2,libpng,libjpeg,fontconfig,pango,opus,fribidi,harfbuzz,nettle,cairo,pixman,expat,openssl',
10 'buildtype': 'debugoptimized',
11 'prefix': '/usr/local', # otherwise mac meson will try and do /opt/homebrew sometimes
12 },
13)
14
15fs = import('fs')
16
17prog_go = find_program('go')
18
19flagbuilder = custom_target(
20 'flagbuilder',
21 input: ['pkg/config/git/git.go'],
22 output: ['flagbuilder'],
23 command: [prog_go, 'build', '-o', '@OUTPUT0@', '@INPUT@'],
24 build_always_stale: true,
25 env: {
26 'CGO_ENABLED': '0',
27 },
28)
29
30flags = custom_target(
31 'flags',
32 input: [],
33 output: ['build-flags.go'],
34 command: [flagbuilder, '-o', '@OUTPUT0@'],
35 build_always_stale: true,
36)
37
38version_cmd = run_command(prog_go, 'run', 'pkg/config/git/git.go', '-v', check: true, env: {
39 'CGO_ENABLED': '0',
40})
41version = version_cmd.stdout().strip()
42
43streamplace_go = custom_target(
44 'streamplace.go',
45 input: 'cmd/libstreamplace/streamplace.go',
46 output: 'streamplace.go',
47 command: ['cp', '@INPUT@', '@OUTPUT@'],
48)
49
50# todo: teach meson to automatically populate this CPATH thing for go
51env = {
52 'PKG_CONFIG_PATH': meson.current_build_dir() + '/meson-uninstalled',
53}
54
55GOOS = meson.get_external_property('GOOS', host_machine.system())
56GOARCH = meson.get_external_property('GOARCH', host_machine.cpu())
57if GOARCH == 'x86_64'
58 GOARCH = 'amd64'
59endif
60if GOARCH == 'aarch64'
61 GOARCH = 'arm64'
62endif
63if meson.is_cross_build()
64 env += {
65 'GOOS': GOOS,
66 'GOARCH': GOARCH,
67 'CGO_ENABLED': '1',
68 'CC': meson.get_compiler('c', native: false).cmd_array()[0],
69 }
70endif
71
72c2pa_go_opts = {}
73triple = meson.get_external_property('RUST_TRIPLE', '')
74if triple != ''
75 c2pa_go_opts += {'RUST_TRIPLE': triple}
76endif
77c2pa_go_proj = subproject(
78 'c2pa_go',
79 default_options: c2pa_go_opts,
80)
81c2pa_go_dep = c2pa_go_proj.get_variable('c2pa_go_dep')
82
83streamplace_deps = []
84# if host_machine.system() == 'linux'
85# mistserver_proj = subproject(
86# 'mistserver',
87# default_options: {
88# 'APPNAME': 'MistServer',glib
89# },
90# )
91# mistserver = mistserver_proj.get_variable('libmistserver_dep')
92# streamplace_deps += mistserver
93# endif
94
95x264_proj = subproject(
96 'x264',
97 default_options: {},
98)
99
100ffmpeg_opts = {
101 'aac_adtstoasc_bsf': 'enabled',
102 'aac_decoder': 'enabled',
103 'aac_latm_parser': 'enabled',
104 'aac_parser': 'enabled',
105 'aformat_filter': 'enabled',
106 'aresample_filter': 'enabled',
107 'asetnsamples_filter': 'enabled',
108 'auto_features': 'enabled',
109 'concat_demuxer': 'enabled',
110 'concat_filter': 'enabled',
111 'concat_protocol': 'enabled',
112 'concatf_protocol': 'enabled',
113 'extract_extradata_bsf': 'enabled',
114 'fd_protocol': 'enabled',
115 'fifo_muxer': 'enabled',
116 'file_protocol': 'enabled',
117 'flac_decoder': 'enabled',
118 'flac_demuxer': 'enabled',
119 'flac_muxer': 'enabled',
120 'flac_parser': 'enabled',
121 'flv_demuxer': 'enabled',
122 'format_filter': 'enabled',
123 'fps_filter': 'enabled',
124 'gpl': 'enabled',
125 'h264_cuvid_decoder': 'enabled',
126 'h264_decoder': 'enabled',
127 'h264_metadata_bsf': 'enabled',
128 'h264_mp4toannexb_bsf': 'enabled',
129 'h264_parser': 'enabled',
130 'h264_redundant_pps_bsf': 'enabled',
131 'hevc_cuvid_decoder': 'enabled',
132 'hevc_mp4toannexb_bsf': 'enabled',
133 'hevc_muxer': 'enabled',
134 'hevc_parser': 'enabled',
135 'hls_muxer': 'enabled',
136 'http_protocol': 'enabled',
137 'hwdownload_filter': 'enabled',
138 'image2_demuxer': 'enabled',
139 'libxcb': 'enabled',
140 'matroska_audio_muxer': 'enabled',
141 'matroska_demuxer': 'enabled',
142 'matroska_muxer': 'enabled',
143 'mov_demuxer': 'enabled',
144 'mp3_decoder': 'enabled',
145 'mp3_demuxer': 'enabled',
146 'mp3_muxer': 'enabled',
147 'mp4_muxer': 'enabled',
148 'mpegaudio_parser': 'enabled',
149 'mpegts_demuxer': 'enabled',
150 'mpegts_muxer': 'enabled',
151 'network': 'enabled',
152 'null_muxer': 'enabled',
153 'opus_decoder': 'enabled',
154 'opus_parser': 'enabled',
155 'pipe_protocol': 'enabled',
156 'png_decoder': 'enabled',
157 'png_parser': 'enabled',
158 'rtmp_protocol': 'enabled',
159 'scale_filter': 'enabled',
160 'segment_muxer': 'enabled',
161 'stream_segment_muxer': 'enabled',
162 'select_filter': 'enabled',
163 'signature_filter': 'enabled',
164 'tcp_protocol': 'enabled',
165 'vorbis_decoder': 'enabled',
166 'vorbis_parser': 'enabled',
167 'vp8_cuvid_decoder': 'enabled',
168 'vp8_parser': 'enabled',
169 'vp9_cuvid_decoder': 'enabled',
170 'vp9_parser': 'enabled',
171 'wav_demuxer': 'enabled',
172 'wav_muxer': 'enabled',
173 'webm_muxer': 'enabled',
174 'x86asm': 'enabled',
175 'mov_muxer': 'enabled',
176 'vp9_superframe_bsf': 'enabled',
177 'ac3_parser': 'enabled',
178 'pgs_frame_merge_bsf': 'enabled',
179 'libx264': 'enabled',
180 'libx264_encoder': 'enabled',
181 'libx264rgb_encoder': 'enabled',
182 'mpegtsraw_demuxer': 'enabled',
183 'adts_muxer': 'enabled',
184 'latm_muxer': 'enabled',
185 'vvc_mp4toannexb_bsf': 'enabled',
186}
187
188if host_machine.system() != 'windows'
189 ffmpeg_opts += {'nanosleep': 'enabled'}
190endif
191
192# Someday maybe once the meson port of ffmpeg supports cuda
193
194# if host_machine.system() != 'darwin'
195# ffmpeg_opts += {
196# 'ff_cuda_llvm': 'enabled',
197# 'cuda': 'enabled',
198# 'hwupload_cuda_filter': 'enabled',
199# 'scale_cuda_filter': 'enabled',
200# # 'signature_cuda_filter': 'enabled',
201# 'ffnvcodec': 'enabled',
202# 'h264_nvenc_encoder': 'enabled',
203# 'nvenc': 'enabled',
204# 'nvdec': 'enabled',
205# 'h264_nvdec_hwaccel': 'enabled',
206# 'libdl': 'enabled',
207# }
208# endif
209
210ffmpeg_proj = subproject(
211 'FFmpeg',
212 # vvc seems to have problems building as a submodule?
213 default_options: ffmpeg_opts,
214)
215avformat = ffmpeg_proj.get_variable('libavformat_dep')
216avfilter = ffmpeg_proj.get_variable('libavfilter_dep')
217streamplace_deps += [avformat, avfilter]
218
219gstreamer_proj = subproject(
220 'gstreamer-full',
221 default_options: {},
222)
223
224streamplace_deps += [
225 dependency('gio-2.0'),
226 dependency('gstreamer-controller-1.0'),
227 dependency('gstreamer-app-1.0'),
228 dependency('gstreamer-pbutils-1.0'),
229]
230
231atproto = subproject(
232 'atproto',
233 default_options: {},
234)
235
236if get_option('default_library') == 'static'
237 gst_full_dep = gstreamer_proj.get_variable('gst_full_dep')
238 streamplace_deps += [
239 gst_full_dep,
240 dependency('gstplayback'),
241 ]
242endif
243
244libstreamplace = custom_target(
245 'libstreamplace',
246 input: [streamplace_go, flags],
247 output: ['streamplace.a', 'streamplace.h'],
248 command: [
249 prog_go,
250 'build',
251 '-o', '@OUTPUT0@',
252 '-buildmode', 'c-archive',
253 '-tags', 'netgo',
254 '@INPUT@',
255 ],
256 build_always_stale: true,
257 env: env,
258)
259
260if host_machine.system() == 'darwin'
261 streamplace_deps += [dependency('appleframeworks', modules: ['CoreFoundation', 'Security'])]
262endif
263if host_machine.system() == 'windows'
264 add_project_link_arguments(
265 [
266 '-lntdll',
267 '-luserenv',
268 '-lcrypt32',
269 '-lbcrypt',
270 '-static-libstdc++',
271 '-static-libgcc',
272 ],
273 language: ['c', 'cpp'],
274 )
275endif
276
277pkg = import('pkgconfig')
278pkg.generate(
279 name: 'streamplacedeps',
280 libraries: [streamplace_deps, c2pa_go_dep],
281 description: 'all streamplace dependencies bundled for easy inclusion',
282)
283
284if build_machine.system() == 'linux' and host_machine.system() == 'darwin'
285 # this only exists to convince meson to build all of the streamplace dependencies
286 # the real binary comes from the `go build` command below
287 cstreamplace = executable(
288 'cstreamplace',
289 ['cmd/streamplace/streamplace.c', libstreamplace],
290 dependencies: [
291 streamplace_deps,
292 ],
293 link_with: [c2pa_go_dep],
294 )
295
296 streamplace = custom_target(
297 'streamplace',
298 input: [cstreamplace, flags],
299 output: ['streamplace'],
300 command: [
301 prog_go,
302 'build',
303 '-o', '@OUTPUT0@',
304 '-tags', 'netgo',
305 'streamplace.go',
306 '@INPUT1@'
307 ],
308 build_always_stale: true,
309 env: env,
310 )
311else
312 streamplace = executable(
313 'streamplace',
314 ['cmd/streamplace/streamplace.c', libstreamplace],
315 dependencies: [
316 streamplace_deps,
317 ],
318 link_with: [c2pa_go_dep],
319 )
320endif
321
322
323if not meson.is_cross_build()
324 test(
325 'go-tests',
326 prog_go,
327 depends: [streamplace],
328 env: env,
329 verbose: true,
330 timeout: 0,
331 args: [
332 'test',
333 '-p', '1',
334 '-timeout', '600s',
335 '@0@/pkg/...'.format(meson.current_source_dir()),
336 '@0@/cmd/...'.format(meson.current_source_dir()),
337 ],
338 )
339endif
340
341if host_machine.system() == 'windows'
342 prog_zip = find_program('zip')
343 archive_name = 'streamplace-' + version + '-' + GOOS + '-' + GOARCH + '.zip'
344 custom_target(
345 'archive',
346 input: [streamplace],
347 output: ['streamplace.zip'],
348 command: [prog_zip, '../bin/' + archive_name, '@INPUT@'],
349 install: true,
350 install_dir: './bin',
351 build_by_default: false,
352 )
353else
354 prog_tar = find_program('tar')
355 # archive_name = streamplace-$(VERSION)-$$GOOS-$$GOARCH.tar.gz
356 archive_name = 'streamplace-' + version + '-' + GOOS + '-' + GOARCH + '.tar.gz'
357 custom_target(
358 'archive',
359 input: [streamplace],
360 output: ['streamplace.tar.gz'],
361 command: [prog_tar, '-czvf', '../bin/' + archive_name, '@INPUT@'],
362 install: true,
363 install_dir: './bin',
364 build_by_default: false,
365 )
366endif