pyrox.dev
fork
Configure Feed
Select the types of activity you want to include in your feed.
lol
fork
Configure Feed
Select the types of activity you want to include in your feed.
1{ lib, stdenv, qtbase, qtdeclarative, fetchFromGitHub, cmake, pkg-config, box2d }:
2
3let
4 inherit (lib) cmakeBool;
5
6 # 2.3.1 is the only supported version
7 box2d' = (box2d.override { settingsFile = "Box2D/Common/b2Settings.h"; }).overrideAttrs (old: rec {
8 version = "2.3.1";
9 src = fetchFromGitHub {
10 owner = "erincatto";
11 repo = "box2d";
12 rev = "v${version}";
13 hash = "sha256-Z2J17YMzQNZqABIa5eyJDT7BWfXveymzs+DWsrklPIs=";
14 };
15 sourceRoot = "source/Box2D";
16 cmakeFlags = old.cmakeFlags or [ ] ++ [
17 (cmakeBool "BOX2D_INSTALL" true)
18 (cmakeBool "BOX2D_BUILD_SHARED" true)
19 (cmakeBool "BOX2D_BUILD_EXAMPLES" false)
20 ];
21 });
22
23in
24stdenv.mkDerivation {
25 pname = "qml-box2d";
26 version = "unstable-2022-08-25";
27
28 src = fetchFromGitHub {
29 owner = "qml-box2d";
30 repo = "qml-box2d";
31 rev = "0bb88a6f871eef72b3b9ded9329c15f1da1f4fd7";
32 hash = "sha256-sfSVetpHIAIujpgjvRScAkJRlQQYjQ/yQrkWvp7Yu0s=";
33 };
34
35 dontWrapQtApps = true;
36
37 nativeBuildInputs = [ cmake pkg-config ];
38
39 buildInputs = [ box2d' qtbase qtdeclarative ];
40
41 cmakeFlags = [
42 (cmakeBool "USE_SYSTEM_BOX2D" true)
43 ];
44
45 meta = with lib; {
46 description = "A QML plugin for Box2D engine";
47 homepage = "https://github.com/qml-box2d/qml-box2d";
48 maintainers = with maintainers; [ guibou ];
49 platforms = platforms.linux;
50 license = licenses.zlib;
51 };
52}