pyrox.dev
1{ lib, stdenv, fetchFromGitHub, bash, perl, python3 }:
2
3stdenv.mkDerivation rec {
4 pname = "dmtcp";
5 version = "unstable-2022-02-28";
6
7 src = fetchFromGitHub {
8 owner = pname;
9 repo = pname;
10 rev = "133687764c6742906006a1d247e3b83cd860fa1d";
11 hash = "sha256-9Vr8IhoeATCfyt7Lp7kYe/7e87mFX9KMNGTqxJgIztE=";
12 };
13
14 dontDisableStatic = true;
15
16 patches = [ ./ld-linux-so-buffer-size.patch ];
17
18 postPatch = ''
19 patchShebangs .
20
21 substituteInPlace configure \
22 --replace '#define ELF_INTERPRETER "$interp"' \
23 "#define ELF_INTERPRETER \"$(cat $NIX_CC/nix-support/dynamic-linker)\""
24 substituteInPlace src/restartscript.cpp \
25 --replace /bin/bash ${stdenv.shell}
26 substituteInPlace util/dmtcp_restart_wrapper.sh \
27 --replace /bin/bash ${stdenv.shell}
28 substituteInPlace test/autotest.py \
29 --replace /bin/bash ${bash}/bin/bash \
30 --replace /usr/bin/perl ${perl}/bin/perl \
31 --replace /usr/bin/python ${python3.interpreter} \
32 --replace "os.environ['USER']" "\"nixbld1\"" \
33 --replace "os.getenv('USER')" "\"nixbld1\""
34 '';
35
36 meta = with lib; {
37 description = "Distributed MultiThreaded Checkpointing";
38 longDescription = ''
39 DMTCP (Distributed MultiThreaded Checkpointing) is a tool to
40 transparently checkpointing the state of an arbitrary group of
41 programs spread across many machines and connected by sockets. It does
42 not modify the user's program or the operating system.
43 '';
44 homepage = "http://dmtcp.sourceforge.net/";
45 license = licenses.lgpl3Plus; # most files seem this or LGPL-2.1+
46 platforms = intersectLists platforms.linux platforms.x86; # broken on ARM and Darwin
47 };
48}