pyrox.dev
1{ lib, stdenv, fetchFromGitHub, kernel }:
2let
3 version = "1.0.13";
4 sha256 = "162hhmnww8z9k0795ffs8v3f61hlfm375law156sk5l08if19a4r";
5in
6stdenv.mkDerivation {
7 name = "system76-module-${version}-${kernel.version}";
8
9 passthru.moduleName = "system76";
10
11 src = fetchFromGitHub {
12 owner = "pop-os";
13 repo = "system76-dkms";
14 rev = version;
15 inherit sha256;
16 };
17
18 hardeningDisable = [ "pic" ];
19
20 nativeBuildInputs = kernel.moduleBuildDependencies;
21
22 buildFlags = [
23 "KERNEL_DIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
24 ];
25
26 installPhase = ''
27 install -D system76.ko $out/lib/modules/${kernel.modDirVersion}/misc/system76.ko
28 mkdir -p $out/lib/udev/hwdb.d
29 mv lib/udev/hwdb.d/* $out/lib/udev/hwdb.d
30 '';
31
32 meta = with lib; {
33 maintainers = [ maintainers.khumba ];
34 license = [ licenses.gpl2Plus ];
35 platforms = [ "i686-linux" "x86_64-linux" ];
36 broken = versionOlder kernel.version "4.14";
37 description = "System76 DKMS driver";
38 homepage = "https://github.com/pop-os/system76-dkms";
39 longDescription = ''
40 The System76 DKMS driver. On newer System76 laptops, this driver controls
41 some of the hotkeys and allows for custom fan control.
42 '';
43 };
44}