pyrox.dev
1{ stdenv, bzip2, patchelf, glibc, gcc, fetchurl, version, releaseType, sha256, ncurses }:
2with stdenv.lib;
3let
4 versionParts = splitString "-" version; # 4.7 2013q3 20130916
5 majorVersion = elemAt versionParts 0; # 4.7
6 yearQuarter = elemAt versionParts 1; # 2013q3
7 underscoreVersion = replaceChars ["."] ["_"] version; # 4_7-2013q3-20130916
8 yearQuarterParts = splitString "q" yearQuarter; # 2013 3
9 year = elemAt yearQuarterParts 0; # 2013
10 quarter = elemAt yearQuarterParts 1; # 3
11 subdirName = "${majorVersion}-${year}-q${quarter}-${releaseType}"; # 4.7-2013-q3-update
12in
13stdenv.mkDerivation {
14 name = "gcc-arm-embedded-${version}";
15
16 src = fetchurl {
17 url = "https://launchpad.net/gcc-arm-embedded/${majorVersion}/${subdirName}/+download/gcc-arm-none-eabi-${underscoreVersion}-linux.tar.bz2";
18 sha256 = sha256;
19 };
20
21 buildInputs = [ bzip2 patchelf ];
22
23 dontPatchELF = true;
24
25 phases = "unpackPhase patchPhase installPhase";
26
27 installPhase = ''
28 mkdir -pv $out
29 cp -r ./* $out
30
31 for f in $(find $out); do
32 if [ -f "$f" ] && patchelf "$f" 2> /dev/null; then
33 patchelf --set-interpreter ${glibc}/lib/ld-linux.so.2 \
34 --set-rpath $out/lib:${gcc}/lib:${ncurses}/lib \
35 "$f" || true
36 fi
37 done
38 '';
39
40 meta = with stdenv.lib; {
41 description = "Pre-built GNU toolchain from ARM Cortex-M & Cortex-R processors (Cortex-M0/M0+/M3/M4, Cortex-R4/R5/R7)";
42 homepage = "https://launchpad.net/gcc-arm-embedded";
43 license = licenses.gpl3;
44 platforms = platforms.linux;
45 };
46}