pyrox.dev
1{ lib, stdenv, fetchurl, fetchpatch, fetchzip }:
2
3stdenv.mkDerivation rec {
4 pname = "figlet";
5 version = "2.2.5";
6
7 # some tools can be found here ftp://ftp.figlet.org/pub/figlet/util/
8 src = fetchurl {
9 url = "ftp://ftp.figlet.org/pub/figlet/program/unix/figlet-${version}.tar.gz";
10 sha256 = "0za1ax15x7myjl8jz271ybly8ln9kb9zhm1gf6rdlxzhs07w925z";
11 };
12
13 contributed = fetchzip {
14 url = "ftp://ftp.figlet.org/pub/figlet/fonts/contributed.tar.gz";
15 hash = "sha256-AyvAoc3IqJeKWgJftBahxb/KJjudeJIY4KD6mElNagQ=";
16 };
17
18 patches = [
19 (fetchpatch {
20 url = "https://git.alpinelinux.org/aports/plain/main/figlet/musl-fix-cplusplus-decls.patch?h=3.4-stable&id=71776c73a6f04b6f671430f702bcd40b29d48399";
21 name = "musl-fix-cplusplus-decls.patch";
22 sha256 = "1720zgrfk9makznqkbjrnlxm7nnhk6zx7g458fv53337n3g3zn7j";
23 })
24 (fetchpatch {
25 url = "https://github.com/cmatsuoka/figlet/commit/9a50c1795bc32e5a698b855131ee87c8d7762c9e.patch";
26 name = "unistd-on-darwin.patch";
27 sha256 = "hyfY87N+yuAwjsBIjpgvcdJ1IbzlR4A2yUJQSzShCRI=";
28 })
29 ];
30
31 makeFlags = [ "prefix=$(out)" "CC:=$(CC)" "LD:=$(CC)" ];
32
33 postInstall = "cp -ar ${contributed}/* $out/share/figlet/";
34
35 doCheck = true;
36
37 meta = {
38 description = "Program for making large letters out of ordinary text";
39 homepage = "http://www.figlet.org/";
40 license = lib.licenses.afl21;
41 maintainers = with lib.maintainers; [ ehmry ];
42 platforms = lib.platforms.unix;
43 };
44}