pyrox.dev
lol
1{ lib
2, stdenvNoCC
3, fetchurl
4, jre
5, makeWrapper
6, copyDesktopItems
7, makeDesktopItem
8}:
9
10stdenvNoCC.mkDerivation (finalAttrs: {
11 pname = "stegsolve";
12 version = "1.3";
13
14 src = fetchurl {
15 # No versioned binary is published :(
16 url = "https://web.archive.org/web/20230319054116if_/http://www.caesum.com/handbook/Stegsolve.jar";
17 sha256 = "0np5zb28sg6yzkp1vic80pm8iiaamvjpbf5dxmi9kwvqcrh4jyq0";
18 };
19
20 dontUnpack = true;
21
22 desktopItems = [
23 (makeDesktopItem {
24 type = "Application";
25 name = finalAttrs.pname;
26 desktopName = "Stegsolve";
27 comment = "A steganographic image analyzer, solver and data extractor for challanges";
28 exec = finalAttrs.pname;
29 categories = [ "Graphics" ];
30 })
31 ];
32
33 nativeBuildInputs = [ makeWrapper copyDesktopItems ];
34
35 installPhase = ''
36 runHook preInstall
37
38 export JAR=$out/share/java/stegsolve/stegsolve.jar
39 install -D $src $JAR
40 makeWrapper ${jre}/bin/java $out/bin/stegsolve \
41 --add-flags "-jar $JAR"
42
43 runHook postInstall
44 '';
45
46 meta = with lib; {
47 description = "A steganographic image analyzer, solver and data extractor for challanges";
48 homepage = "https://www.wechall.net/forum/show/thread/527/Stegsolve_1.3/";
49 sourceProvenance = with sourceTypes; [ binaryBytecode ];
50 license = {
51 fullName = "Cronos License";
52 url = "http://www.caesum.com/legal.php";
53 free = false;
54 redistributable = true;
55 };
56 maintainers = with maintainers; [ emilytrau ];
57 platforms = platforms.all;
58 };
59})