{
	description = "The Starlight OS";

	inputs = {
		security.url = "git+https://git.vulpecula.zone/tasiaiso/nixos-security";
		nixpkgs.follows = "security/nixpkgs";

		disko = {
			url = "github:nix-community/disko";
			inputs.nixpkgs.follows = "nixpkgs";
		};
		nixos-cli = {
			url = "github:nix-community/nixos-cli";
			inputs.nixpkgs.follows = "nixpkgs";
			inputs.flake-compat.follows = "flake-compat";
			# inputs.flake-parts.follows = "flake-parts";
			inputs.optnix.follows = "optnix";
		};
		optnix = {
			url = "github:water-sucks/optnix";
			inputs.nixpkgs.follows = "nixpkgs";
			inputs.flake-compat.follows = "flake-compat";
		};
		flake-compat = {
			url = "github:edolstra/flake-compat";
		};
	};

	outputs = {
		self,
		nixpkgs,
		...
	} @ inputs: let
		inherit (self) outputs;

		defaultSpecialArgs = {
			inherit self inputs outputs;
		};
		pkgs = nixpkgs.legacyPackages.x86_64-linux;
	in {
		packages.x86_64-linux = import ./pkgs {inherit pkgs inputs;};
		# packages.aarch64-linux = import ./pkgs nixpkgs.legacyPackages.aarch64-linux // defaultSpecialArgs;

		formatter.x86_64-linux = nixpkgs.legacyPackages.x86_64-linux.alejandra;
		formatter.aarch64-linux = nixpkgs.legacyPackages.aarch64-linux.alejandra;

		nixosConfigurations = {
			slos =
				nixpkgs.lib.nixosSystem {
					system = "x86_64-linux";
					specialArgs = defaultSpecialArgs;
					modules = [
						./slos/configuration.nix
					];
				};
			installer =
				nixpkgs.lib.nixosSystem {
					system = "x86_64-linux";
					specialArgs = defaultSpecialArgs;
					modules = [
						./installer/configuration.nix
					];
				};
		};

		hydraJobs = {
			packages = self.packages.x86_64-linux;
			hosts = {
				# slos = self.nixosConfigurations.slos.config.system.build.toplevel;
				installer = self.nixosConfigurations.installer.config.system.build.toplevel;
			};
		};
	};
}