pyrox.dev
1{ lib, meson, ninja, pkg-config, gettext, fetchFromGitHub, python3
2, wrapGAppsHook, gtk3, glib, desktop-file-utils, appstream-glib, gnome
3, gobject-introspection, librsvg }:
4
5python3.pkgs.buildPythonApplication rec {
6 pname = "piper";
7 version = "0.7";
8
9 format = "other";
10
11 src = fetchFromGitHub {
12 owner = "libratbag";
13 repo = "piper";
14 rev = version;
15 sha256 = "0jsvfy0ihdcgnqljfgs41lys1nlz18qvsa0a8ndx3pyr41f8w8wf";
16 };
17
18 nativeBuildInputs = [ meson ninja gettext pkg-config wrapGAppsHook desktop-file-utils appstream-glib gobject-introspection ];
19 buildInputs = [
20 gtk3 glib gnome.adwaita-icon-theme python3 librsvg
21 ];
22 propagatedBuildInputs = with python3.pkgs; [ lxml evdev pygobject3 ] ++ [
23 gobject-introspection # fixes https://github.com/NixOS/nixpkgs/issues/56943 for now
24 ];
25
26 mesonFlags = [
27 "-Druntime-dependency-checks=false"
28 "-Dtests=false"
29 ];
30
31 postPatch = ''
32 chmod +x meson_install.sh # patchShebangs requires executable file
33 patchShebangs meson_install.sh data/generate-piper-gresource.xml.py
34 '';
35
36 meta = with lib; {
37 description = "GTK frontend for ratbagd mouse config daemon";
38 homepage = "https://github.com/libratbag/piper";
39 license = licenses.gpl2;
40 maintainers = with maintainers; [ mvnetbiz ];
41 platforms = platforms.linux;
42 };
43}