pyrox.dev
1{ buildPythonPackage
2, fetchFromGitHub
3, writeText
4, lib
5, attrs
6, six
7, okonomiyaki
8}:
9
10let
11 version = "0.8.2";
12
13 versionFile = writeText "simplesat_ver" ''
14 version = '${version}'
15 full_version = '${version}'
16 git_revision = '0000000000000000000000000000000000000000'
17 is_released = True
18 msi_version = '${version}.000'
19 version_info = (${lib.versions.major version}, ${lib.versions.minor version}, ${lib.versions.patch version}, 'final', 0)
20 '';
21
22in buildPythonPackage rec {
23 pname = "simplesat";
24 inherit version;
25
26 propagatedBuildInputs = [ attrs six okonomiyaki ];
27
28 src = fetchFromGitHub {
29 owner = "enthought";
30 repo = "sat-solver";
31 rev = "v${version}";
32 hash = "sha256-6BQn1W2JGrMmNqgxi+sXx06XzNMcvwqYGMkpD0SSpT8=";
33 };
34
35 preConfigure = ''
36 cp ${versionFile} simplesat/_version.py
37 '';
38 dontUseSetuptoolsCheck = true;
39
40 pythonImportsCheck = [ "simplesat" ];
41
42 meta = with lib; {
43 homepage = "https://github.com/enthought/sat-solver";
44 description = "Prototype for SAT-based dependency handling";
45 maintainers = with maintainers; [ genericnerdyusername ];
46 license = licenses.bsd3;
47 };
48}