pyrox.dev
1{ lib, stdenv, fetchFromGitHub, postgresql, postgresqlTestHook }:
2
3stdenv.mkDerivation (finalAttrs: {
4 pname = "pg_squeeze";
5 version = "1.6.2";
6
7 src = fetchFromGitHub {
8 owner = "cybertec-postgresql";
9 repo = "pg_squeeze";
10 rev = "REL${builtins.replaceStrings ["."] ["_"] finalAttrs.version}";
11 hash = "sha256-YS13iIpQ4NJe0N6bRVa2RDxEMwEzBc2mjNYM5/Vqjn8=";
12 };
13
14 buildInputs = [
15 postgresql
16 ];
17
18 installPhase = ''
19 runHook preInstall
20
21 install -D -t $out/lib pg_squeeze${postgresql.dlSuffix}
22 install -D -t $out/share/postgresql/extension pg_squeeze-*.sql
23 install -D -t $out/share/postgresql/extension pg_squeeze.control
24
25 runHook postInstall
26 '';
27
28 passthru.tests.extension = stdenv.mkDerivation {
29 name = "pg_squeeze-test";
30 dontUnpack = true;
31 doCheck = true;
32 nativeCheckInputs = [ postgresqlTestHook (postgresql.withPackages (_: [ finalAttrs.finalPackage ])) ];
33 failureHook = "postgresqlStop";
34 postgresqlTestUserOptions = "LOGIN SUPERUSER";
35 postgresqlExtraSettings = ''
36 wal_level = logical
37 shared_preload_libraries = 'pg_squeeze'
38 '';
39 passAsFile = [ "sql" ];
40 sql = ''
41 CREATE EXTENSION pg_squeeze;
42
43 SELECT squeeze.start_worker();
44
45 CREATE TABLE a(i int PRIMARY KEY, j int);
46 INSERT INTO a(i, j) SELECT x, x FROM generate_series(1, 20) AS g(x);
47 INSERT INTO squeeze.tables (tabschema, tabname, schedule)
48 VALUES ('public', 'a', ('{30}', '{22}', NULL, NULL, '{3, 5}'));
49 SELECT squeeze.squeeze_table('public', 'a', NULL, NULL, NULL);
50 '';
51 checkPhase = ''
52 runHook preCheck
53 psql -a -v ON_ERROR_STOP=1 -f $sqlPath
54 runHook postCheck
55 '';
56 installPhase = "touch $out";
57 };
58
59 meta = with lib; {
60 description = "A PostgreSQL extension for automatic bloat cleanup";
61 homepage = "https://github.com/cybertec-postgresql/pg_squeeze";
62 changelog = "https://github.com/cybertec-postgresql/pg_squeeze/blob/${finalAttrs.src.rev}/NEWS";
63 license = licenses.mit;
64 maintainers = [ ];
65 platforms = postgresql.meta.platforms;
66 };
67})