pyrox.dev
lol
1{ lib, stdenv, fetchurl, guileSupport ? false, pkg-config ? null , guile ? null }:
2
3assert guileSupport -> ( pkg-config != null && guile != null );
4
5stdenv.mkDerivation rec {
6 pname = "gnumake";
7 version = "4.2.1";
8
9 src = fetchurl {
10 url = "mirror://gnu/make/make-${version}.tar.bz2";
11 sha256 = "12f5zzyq2w56g95nni65hc0g5p7154033y2f3qmjvd016szn5qnn";
12 };
13
14 patchFlags = [ "-p0" ];
15 patches = [
16 # Purity: don't look for library dependencies (of the form `-lfoo') in /lib
17 # and /usr/lib. It's a stupid feature anyway. Likewise, when searching for
18 # included Makefiles, don't look in /usr/include and friends.
19 ./impure-dirs.patch
20 ./pselect.patch
21 # Fix support for glibc 2.27's glob, inspired by http://www.linuxfromscratch.org/lfs/view/8.2/chapter05/make.html
22 ./glibc-2.27-glob.patch
23 ./glibc-2.33-glob.patch
24 ];
25
26 nativeBuildInputs = lib.optionals guileSupport [ pkg-config ];
27 buildInputs = lib.optionals guileSupport [ guile ];
28
29 configureFlags = lib.optional guileSupport "--with-guile"
30
31 # Make uses this test to decide whether it should keep track of
32 # subseconds. Apple made this possible with APFS and macOS 10.13.
33 # However, we still support macOS 10.11 and 10.12. Binaries built
34 # in Nixpkgs will be unable to use futimens to set mtime less than
35 # a second. So, tell Make to ignore nanoseconds in mtime here by
36 # overriding the autoconf test for the struct.
37 # See https://github.com/NixOS/nixpkgs/issues/51221 for discussion.
38 ++ lib.optional stdenv.isDarwin "ac_cv_struct_st_mtim_nsec=no";
39
40 outputs = [ "out" "man" "info" ];
41
42 meta = with lib; {
43 description = "A tool to control the generation of non-source files from sources";
44 longDescription = ''
45 Make is a tool which controls the generation of executables and
46 other non-source files of a program from the program's source files.
47
48 Make gets its knowledge of how to build your program from a file
49 called the makefile, which lists each of the non-source files and
50 how to compute it from other files. When you write a program, you
51 should write a makefile for it, so that it is possible to use Make
52 to build and install the program.
53 '';
54 homepage = "https://www.gnu.org/software/make/";
55
56 license = licenses.gpl3Plus;
57 maintainers = [ maintainers.vrthra ];
58 mainProgram = "make";
59 platforms = platforms.all;
60 };
61}