pyrox.dev
1{ lib, stdenv, fetchurl, kernel }:
2
3let
4 version = "6.30.223.271";
5 hashes = {
6 i686-linux = "1kaqa2dw3nb8k23ffvx46g8jj3wdhz8xa6jp1v3wb35cjfr712sg";
7 x86_64-linux = "1gj485qqr190idilacpxwgqyw21il03zph2rddizgj7fbd6pfyaz";
8 };
9
10 arch = lib.optionalString (stdenv.hostPlatform.system == "x86_64-linux") "_64";
11 tarballVersion = lib.replaceStrings ["."] ["_"] version;
12 tarball = "hybrid-v35${arch}-nodebug-pcoem-${tarballVersion}.tar.gz";
13in
14stdenv.mkDerivation {
15 name = "broadcom-sta-${version}-${kernel.version}";
16
17 src = fetchurl {
18 url = "https://docs.broadcom.com/docs-and-downloads/docs/linux_sta/${tarball}";
19 sha256 = hashes.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
20 };
21
22 hardeningDisable = [ "pic" ];
23
24 nativeBuildInputs = kernel.moduleBuildDependencies;
25
26 patches = [
27 ./i686-build-failure.patch
28 ./license.patch
29 ./linux-4.7.patch
30 # source: https://git.archlinux.org/svntogit/community.git/tree/trunk/004-linux48.patch?h=packages/broadcom-wl-dkms
31 ./linux-4.8.patch
32 # source: https://aur.archlinux.org/cgit/aur.git/tree/linux411.patch?h=broadcom-wl
33 ./linux-4.11.patch
34 # source: https://aur.archlinux.org/cgit/aur.git/tree/linux412.patch?h=broadcom-wl
35 ./linux-4.12.patch
36 ./linux-4.15.patch
37 ./linux-5.1.patch
38 # source: https://salsa.debian.org/Herrie82-guest/broadcom-sta/-/commit/247307926e5540ad574a17c062c8da76990d056f
39 ./linux-5.6.patch
40 # source: https://gist.github.com/joanbm/5c640ac074d27fd1d82c74a5b67a1290
41 ./linux-5.9.patch
42 # source: https://github.com/archlinux/svntogit-community/blob/33b4bd2b9e30679b03f5d7aa2741911d914dcf94/trunk/012-linux517.patch
43 ./linux-5.17.patch
44 # source: https://github.com/archlinux/svntogit-community/blob/2e1fd240f9ce06f500feeaa3e4a9675e65e6b967/trunk/013-linux518.patch
45 ./linux-5.18.patch
46 # source: https://gist.github.com/joanbm/207210d74637870c01ef5a3c262a597d
47 ./linux-6.0.patch
48 # source: https://gist.github.com/joanbm/94323ea99eff1e1d1c51241b5b651549
49 ./linux-6.1.patch
50 ./pedantic-fix.patch
51 ./null-pointer-fix.patch
52 ./gcc.patch
53 ];
54
55 makeFlags = [ "KBASE=${kernel.dev}/lib/modules/${kernel.modDirVersion}" ];
56
57 unpackPhase = ''
58 sourceRoot=broadcom-sta
59 mkdir "$sourceRoot"
60 tar xvf "$src" -C "$sourceRoot"
61 '';
62
63 installPhase = ''
64 binDir="$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
65 docDir="$out/share/doc/broadcom-sta/"
66 mkdir -p "$binDir" "$docDir"
67 cp wl.ko "$binDir"
68 cp lib/LICENSE.txt "$docDir"
69 '';
70
71 meta = {
72 description = "Kernel module driver for some Broadcom's wireless cards";
73 homepage = "http://www.broadcom.com/support/802.11/linux_sta.php";
74 license = lib.licenses.unfreeRedistributable;
75 maintainers = with lib.maintainers; [ ];
76 platforms = lib.platforms.linux;
77 };
78}