pyrox.dev
1{ lib, buildLinux, fetchurl
2, kernelPatches ? [ ]
3, structuredExtraConfig ? {}
4, extraMeta ? {}
5, argsOverride ? {}
6, ... } @ args:
7
8let
9 version = "5.10.199-rt97"; # updated by ./update-rt.sh
10 branch = lib.versions.majorMinor version;
11 kversion = builtins.elemAt (lib.splitString "-" version) 0;
12in buildLinux (args // {
13 inherit version;
14
15 # modDirVersion needs a patch number, change X.Y-rtZ to X.Y.0-rtZ.
16 modDirVersion = lib.versions.pad 3 version;
17
18 src = fetchurl {
19 url = "mirror://kernel/linux/kernel/v5.x/linux-${kversion}.tar.xz";
20 sha256 = "1h944syk7n6c4j1djlx19n77alzwbxcdza77c9ykicgfynhpgsm0";
21 };
22
23 kernelPatches = let rt-patch = {
24 name = "rt";
25 patch = fetchurl {
26 url = "mirror://kernel/linux/kernel/projects/rt/${branch}/older/patch-${version}.patch.xz";
27 sha256 = "13k7md0a63q4r5vqqvbszmg3kzp5np0hdaj1siyl4yvs9j78d03s";
28 };
29 }; in [ rt-patch ] ++ kernelPatches;
30
31 structuredExtraConfig = with lib.kernel; {
32 PREEMPT_RT = yes;
33 # Fix error: unused option: PREEMPT_RT.
34 EXPERT = yes; # PREEMPT_RT depends on it (in kernel/Kconfig.preempt)
35 # Fix error: option not set correctly: PREEMPT_VOLUNTARY (wanted 'y', got 'n').
36 PREEMPT_VOLUNTARY = lib.mkForce no; # PREEMPT_RT deselects it.
37 # Fix error: unused option: RT_GROUP_SCHED.
38 RT_GROUP_SCHED = lib.mkForce (option no); # Removed by sched-disable-rt-group-sched-on-rt.patch.
39 } // structuredExtraConfig;
40
41 extraMeta = extraMeta // {
42 inherit branch;
43 };
44} // argsOverride)