pyrox.dev
1{ lib, stdenv, fetchurl, pkg-config, libnl, openssl, sqlite ? null }:
2
3stdenv.mkDerivation rec {
4 pname = "hostapd";
5 version = "2.10";
6
7 src = fetchurl {
8 url = "https://w1.fi/releases/${pname}-${version}.tar.gz";
9 sha256 = "sha256-IG58eZtnhXLC49EgMCOHhLxKn4IyOwFWtMlGbxSYkV0=";
10 };
11
12 nativeBuildInputs = [ pkg-config ];
13 buildInputs = [ libnl openssl sqlite ];
14
15 patches = [
16 (fetchurl {
17 # Note: fetchurl seems to be unhappy with openwrt git
18 # server's URLs containing semicolons. Using the github mirror instead.
19 url = "https://raw.githubusercontent.com/openwrt/openwrt/eefed841b05c3cd4c65a78b50ce0934d879e6acf/package/network/services/hostapd/patches/300-noscan.patch";
20 sha256 = "08p5frxhpq1rp2nczkscapwwl8g9nc4fazhjpxic5bcbssc3sb00";
21 })
22 ];
23
24 outputs = [ "out" "man" ];
25
26 # Based on hostapd's defconfig. Only differences are tracked.
27 extraConfig = ''
28 # Use epoll(7) instead of select(2) on linux
29 CONFIG_ELOOP_EPOLL=y
30
31 # Drivers
32 CONFIG_DRIVER_WIRED=y
33 CONFIG_DRIVER_NONE=y
34
35 # Integrated EAP server
36 CONFIG_EAP_SIM=y
37 CONFIG_EAP_AKA=y
38 CONFIG_EAP_AKA_PRIME=y
39 CONFIG_EAP_PAX=y
40 CONFIG_EAP_PSK=y
41 CONFIG_EAP_PWD=y
42 CONFIG_EAP_SAKE=y
43 CONFIG_EAP_GPSK=y
44 CONFIG_EAP_GPSK_SHA256=y
45 CONFIG_EAP_FAST=y
46 CONFIG_EAP_IKEV2=y
47 CONFIG_EAP_TNC=y
48 CONFIG_EAP_EKE=y
49
50 CONFIG_TLS=openssl
51 CONFIG_TLSV11=y
52 CONFIG_TLSV12=y
53
54 CONFIG_SAE=y
55 CONFIG_SAE_PK=y
56
57 CONFIG_OWE=y
58 CONFIG_OCV=y
59
60 # TKIP is considered insecure and upstream support will be removed in the future
61 CONFIG_NO_TKIP=y
62
63 # Misc
64 CONFIG_RADIUS_SERVER=y
65 CONFIG_FULL_DYNAMIC_VLAN=y
66 CONFIG_VLAN_NETLINK=y
67 CONFIG_GETRANDOM=y
68 CONFIG_INTERWORKING=y
69 CONFIG_HS20=y
70 CONFIG_FST=y
71 CONFIG_FST_TEST=y
72 CONFIG_ACS=y
73 CONFIG_WNM=y
74 CONFIG_MBO=y
75
76 CONFIG_IEEE80211R=y
77 CONFIG_IEEE80211W=y
78 CONFIG_IEEE80211N=y
79 CONFIG_IEEE80211AC=y
80 CONFIG_IEEE80211AX=y
81 '' + lib.optionalString (sqlite != null) ''
82 CONFIG_SQLITE=y
83 '';
84
85 passAsFile = [ "extraConfig" ];
86
87 configurePhase = ''
88 cd hostapd
89 cp -v defconfig .config
90 cat $extraConfigPath >> .config
91 cat -n .config
92 substituteInPlace Makefile --replace /usr/local $out
93 export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE $(pkg-config --cflags libnl-3.0)"
94 '';
95
96 preInstall = "mkdir -p $out/bin";
97 postInstall = ''
98 install -vD hostapd.8 -t $man/share/man/man8
99 install -vD hostapd_cli.1 -t $man/share/man/man1
100 '';
101
102 meta = with lib; {
103 homepage = "https://w1.fi/hostapd/";
104 description = "A user space daemon for access point and authentication servers";
105 license = licenses.gpl2;
106 maintainers = with maintainers; [ hexa ];
107 platforms = platforms.linux;
108 };
109}