pyrox.dev
1{ lib, stdenv, fetchurl, Libsystem }:
2let
3 version = "110.95";
4 baseurl = "http://smlnj.cs.uchicago.edu/dist/working/${version}";
5
6 arch = if stdenv.is64bit
7 then "64"
8 else "32";
9
10 boot32 = { url = "${baseurl}/boot.x86-unix.tgz";
11 sha256 = "07bcrvjphyin1ygjbymcqhd1mbfk4hff82wmxcllh77lr28l5dxf"; };
12 boot64 = { url = "${baseurl}/boot.amd64-unix.tgz";
13 sha256 = "1zn96a83kb6bn6228yfjsvb58m2qxw9k4j3qz0p9c8za479w4ch6"; };
14
15 bootBinary = if stdenv.is64bit
16 then boot64
17 else boot32;
18
19 sources = map fetchurl [
20 bootBinary
21 { url = "${baseurl}/config.tgz"; sha256 = "09srqxkxl86iaz6l6dz83c1apsac0pxpfq6b74i6l0nfl261jibw"; }
22 { url = "${baseurl}/cm.tgz"; sha256 = "0gh8inrb07z597axw8qipwyx52m8nac5d5r0rvgzvdnnjg9nr9zy"; }
23 { url = "${baseurl}/compiler.tgz"; sha256 = "1kk6jwzyc261l5nii3n8rwccmgvcj1mg5fgycfsfsiyyy1v8xfx7"; }
24 { url = "${baseurl}/runtime.tgz"; sha256 = "17i069h5cv411sgzx3ynlf4v3wlrxiba9bwy1b0x0cyhs879kppc"; }
25 { url = "${baseurl}/system.tgz"; sha256 = "0s8ij3wfxpjrmrwxrgrirfxjj8vkda6l32j88al5q1ic3ncwc58s"; }
26 { url = "${baseurl}/MLRISC.tgz"; sha256 = "1v2d3gjxrcgc95x5glqcw0nfp13aapkcw03fyi70m3k1yc61izmz"; }
27 { url = "${baseurl}/smlnj-lib.tgz"; sha256 = "04i11ki8v9s7yz3lg6b0djhi03zzkzav0b5cr81ypxlkmf4hh6bp"; }
28 { url = "${baseurl}/old-basis.tgz"; sha256 = "1ryqpy0n7c9gd995ndmjvaci74f95nr8n1jjgm28yd1sn7hnavhi"; }
29 { url = "${baseurl}/ckit.tgz"; sha256 = "18mcs3j8c5gq9cmck7r175am60blaznqmhzyir622yfc8fpw1map"; }
30 { url = "${baseurl}/nlffi.tgz"; sha256 = "16mrl5aqbgsgljxa3z8kj5max9drddml34bq7rn1i78594jfvkwk"; }
31 { url = "${baseurl}/cml.tgz"; sha256 = "00x784nv1pi6534k3vva26i9qx84cvw242vgwbs5020zkm6gvrmn"; }
32 { url = "${baseurl}/eXene.tgz"; sha256 = "143825h36v6z77kwvrvpszgwnhmjs3yldb18i9z4lwkqfb4kn7f7"; }
33 { url = "${baseurl}/ml-lpt.tgz"; sha256 = "17ly9h9ry8r94dx6lkas6w2cxknwkpma4z9pj8rgzmd3w6qm7j1z"; }
34 { url = "${baseurl}/ml-lex.tgz"; sha256 = "1ja3l2kiq17754c58mwdiqi25f7ax0cji2wk0vq4872iwwxc22px"; }
35 { url = "${baseurl}/ml-yacc.tgz"; sha256 = "1m48nkwvw87yg39sjihlw8na5m34bzz3d4zpfbjaj2f75fkjy3jf"; }
36 { url = "${baseurl}/ml-burg.tgz"; sha256 = "13nbvbah7bn8gjm4gi41m412vpl69wd6d3x3wzbb6xpia9vm4z4j"; }
37 { url = "${baseurl}/pgraph.tgz"; sha256 = "1aizkl8avz01kx221xy5z7a1a1b5xqn2hrk66wr8d0iav2nh5c98"; }
38 { url = "${baseurl}/trace-debug-profile.tgz"; sha256 = "1c80xgck9sb2rm554nfg4f5mpjkdbrwkcx88pj120056225l10vx"; }
39 { url = "${baseurl}/heap2asm.tgz"; sha256 = "1n68drd7as5dy20ccfvgd9cmnhfpfvz7g3f0gc8kpaqaz3vpy36g"; }
40 { url = "${baseurl}/smlnj-c.tgz"; sha256 = "1b6svh2kk5211rq73fdwx3sf80d2rshf0dmkkrq5mw4852nzqz3p"; }
41 { url = "${baseurl}/doc.tgz"; sha256 = "021yzhy9maypq4ahz0d0qpr601spndg583fn9mapv6rl42kwhjq6"; }
42 { url = "${baseurl}/asdl.tgz"; sha256 = "0nqavqcbidwnphbbwjrxhpy8glbyad51wy0cpqimbsw3sgns0zkd"; }
43 ];
44in stdenv.mkDerivation {
45 pname = "smlnj";
46 inherit version;
47
48 inherit sources;
49
50 patchPhase = ''
51 sed -i '/PATH=/d' config/_arch-n-opsys base/runtime/config/gen-posix-names.sh
52 echo SRCARCHIVEURL="file:/$TMP" > config/srcarchiveurl
53 patch --verbose config/_heap2exec ${./heap2exec.diff}
54 '' + lib.optionalString stdenv.isDarwin ''
55 # Locate standard headers like <unistd.h>
56 substituteInPlace base/runtime/config/gen-posix-names.sh \
57 --replace "\$SDK_PATH/usr" "${Libsystem}"
58 '';
59
60 unpackPhase = ''
61 for s in $sources; do
62 b=$(basename $s)
63 cp $s ''${b#*-}
64 done
65 unpackFile config.tgz
66 mkdir base
67 ./config/unpack $TMP runtime
68 '';
69
70 buildPhase = ''
71 ./config/install.sh -default ${arch}
72 '';
73
74 installPhase = ''
75 mkdir -pv $out
76 cp -rv bin lib $out
77
78 cd $out/bin
79 for i in *; do
80 sed -i "2iSMLNJ_HOME=$out/" $i
81 done
82 '';
83
84 meta = with lib; {
85 description = "Standard ML of New Jersey, a compiler";
86 homepage = "http://smlnj.org";
87 license = licenses.bsd3;
88 platforms = [ "x86_64-linux" "i686-linux" "x86_64-darwin" ];
89 maintainers = with maintainers; [ thoughtpolice ];
90 mainProgram = "sml";
91 # never built on x86_64-darwin since first introduction in nixpkgs
92 broken = stdenv.isDarwin && stdenv.isx86_64;
93 };
94}