pyrox.dev
1{ lib, stdenv, buildGraalvmNativeImage, babashka, fetchurl, fetchFromGitHub, clojure, writeScript }:
2
3buildGraalvmNativeImage rec {
4 pname = "clojure-lsp";
5 version = "2023.08.06-00.28.06";
6
7 src = fetchFromGitHub {
8 owner = pname;
9 repo = pname;
10 rev = version;
11 sha256 = "sha256-wc7M2cPRtdaRzZn3GNu/aCbQ2VqxiDxvu/b7qnBVUBo=";
12 };
13
14 jar = fetchurl {
15 url = "https://github.com/clojure-lsp/clojure-lsp/releases/download/${version}/clojure-lsp-standalone.jar";
16 sha256 = "c301821ac6914999a44f5c1cd371d46b248fe9a2e31d43a666d0bc2656cfdd78";
17 };
18
19 extraNativeImageBuildArgs = [
20 "--no-fallback"
21 "--native-image-info"
22 ];
23
24 doCheck = true;
25 checkPhase = ''
26 runHook preCheck
27
28 export HOME="$(mktemp -d)"
29 ./${pname} --version | fgrep -q '${version}'
30 ''
31 # TODO: fix classpath issue per https://github.com/NixOS/nixpkgs/pull/153770
32 #${babashka}/bin/bb integration-test ./${pname}
33 + ''
34 runHook postCheck
35 '';
36
37 passthru.updateScript = writeScript "update-clojure-lsp" ''
38 #!/usr/bin/env nix-shell
39 #!nix-shell -i bash -p curl common-updater-scripts gnused jq nix
40
41 set -eu -o pipefail
42
43 latest_version=$(curl -s https://api.github.com/repos/clojure-lsp/clojure-lsp/releases/latest | jq --raw-output .tag_name)
44
45 old_jar_hash=$(nix-instantiate --eval --strict -A "clojure-lsp.jar.drvAttrs.outputHash" | tr -d '"' | sed -re 's|[+]|\\&|g')
46
47 curl -o clojure-lsp-standalone.jar -sL https://github.com/clojure-lsp/clojure-lsp/releases/download/$latest_version/clojure-lsp-standalone.jar
48 new_jar_hash=$(nix-hash --flat --type sha256 clojure-lsp-standalone.jar | sed -re 's|[+]|\\&|g')
49
50 rm -f clojure-lsp-standalone.jar
51
52 nixFile=$(nix-instantiate --eval --strict -A "clojure-lsp.meta.position" | sed -re 's/^"(.*):[0-9]+"$/\1/')
53
54 sed -i "$nixFile" -re "s|\"$old_jar_hash\"|\"$new_jar_hash\"|"
55 update-source-version clojure-lsp "$latest_version"
56 '';
57
58 meta = with lib; {
59 description = "Language Server Protocol (LSP) for Clojure";
60 homepage = "https://github.com/clojure-lsp/clojure-lsp";
61 sourceProvenance = with sourceTypes; [ binaryBytecode ];
62 license = licenses.mit;
63 maintainers = with maintainers; [ ericdallo babariviere ];
64 };
65}