pyrox.dev
1{
2 lib,
3 stdenv,
4 fetchurl,
5 kernel,
6}:
7
8let
9 srcs = import (./srcs.nix) { inherit fetchurl; };
10in
11stdenv.mkDerivation rec {
12 pname = "mxu11x0";
13
14 src = if lib.versionAtLeast kernel.version "5.0" then srcs.mxu11x0_5.src else srcs.mxu11x0_4.src;
15 mxu_version =
16 if lib.versionAtLeast kernel.version "5.0" then srcs.mxu11x0_5.version else srcs.mxu11x0_4.version;
17
18 version = mxu_version + "-${kernel.version}";
19
20 nativeBuildInputs = kernel.moduleBuildDependencies;
21
22 preBuild = ''
23 sed -i -e 's|/lib/modules|${kernel.dev}/lib/modules|' driver/mxconf
24 sed -i -e 's|/lib/modules|${kernel.dev}/lib/modules|' driver/Makefile
25 '';
26
27 installPhase = ''
28 install -v -D -m 644 ./driver/mxu11x0.ko "$out/lib/modules/${kernel.modDirVersion}/kernel/drivers/usb/serial/mxu11x0.ko"
29 install -v -D -m 644 ./driver/mxu11x0.ko "$out/lib/modules/${kernel.modDirVersion}/misc/mxu11x0.ko"
30 '';
31
32 dontStrip = true;
33
34 enableParallelBuilding = true;
35
36 hardeningDisable = [ "pic" ];
37
38 meta = with lib; {
39 description = "MOXA UPort 11x0 USB to Serial Hub driver";
40 homepage = "https://www.moxa.com/en/products/industrial-edge-connectivity/usb-to-serial-converters-usb-hubs/usb-to-serial-converters/uport-1000-series";
41 license = licenses.gpl2Plus;
42 maintainers = with maintainers; [ uralbash ];
43 platforms = platforms.linux;
44 # broken due to API change in write_room() > v5.14-rc1
45 # https://github.com/torvalds/linux/commit/94cc7aeaf6c0cff0b8aeb7cb3579cee46b923560
46 broken = kernel.kernelAtLeast "5.14";
47 };
48}