pyrox.dev
1{ stdenv, lib, fetchurl, fetchFromSavannah, fetchFromGitHub
2, zlib, zlibSupport ? true
3, openssl, opensslSupport ? true
4, gdbm, gdbmSupport ? true
5, ncurses, readline, cursesSupport ? true
6, groff, docSupport ? false
7, libyaml, yamlSupport ? true
8, libffi, fiddleSupport ? true
9, ruby_2_1_1, autoreconfHook, bison, useRailsExpress ? true
10}:
11
12let
13 op = stdenv.lib.optional;
14 ops = stdenv.lib.optionals;
15 patchSet = import ./rvm-patchsets.nix { inherit fetchFromGitHub; };
16 config = import ./config.nix { inherit fetchFromSavannah; };
17 baseruby = ruby_2_1_1.override { useRailsExpress = false; };
18in
19
20stdenv.mkDerivation rec {
21 version = with passthru; "${majorVersion}.${minorVersion}.${teenyVersion}-p${patchLevel}";
22
23 name = "ruby-${version}";
24
25 src = if useRailsExpress then fetchFromGitHub {
26 owner = "ruby";
27 repo = "ruby";
28 rev = "v2_1_1";
29 sha256 = "1v2ffvyd0xx1h1qd70431zczhvsdiyyw5kjxih4rszd5avzh5grl";
30 } else fetchurl {
31 url = "http://cache.ruby-lang.org/pub/ruby/2.1/ruby-2.1.1.tar.gz";
32 sha256 = "0hc9x3mazyvnk94gs19q8mbnanlzk8mv0hii77slkvc8mqqxyhy8";
33 };
34
35 # Have `configure' avoid `/usr/bin/nroff' in non-chroot builds.
36 NROFF = "${groff}/bin/nroff";
37
38 buildInputs = ops useRailsExpress [ autoreconfHook bison ]
39 ++ (op fiddleSupport libffi)
40 ++ (ops cursesSupport [ ncurses readline ] )
41 ++ (op docSupport groff )
42 ++ (op zlibSupport zlib)
43 ++ (op opensslSupport openssl)
44 ++ (op gdbmSupport gdbm)
45 ++ (op yamlSupport libyaml)
46 # Looks like ruby fails to build on darwin without readline even if curses
47 # support is not enabled, so add readline to the build inputs if curses
48 # support is disabled (if it's enabled, we already have it) and we're
49 # running on darwin
50 ++ (op (!cursesSupport && stdenv.isDarwin) readline);
51
52 enableParallelBuilding = true;
53
54 patches = ops useRailsExpress [
55 "${patchSet}/patches/ruby/2.1.0/railsexpress/01-zero-broken-tests.patch"
56 "${patchSet}/patches/ruby/2.1.0/railsexpress/02-improve-gc-stats.patch"
57 "${patchSet}/patches/ruby/2.1.0/railsexpress/03-display-more-detailed-stack-trace.patch"
58 "${patchSet}/patches/ruby/2.1.0/railsexpress/04-show-full-backtrace-on-stack-overflow.patch"
59 "${patchSet}/patches/ruby/2.1.0/railsexpress/05-fix-missing-c-return-event.patch"
60 "${patchSet}/patches/ruby/2.1.0/railsexpress/07-backport-006e66b6680f60adfb434ee7397f0dbc77de7873.patch"
61 "${patchSet}/patches/ruby/2.1.0/railsexpress/08-funny-falcon-stc-density.patch"
62 "${patchSet}/patches/ruby/2.1.0/railsexpress/09-funny-falcon-stc-pool-allocation.patch"
63 "${patchSet}/patches/ruby/2.1.0/railsexpress/10-aman-opt-aset-aref-str.patch"
64 "${patchSet}/patches/ruby/2.1.0/railsexpress/11-funny-falcon-method-cache.patch"
65 "${patchSet}/patches/ruby/2.1.0/railsexpress/12-backport-r44370.patch"
66 ];
67
68 # Ruby >= 2.1.0 tries to download config.{guess,sub}
69 postPatch = ''
70 rm tool/config_files.rb
71 cp ${config}/config.guess tool/
72 cp ${config}/config.sub tool/
73 '';
74
75 configureFlags = ["--enable-shared" ]
76 ++ op useRailsExpress "--with-baseruby=${baseruby}/bin/ruby"
77 # on darwin, we have /usr/include/tk.h -- so the configure script detects
78 # that tk is installed
79 ++ ( if stdenv.isDarwin then [ "--with-out-ext=tk " ] else [ ]);
80
81 installFlags = stdenv.lib.optionalString docSupport "install-doc";
82 # Bundler tries to create this directory
83 postInstall = ''
84 # Bundler tries to create this directory
85 mkdir -pv $out/${passthru.gemPath}
86 mkdir -p $out/nix-support
87 cat > $out/nix-support/setup-hook <<EOF
88 addGemPath() {
89 addToSearchPath GEM_PATH \$1/${passthru.gemPath}
90 }
91
92 envHooks+=(addGemPath)
93 EOF
94 '' + lib.optionalString useRailsExpress ''
95 rbConfig=$(find $out/lib/ruby -name rbconfig.rb)
96
97 # Prevent the baseruby from being included in the closure.
98 sed -i '/^ CONFIG\["BASERUBY"\]/d' $rbConfig
99 sed -i "s|'--with-baseruby=${baseruby}/bin/ruby'||" $rbConfig
100 '';
101
102 meta = {
103 license = stdenv.lib.licenses.ruby;
104 homepage = "http://www.ruby-lang.org/en/";
105 description = "The Ruby language";
106 platforms = stdenv.lib.platforms.all;
107 };
108
109 passthru = rec {
110 majorVersion = "2";
111 minorVersion = "1";
112 teenyVersion = "1";
113 patchLevel = "0";
114 rubyEngine = "ruby";
115 libPath = "lib/${rubyEngine}/${majorVersion}.${minorVersion}.${teenyVersion}";
116 gemPath = "lib/${rubyEngine}/gems/${majorVersion}.${minorVersion}.${teenyVersion}";
117 };
118}