pyrox.dev
1{ lib, stdenv, fetchgit, autoconf, popt, zlib, rpcsvc-proto, libtirpc }:
2
3stdenv.mkDerivation rec {
4 pname = "dbench";
5 version = "2013-01-01";
6
7 src = fetchgit {
8 url = "git://git.samba.org/sahlberg/${pname}.git";
9 rev = "65b19870ed8d25bff14cafa1c30beb33f1fb6597";
10 sha256 = "16lcbwmmx8z5i73k3dnf54yffrpx7ql3y9k3cpkss9dcyxb1p83i";
11 };
12
13 nativeBuildInputs = [ autoconf rpcsvc-proto ];
14 buildInputs = [ popt zlib libtirpc ];
15 env.NIX_CFLAGS_COMPILE = toString [ "-I${libtirpc.dev}/include/tirpc" ];
16 NIX_LDFLAGS = [ "-ltirpc" ];
17
18 patches = [
19 # patch has been also sent upstream and might be included in future versions
20 ./fix-missing-stdint.patch
21 ];
22
23 preConfigure = ''
24 ./autogen.sh
25 configureFlagsArray+=("--datadir=$out/share/dbench")
26 '';
27
28 postInstall = ''
29 cp -R loadfiles/* $out/share/dbench/doc/dbench/loadfiles
30
31 # dbench looks here for the file
32 ln -s doc/dbench/loadfiles/client.txt $out/share/dbench/client.txt
33
34 # backwards compatible to older nixpkgs packaging introduced by
35 # 3f27be8e5d5861cd4b9487d6c5212d88bf24316d
36 ln -s dbench/doc/dbench/loadfiles $out/share/loadfiles
37 '';
38
39 meta = with lib; {
40 description = "Filesystem benchmark tool based on load patterns";
41 homepage = "https://dbench.samba.org/";
42 license = licenses.gpl3;
43 platforms = platforms.linux;
44 maintainers = [ maintainers.bjornfor ];
45 };
46}