pyrox.dev
lol
1{
2 lib,
3 stdenv,
4 rustPlatform,
5 fetchFromGitHub,
6 installShellFiles,
7}:
8
9rustPlatform.buildRustPackage rec {
10 pname = "intermodal";
11 version = "0.1.14";
12
13 src = fetchFromGitHub {
14 owner = "casey";
15 repo = "intermodal";
16 rev = "v${version}";
17 hash = "sha256-N3TumAwHcHDuVyY4t6FPNOO28D7xX5jheCTodfn71/Q=";
18 };
19
20 cargoHash = "sha256-NqbsDi47AhYw4hNcoWfXNUnc7WjC1en7mbyCJvhYdR4=";
21
22 # include_hidden test tries to use `chflags` on darwin
23 checkFlags = lib.optionals stdenv.hostPlatform.isDarwin [
24 "--skip=subcommand::torrent::create::tests::include_hidden"
25 ];
26
27 nativeBuildInputs = [ installShellFiles ];
28
29 postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
30 installShellCompletion --cmd imdl \
31 --bash <($out/bin/imdl completions bash) \
32 --fish <($out/bin/imdl completions fish) \
33 --zsh <($out/bin/imdl completions zsh)
34 '';
35
36 meta = {
37 description = "User-friendly and featureful command-line BitTorrent metainfo utility";
38 homepage = "https://github.com/casey/intermodal";
39 changelog = "https://github.com/casey/intermodal/releases/tag/v${version}";
40 license = lib.licenses.cc0;
41 maintainers = with lib.maintainers; [
42 Br1ght0ne
43 xrelkd
44 ];
45 mainProgram = "imdl";
46 };
47}