pyrox.dev
1{stdenv, fetchurl, perl, CryptSSLeay, LWP, unzip, xz, dpkg, TimeDate, DBFile
2, FileDesktopEntry, libxslt, docbook_xsl, python3, setuptools, makeWrapper
3, perlPackages, curl, gnupg, diffutils
4, sendmailPath ? "/var/setuid-wrappers/sendmail"
5}:
6
7stdenv.mkDerivation rec {
8 version = "2.15.8";
9 name = "debian-devscripts-${version}";
10
11 src = fetchurl {
12 url = "mirror://debian/pool/main/d/devscripts/devscripts_${version}.tar.xz";
13 sha256 = "1zw7phaigncblxb3jp4m8pk165hylk1f088k51nhj9d7z5iz6bbx";
14 };
15
16 buildInputs = [ perl CryptSSLeay LWP unzip xz dpkg TimeDate DBFile
17 FileDesktopEntry libxslt python3 setuptools makeWrapper
18 perlPackages.ParseDebControl perlPackages.LWPProtocolHttps
19 curl gnupg diffutils ];
20
21 preConfigure = ''
22 export PERL5LIB="$PERL5LIB''${PERL5LIB:+:}${dpkg}";
23 tgtpy="$out/lib/${python3.libPrefix}/site-packages"
24 mkdir -p "$tgtpy"
25 export PYTHONPATH="$PYTHONPATH''${PYTHONPATH:+:}$tgtpy"
26 find po4a scripts -type f -exec sed -r \
27 -e "s@/usr/bin/gpg(2|)@${gnupg}/bin/gpg2@g" \
28 -e "s@/usr/(s|)bin/sendmail@${sendmailPath}@g" \
29 -e "s@/usr/bin/diff@${diffutils}/bin/diff@g" \
30 -e "s@/usr/bin/gpgv(2|)@${gnupg}/bin/gpgv2@g" \
31 -e "s@(command -v|/usr/bin/)curl@${curl}/bin/curl@g" \
32 -i {} +
33 sed -e "s@/usr/share/sgml/[^ ]*/manpages/docbook.xsl@${docbook_xsl}/xml/xsl/docbook/manpages/docbook.xsl@" -i scripts/Makefile
34 sed -r \
35 -e "s@/usr( |$|/)@$out\\1@g" \
36 -e "s@/etc( |$|/)@$out/etc\\1@g" \
37 -e 's/ translated_manpages//; s/--install-layout=deb//; s@--root="[^ ]*"@--prefix="'"$out"'"@' \
38 -i Makefile* */Makefile*
39 '';
40
41 makeFlags = [
42 "DESTDIR=$(out)"
43 "PREFIX="
44 "COMPL_DIR=/share/bash-completion/completions"
45 "PERLMOD_DIR=/share/devscripts"
46 ];
47
48 postInstall = ''
49 sed -re 's@(^|[ !`"])/bin/bash@\1${stdenv.shell}@g' -i "$out/bin"/*
50 for i in "$out/bin"/*; do
51 wrapProgram "$i" \
52 --prefix PERL5LIB : "$PERL5LIB" \
53 --prefix PERL5LIB : "$out/share/devscripts" \
54 --prefix PYTHONPATH : "$out/lib/python3.4/site-packages"
55 done
56 '';
57
58 meta = with stdenv.lib; {
59 description = ''Debian package maintenance scripts'';
60 license = licenses.free; # Mix of public domain, Artistic+GPL, GPL1+, GPL2+, GPL3+, and GPL2-only... TODO
61 maintainers = with maintainers; [raskin];
62 };
63}