pyrox.dev
1{
2 lib,
3 stdenv,
4 buildPythonPackage,
5 fetchFromGitHub,
6
7 # build-system
8 setuptools,
9
10 # dependencies
11 typing-extensions,
12
13 # tests
14 cython,
15 numpy,
16 pytest-timeout,
17 pytest-xdist,
18 pytestCheckHook,
19 scikit-image,
20 scikit-learn,
21 torchtnt-nightly,
22 torchvision,
23}:
24let
25 pname = "torcheval";
26 version = "0.0.7";
27in
28buildPythonPackage {
29 inherit pname version;
30 pyproject = true;
31
32 src = fetchFromGitHub {
33 owner = "pytorch";
34 repo = "torcheval";
35 # Upstream has not created a tag for this version
36 # https://github.com/pytorch/torcheval/issues/215
37 rev = "f1bc22fc67ec2c77ee519aa4af8079f4fdaa41bb";
38 hash = "sha256-aVr4qKKE+dpBcJEi1qZJBljFLUl8d7D306Dy8uOojJE=";
39 };
40
41 # Patches are only applied to usages of numpy within tests,
42 # which are only used for testing purposes (see dev-requirements.txt)
43 postPatch =
44 # numpy's `np.NAN` was changed to `np.nan` when numpy 2 was released
45 ''
46 substituteInPlace tests/metrics/classification/test_accuracy.py tests/metrics/functional/classification/test_accuracy.py \
47 --replace-fail "np.NAN" "np.nan"
48 ''
49
50 # `unittest.TestCase.assertEquals` does not exist;
51 # the correct symbol is `unittest.TestCase.assertEqual`
52 + ''
53 substituteInPlace tests/metrics/test_synclib.py \
54 --replace-fail "tc.assertEquals" "tc.assertEqual"
55 '';
56
57 build-system = [ setuptools ];
58
59 dependencies = [ typing-extensions ];
60
61 pythonImportsCheck = [ "torcheval" ];
62
63 nativeCheckInputs = [
64 cython
65 numpy
66 pytest-timeout
67 pytest-xdist
68 pytestCheckHook
69 scikit-image
70 scikit-learn
71 torchtnt-nightly
72 torchvision
73 ];
74
75 pytestFlagsArray =
76 [
77 "-v"
78 "tests/"
79
80 # -- tests/metrics/audio/test_fad.py --
81 # Touch filesystem and require network access.
82 # torchaudio.utils.download_asset("models/vggish.pt") -> PermissionError: [Errno 13] Permission denied: '/homeless-shelter'
83 "--deselect=tests/metrics/audio/test_fad.py::TestFAD::test_vggish_fad"
84 "--deselect=tests/metrics/audio/test_fad.py::TestFAD::test_vggish_fad_merge"
85
86 # -- tests/metrics/image/test_fid.py --
87 # Touch filesystem and require network access.
88 # models.inception_v3(weights=weights) -> PermissionError: [Errno 13] Permission denied: '/homeless-shelter'
89 "--deselect=tests/metrics/image/test_fid.py::TestFrechetInceptionDistance::test_fid_invalid_input"
90 "--deselect=tests/metrics/image/test_fid.py::TestFrechetInceptionDistance::test_fid_random_data_custom_model"
91 "--deselect=tests/metrics/image/test_fid.py::TestFrechetInceptionDistance::test_fid_random_data_default_model"
92 "--deselect=tests/metrics/image/test_fid.py::TestFrechetInceptionDistance::test_fid_with_dissimilar_inputs"
93 "--deselect=tests/metrics/image/test_fid.py::TestFrechetInceptionDistance::test_fid_with_similar_inputs"
94
95 # -- tests/metrics/functional/text/test_perplexity.py --
96 # AssertionError: Scalars are not close!
97 # Expected 3.537154912949 but got 3.53715443611145
98 "--deselect=tests/metrics/functional/text/test_perplexity.py::Perplexity::test_perplexity_with_ignore_index"
99
100 # -- tests/metrics/image/test_psnr.py --
101 # AssertionError: Scalars are not close!
102 # Expected 7.781850814819336 but got 7.781772613525391
103 "--deselect=tests/metrics/image/test_psnr.py::TestPeakSignalNoiseRatio::test_psnr_with_random_data"
104
105 # -- tests/metrics/regression/test_mean_squared_error.py --
106 # AssertionError: Scalars are not close!
107 # Expected -640.4547729492188 but got -640.4707641601562
108 "--deselect=tests/metrics/regression/test_mean_squared_error.py::TestMeanSquaredError::test_mean_squared_error_class_update_input_shape_different"
109
110 # -- tests/metrics/window/test_mean_squared_error.py --
111 # AssertionError: Scalars are not close!
112 # Expected 0.0009198983898386359 but got 0.0009198188781738281
113 "--deselect=tests/metrics/window/test_mean_squared_error.py::TestMeanSquaredError::test_mean_squared_error_class_update_input_shape_different"
114 ]
115
116 # These tests error on darwin platforms.
117 # NotImplementedError: The operator 'c10d::allgather_' is not currently implemented for the mps device
118 #
119 # Applying the suggested environment variable `PYTORCH_ENABLE_MPS_FALLBACK=1;` causes the tests to fail,
120 # as using the CPU instead of the MPS causes the tensors to be on the wrong device:
121 # RuntimeError: ProcessGroupGloo::allgather: invalid tensor type at index 0;
122 # Expected TensorOptions(dtype=float, device=cpu, ...), got TensorOptions(dtype=float, device=mps:0, ...)
123 ++ lib.optional stdenv.hostPlatform.isDarwin [
124 # -- tests/metrics/test_synclib.py --
125 "--deselect=tests/metrics/test_synclib.py::SynclibTest::test_complex_mixed_state_sync"
126 "--deselect=tests/metrics/test_synclib.py::SynclibTest::test_complex_mixed_state_sync"
127 "--deselect=tests/metrics/test_synclib.py::SynclibTest::test_empty_tensor_list_sync_state"
128 "--deselect=tests/metrics/test_synclib.py::SynclibTest::test_sync_dtype_and_shape"
129 "--deselect=tests/metrics/test_synclib.py::SynclibTest::test_tensor_list_sync_states"
130 "--deselect=tests/metrics/test_synclib.py::SynclibTest::test_tensor_dict_sync_states"
131 "--deselect=tests/metrics/test_synclib.py::SynclibTest::test_tensor_sync_states"
132 # -- tests/metrics/test_toolkit.py --
133 "--deselect=tests/metrics/test_toolkit.py::MetricToolkitTest::test_metric_sync"
134 "--deselect=tests/metrics/test_toolkit.py::MetricCollectionToolkitTest::test_metric_collection_sync"
135 ];
136
137 meta = {
138 description = "Rich collection of performant PyTorch model metrics and tools for PyTorch model evaluations";
139 homepage = "https://pytorch.org/torcheval";
140 changelog = "https://github.com/pytorch/torcheval/releases/tag/${version}";
141
142 platforms = lib.platforms.unix;
143 license = [ lib.licenses.bsd3 ];
144 maintainers = [ lib.maintainers.bengsparks ];
145 };
146}