pyrox.dev
1{ stdenv, fetchurl, python, cython, pkgconfig, wrapPython
2, pygame, SDL, libpng, ffmpeg, freetype, glew, mesa, fribidi, zlib
3}:
4
5stdenv.mkDerivation {
6 name = "renpy-6.17.6";
7
8 meta = {
9 description = "Ren'Py Visual Novel Engine";
10 homepage = "http://renpy.org/";
11 license = stdenv.lib.licenses.mit;
12 platforms = stdenv.lib.platforms.linux;
13 maintainers = with stdenv.lib.maintainers; [ iyzsong ];
14 };
15
16 src = fetchurl {
17 url = "http://www.renpy.org/dl/6.17.6/renpy-6.17.6-source.tar.bz2";
18 sha256 = "0rkynw9cnr1zqdinz037d9zig6grhp2ca2pyxk80vhdpjb0xrkic";
19 };
20
21 buildInputs = [
22 python cython pkgconfig wrapPython
23 SDL libpng ffmpeg freetype glew mesa fribidi zlib pygame
24 ];
25
26 pythonPath = [ pygame ];
27
28 RENPY_DEPS_INSTALL = stdenv.lib.concatStringsSep "::" (map (path: "${path}") [
29 SDL libpng ffmpeg freetype glew mesa fribidi zlib
30 ]);
31
32 buildPhase = ''
33 python module/setup.py build
34 '';
35
36 installPhase = ''
37 mkdir -p $out/share/renpy
38 cp -r renpy renpy.py $out/share/renpy
39 python module/setup.py install --prefix=$out --install-lib=$out/share/renpy/module
40
41 wrapPythonPrograms
42 makeWrapper ${python}/bin/python $out/bin/renpy \
43 --set PYTHONPATH $program_PYTHONPATH \
44 --set RENPY_BASE $out/share/renpy \
45 --add-flags "-O $out/share/renpy/renpy.py"
46 '';
47
48 NIX_CFLAGS_COMPILE = "-I${pygame}/include/${python.libPrefix}";
49}