pyrox.dev
1{ lib, buildLinux, fetchurl
2, kernelPatches ? [ ]
3, structuredExtraConfig ? {}
4, extraMeta ? {}
5, argsOverride ? {}
6, ... } @ args:
7
8let
9 version = "5.15.137-rt71"; # updated by ./update-rt.sh
10 branch = lib.versions.majorMinor version;
11 kversion = builtins.elemAt (lib.splitString "-" version) 0;
12in buildLinux (args // {
13 inherit version;
14
15 # modDirVersion needs a patch number, change X.Y-rtZ to X.Y.0-rtZ.
16 modDirVersion = if (builtins.match "[^.]*[.][^.]*-.*" version) == null then version
17 else lib.replaceStrings ["-"] [".0-"] version;
18
19 src = fetchurl {
20 url = "mirror://kernel/linux/kernel/v5.x/linux-${kversion}.tar.xz";
21 sha256 = "1xxjbxldrhmnh2q6rykpxyfbj8xqgl82q30n8sfavrzr14bb4jcp";
22 };
23
24 kernelPatches = let rt-patch = {
25 name = "rt";
26 patch = fetchurl {
27 url = "mirror://kernel/linux/kernel/projects/rt/${branch}/older/patch-${version}.patch.xz";
28 sha256 = "11zk02ni3b0l1wwrfvyc1q92bd9as61hwgbwlj42xv5gbpd39jlw";
29 };
30 }; in [ rt-patch ] ++ kernelPatches;
31
32 structuredExtraConfig = with lib.kernel; {
33 PREEMPT_RT = yes;
34 # Fix error: unused option: PREEMPT_RT.
35 EXPERT = yes; # PREEMPT_RT depends on it (in kernel/Kconfig.preempt)
36 # Fix error: option not set correctly: PREEMPT_VOLUNTARY (wanted 'y', got 'n').
37 PREEMPT_VOLUNTARY = lib.mkForce no; # PREEMPT_RT deselects it.
38 # Fix error: unused option: RT_GROUP_SCHED.
39 RT_GROUP_SCHED = lib.mkForce (option no); # Removed by sched-disable-rt-group-sched-on-rt.patch.
40 } // structuredExtraConfig;
41
42 extraMeta = extraMeta // {
43 inherit branch;
44 };
45} // argsOverride)