pyrox.dev
lol
scrumplex.net
1{
2 stdenvNoCC,
3 lib,
4 opencloud,
5 pnpm_10,
6 nodejs,
7}:
8
9stdenvNoCC.mkDerivation (finalAttrs: {
10 pname = "opencloud-idp-web";
11
12 inherit (opencloud) version src;
13
14 pnpmRoot = "services/idp";
15
16 pnpmDeps = pnpm_10.fetchDeps {
17 inherit (finalAttrs) pname version src;
18 sourceRoot = "${finalAttrs.src.name}/${finalAttrs.pnpmRoot}";
19 fetcherVersion = 1;
20 hash = "sha256-NW7HK2B9h5JprK3JcIGi/OHcyoa5VTs/P0s3BZr+4FU=";
21 };
22
23 nativeBuildInputs = [
24 nodejs
25 pnpm_10.configHook
26 ];
27
28 buildPhase = ''
29 runHook preBuild
30 cd $pnpmRoot
31 pnpm build
32 mkdir -p assets/identifier/static
33 cp -v src/images/favicon.svg assets/identifier/static/favicon.svg
34 cp -v src/images/icon-lilac.svg assets/identifier/static/icon-lilac.svg
35 runHook postBuild
36 '';
37
38 installPhase = ''
39 runHook preInstall
40 mkdir $out
41 cp -r assets $out
42 runHook postInstall
43 '';
44
45 meta = {
46 description = "OpenCloud - IDP Web UI";
47 homepage = "https://github.com/opencloud-eu/opencloud";
48 changelog = "https://github.com/opencloud-eu/opencloud/blob/${finalAttrs.src.tag}/CHANGELOG.md";
49 license = lib.licenses.asl20;
50 maintainers = with lib.maintainers; [
51 christoph-heiss
52 k900
53 ];
54 platforms = lib.platforms.all;
55 };
56})