pyrox.dev
lol
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 autoreconfHook,
6 libevent,
7 krb5,
8 openssl,
9 perl,
10 pkg-config,
11}:
12stdenv.mkDerivation (finalAttrs: {
13 pname = "remctl";
14 version = "3.18";
15
16 src = fetchFromGitHub {
17 owner = "rra";
18 repo = "remctl";
19 rev = "release/${finalAttrs.version}";
20 hash = "sha256-4KzNhFswNTwcXrDBAfRyr502zwRQ3FACV8gDfBm7M0A=";
21 };
22
23 # Fix references to /usr/bin/perl in tests and
24 # disable acl/localgroup test that does not work in sandbox.
25 postPatch = ''
26 patchShebangs tests
27 sed -i '\,server/acl/localgroup,d' tests/TESTS
28 substituteInPlace configure.ac --replace "-Werror" ""
29 '';
30
31 nativeBuildInputs = [
32 autoreconfHook
33 perl
34 pkg-config
35 ];
36
37 buildInputs = [
38 krb5
39 libevent
40 openssl
41 ];
42
43 # Invokes pod2man to create man pages required by Makefile.
44 preConfigure = ''
45 ./bootstrap
46 '';
47
48 makeFlags = [
49 "LD=$(CC)"
50 "REMCTL_PERL_FLAGS='--prefix=$(out)'"
51 "REMCTL_PYTHON_INSTALL='--prefix=$(out)'"
52 ];
53
54 checkTarget = "check-local";
55
56 meta = with lib; {
57 description = "Remote execution tool";
58 homepage = "https://www.eyrie.org/~eagle/software/remctl";
59 mainProgram = "remctl";
60 license = licenses.mit;
61 teams = [ teams.deshaw ];
62 };
63})