pyrox.dev
1{ lib, stdenv, fetchFromGitHub, fetchpatch, kernel, runtimeShell }:
2
3let
4 baseName = "bbswitch";
5 version = "unstable-2021-11-29";
6 name = "${baseName}-${version}-${kernel.version}";
7
8in
9
10stdenv.mkDerivation {
11 inherit name;
12
13 src = fetchFromGitHub {
14 owner = "Bumblebee-Project";
15 repo = "bbswitch";
16 # https://github.com/Bumblebee-Project/bbswitch/tree/develop
17 rev = "23891174a80ea79c7720bcc7048a5c2bfcde5cd9";
18 hash = "sha256-50v1Jxem5kaI1dHOKmgBbPLxI82QeYxiaRHhrHpWRzU=";
19 };
20
21 patches = [
22 (fetchpatch {
23 url = "https://raw.githubusercontent.com/archlinux/svntogit-community/0bd986055ba52887b81048de5c61e618eec06eb0/trunk/0003-kernel-5.18.patch";
24 sha256 = "sha256-va62/bR1qyBBMPg0lUwCH7slGG0XijxVCsFa4FCoHEQ=";
25 })
26 ];
27
28 nativeBuildInputs = kernel.moduleBuildDependencies;
29
30 hardeningDisable = [ "pic" ];
31
32 preBuild = ''
33 substituteInPlace Makefile \
34 --replace "\$(shell uname -r)" "${kernel.modDirVersion}" \
35 --replace "/lib/modules" "${kernel.dev}/lib/modules"
36 '';
37
38 makeFlags = kernel.makeFlags;
39
40 installPhase = ''
41 mkdir -p $out/lib/modules/${kernel.modDirVersion}/misc
42 cp bbswitch.ko $out/lib/modules/${kernel.modDirVersion}/misc
43
44 mkdir -p $out/bin
45 tee $out/bin/discrete_vga_poweroff << EOF
46 #!${runtimeShell}
47
48 echo -n OFF > /proc/acpi/bbswitch
49 EOF
50 tee $out/bin/discrete_vga_poweron << EOF
51 #!${runtimeShell}
52
53 echo -n ON > /proc/acpi/bbswitch
54 EOF
55 chmod +x $out/bin/discrete_vga_poweroff $out/bin/discrete_vga_poweron
56 '';
57
58 meta = with lib; {
59 description = "A module for powering off hybrid GPUs";
60 platforms = [ "x86_64-linux" "i686-linux" ];
61 homepage = "https://github.com/Bumblebee-Project/bbswitch";
62 maintainers = with maintainers; [ abbradar ];
63 license = licenses.gpl2Plus;
64 };
65}