pyrox.dev
1{ lib
2, stdenv
3, fetchurl
4, installShellFiles
5}:
6let
7 arch = with stdenv.hostPlatform; if isx86_64 then "amd64"
8 else if isAarch64 then "arm64"
9 else if isi686 then "386"
10 else if isPower64 && isLittleEndian then "ppc64le"
11 else if isS390x then "s390x"
12 else throw "Unsupported arch: ${stdenv.hostPlatform.system}";
13 platform = if stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64 then "macos_arm64"
14 else if stdenv.hostPlatform.isDarwin then "macos"
15 else "linux_${arch}";
16in
17stdenv.mkDerivation (finalAttrs: {
18 pname = "ibmcloud-cli";
19 version = "2.17.0";
20
21 src = fetchurl {
22 url = "https://download.clis.cloud.ibm.com/ibm-cloud-cli/${finalAttrs.version}/binaries/IBM_Cloud_CLI_${finalAttrs.version}_${platform}.tgz";
23 sha256 = {
24 "x86_64-darwin" = "18f0dylgwwn9p1jmchqhq061s435n85qr2872i532whbrziwwjf3";
25 "aarch64-darwin" = "1rid6rv601z4ayd3yi5srqbfn5bspypxarikvm563ygxawh1bxyi";
26 "x86_64-linux" = "0ry8ix5id2zk04w9d9581g127f9jpj7bwg3x0pk3n9yfwn61g96d";
27 "aarch64-linux" = "0s5jaqhyl234670q1mg89in2g5b9w3gzvnzl8qmlmgqkaxvzxj94";
28 "i686-linux" = "0iw8y7iy9yx7y8v8b2wfl24f2rv9r20yj7l4sislxspfyvqv54p2";
29 "powerpc64le-linux" = "19ac0na163l9h7ygbf3jwwv7zf0wagqvn6kcdh871c690i86wg9z";
30 "s390x-linux" = "1zvy28jpxijzgdbr9q4rfyx6mk295mqp4nk8z299nm9ryk4q81lv";
31 }.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
32 };
33
34 nativeBuildInputs = [ installShellFiles ];
35
36 installPhase = ''
37 runHook preInstall
38
39 install -D ibmcloud $out/bin/ibmcloud
40 mkdir -p $out/share/ibmcloud
41 cp CF_CLI_Notices.txt CF_CLI_SLC_Notices.txt LICENSE NOTICE $out/share/ibmcloud
42 export HOME=$(mktemp -d)
43 installShellCompletion --cmd ibmcloud --bash <($out/bin/ibmcloud --generate-bash-completion)
44
45 runHook postInstall
46 '';
47
48 meta = with lib; {
49 description = "Command line client for IBM Cloud";
50 homepage = "https://cloud.ibm.com/docs/cli";
51 license = licenses.asl20;
52 maintainers = with maintainers; [ emilytrau ];
53 platforms = [ "x86_64-linux" "aarch64-linux" "i686-linux" "powerpc64le-linux" "s390x-linux" ] ++ platforms.darwin;
54 sourceProvenance = with sourceTypes; [ binaryNativeCode ];
55 mainProgram = "ibmcloud";
56 };
57})