pyrox.dev
1{ lib
2, appdirs
3, bokeh
4, buildPythonPackage
5, dask
6, entrypoints
7, fetchFromGitHub
8, fsspec
9, hvplot
10, intake-parquet
11, jinja2
12, msgpack
13, msgpack-numpy
14, pandas
15, panel
16, pyarrow
17, pytestCheckHook
18, python-snappy
19, pythonOlder
20, pyyaml
21, requests
22, stdenv
23, tornado
24}:
25
26buildPythonPackage rec {
27 pname = "intake";
28 version = "0.7.0";
29 format = "setuptools";
30
31 disabled = pythonOlder "3.8";
32
33 src = fetchFromGitHub {
34 owner = "intake";
35 repo = "intake";
36 rev = "refs/tags/${version}";
37 hash = "sha256-LK4abwPViEFJZ10bbRofF2aw2Mj0dliKwX6dFy93RVQ=";
38 };
39
40 propagatedBuildInputs = [
41 appdirs
42 dask
43 entrypoints
44 fsspec
45 msgpack
46 jinja2
47 pandas
48 pyyaml
49 ];
50
51 nativeCheckInputs = [
52 intake-parquet
53 pytestCheckHook
54 ] ++ lib.flatten (builtins.attrValues passthru.optional-dependencies);
55
56 passthru.optional-dependencies = {
57 server = [
58 msgpack
59 python-snappy
60 tornado
61 ];
62 dataframe = [
63 msgpack-numpy
64 pyarrow
65 ];
66 plot = [
67 hvplot
68 bokeh
69 panel
70 ];
71 remote = [
72 requests
73 ];
74 };
75
76 postPatch = ''
77 substituteInPlace setup.py \
78 --replace "'pytest-runner'" ""
79 '';
80
81 __darwinAllowLocalNetworking = true;
82
83 preCheck = ''
84 export HOME=$(mktemp -d);
85 export PATH="$PATH:$out/bin";
86 '';
87
88 disabledTests = [
89 # Disable tests which touch network
90 "http"
91 "test_address_flag"
92 "test_dir"
93 "test_discover"
94 "test_filtered_compressed_cache"
95 "test_flatten_flag"
96 "test_get_dir"
97 "test_pagination"
98 "test_port_flag"
99 "test_read_part_compressed"
100 "test_read_partition"
101 "test_read_pattern"
102 "test_remote_arr"
103 "test_remote_cat"
104 "test_remote_env"
105 # ValueError
106 "test_mlist_parameter"
107 # ImportError
108 "test_dataframe"
109 "test_ndarray"
110 "test_python"
111 # Timing-based, flaky on darwin and possibly others
112 "test_idle_timer"
113 # arrow-cpp-13 related
114 "test_read"
115 "test_pickle"
116 "test_read_dask"
117 "test_read_list"
118 "test_read_list_with_glob"
119 "test_to_dask"
120 "test_columns"
121 "test_df_transform"
122 "test_pipeline_apply"
123 ] ++ lib.optionals (stdenv.isDarwin && lib.versionOlder stdenv.hostPlatform.darwinMinVersion "10.13") [
124 # Flaky with older low-res mtime on darwin < 10.13 (#143987)
125 "test_second_load_timestamp"
126 ];
127
128 pythonImportsCheck = [
129 "intake"
130 ];
131
132 meta = with lib; {
133 description = "Data load and catalog system";
134 homepage = "https://github.com/ContinuumIO/intake";
135 changelog = "https://github.com/intake/intake/blob/${version}/docs/source/changelog.rst";
136 license = licenses.bsd2;
137 maintainers = with maintainers; [ ];
138 };
139}